WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarlsonRD[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRD]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
微分と積分  
関数表現  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CarlsonRD

CarlsonRD[x,y,z]

Carlsonの楕円積分 TemplateBox[{x, y, z}, CarlsonRD]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 非負の引数について TemplateBox[{x, y, z}, CarlsonRD]=3/2int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-3/2)dt である．
  • CarlsonRD[x,y,z]は に不連続な分枝切断線を持つ．
  • 特別な引数の場合，CarlsonRDは自動的に厳密値を計算する．
  • CarlsonRDは任意の数値精度で評価できる．
  • CarlsonRDは自動的にリストに縫い込まれる．
  • CarlsonRDは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: CarlsonRD[2., 3., 5.]

CarlsonRDをプロットする：

Wolfram Language code: Plot[Table[CarlsonRD[3, y, z], {y, {1 / 2, 2, 5}}]//Evaluate, {z, 0, 10}, PlotLegends -> "Expressions"]

CarlsonRDは，で，ルジャンドル(Legendre)の楕円積分の組合せに関連している：

Wolfram Language code: (m/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {ϕ -> Pi / 3, m -> 0.43}
Wolfram Language code: EllipticF[ϕ, m] - EllipticE[ϕ, m] /. {ϕ -> Pi / 3, m -> 0.43}

スコープ  (15)

数値評価  (6)

CarlsonRDを数値的に評価する：

Wolfram Language code: CarlsonRD[3 / 5, 11, 22 / 7.]

高精度で評価する：

Wolfram Language code: N[CarlsonRD[1, 7, 11], 50]

出力精度は入力精度に従う：

Wolfram Language code: CarlsonRD[1, 7, 11.2345678901234567890123]
Wolfram Language code: CarlsonRD[1, 7, 11.234567890123456789012345678901234567]

複素引数について評価する：

Wolfram Language code: CarlsonRD[1 + I, 1 - 2I, 5.]

高精度で効率的に評価する：

Wolfram Language code: Timing[CarlsonRD[11, 1, 34`500]]
Wolfram Language code: Timing[Precision[CarlsonRD[11, 1, 34`100000]]]

CarlsonRDは要素単位でリストに縫い込まれる：

Wolfram Language code: CarlsonRD[{1, 2, 3, 4, 5}, 3, 4.]

CarlsonRDは，IntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: CarlsonRD[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRD[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

特定の値  (2)

単純な厳密値は自動的に生成される：

Wolfram Language code: CarlsonRD[x, x, x]
Wolfram Language code: CarlsonRD[x, x, y]
Wolfram Language code: CarlsonRD[x, y, y]

CarlsonRDの一つの引数が0のとき，CarlsonRDは完全楕円積分CarlsonREおよびCarlsonRKで表すことができる：

Wolfram Language code: CarlsonRD[0, x, y]

微分と積分  (2)

についてのTemplateBox[{x, y, z}, CarlsonRD]の導関数：

Wolfram Language code: D[CarlsonRD[x, y, z], x]

についてのTemplateBox[{x, y, z}, CarlsonRD]の導関数：

Wolfram Language code: D[CarlsonRD[x, y, z], z]

TemplateBox[{x, y, z}, CarlsonRD]の についての不定積分：

Wolfram Language code: Integrate[CarlsonRD[x, y, z], x]

TemplateBox[{x, y, z}, CarlsonRD]の についての不定積分：

Wolfram Language code: Integrate[CarlsonRD[x, y, z], z]

関数表現  (1)

TraditionalFormによる表示：

Wolfram Language code: CarlsonRD[x, y, z]//TraditionalForm

関数の恒等式と簡約  (4)

CarlsonRD，CarlsonRF，CarlsonRGを関連付ける等式：

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

CarlsonRDについてのいくつかの巡回置換恒等式：

Wolfram Language code: CarlsonRD[x, y, z] + CarlsonRD[y, z, x] + CarlsonRD[z, x, y] == (3/Sqrt[x]Sqrt[y]Sqrt[z])//FullSimplify
Wolfram Language code: z CarlsonRD[x, y, z] + x CarlsonRD[y, z, x] + y CarlsonRD[z, x, y] == 3CarlsonRF[x, y, z]//FullSimplify
Wolfram Language code: z(x + y)CarlsonRD[x, y, z] + x(y + z)CarlsonRD[y, z, x] + y(z + x)CarlsonRD[z, x, y] == 6CarlsonRG[x, y, z]//FunctionExpand//FullSimplify

CarlsonRDはオイラー・ポアソン(Euler–Poisson)の偏微分方程式を満足する：

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, y]CarlsonRD[x, y, z] - Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - z)Subscript[∂, x, z]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, z]CarlsonRD[x, y, z] - 3Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify

CarlsonRDはオイラーの同次関係を満足する：

Wolfram Language code: xSubscript[∂, x]CarlsonRD[x, y, z] + ySubscript[∂, y]CarlsonRD[x, y, z] + zSubscript[∂, z]CarlsonRD[x, y, z] == -(3/2)CarlsonRD[x, y, z]//FunctionExpand//FullSimplify

アプリケーション  (2)

地球の経線に沿った距離：

Wolfram Language code: With[{a = UnitConvert[GeodesyData["ITRF00", "SemimajorAxis"], $UnitSystem], e = GeodesyData["ITRF00", "Eccentricity"], ϕ = 29°}, a(1 - e^2)(Sin[ϕ]CarlsonRF[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1] + (e^2/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1])]

GeoDistanceの結果と比較する：

Wolfram Language code: GeoDistance[GeoPosition[{0, 0}], GeoPosition[{29, 0}]]

マイラー風船（2枚の平らなプラスティックシートの外周を縫い合せて膨らませたもの）のパラメータ化：

Wolfram Language code: With[{kk = N[π CarlsonRK[2, 4]]}, ParametricPlot3D[{JacobiCN[u, (1/2)]Cos[v], JacobiCN[u, (1/2)]Sin[v], (1/Sqrt[2])(u - (1/3)JacobiSN[u, (1/2)]^3CarlsonRD[JacobiCN[u, (1/2)]^2, JacobiDN[u, (1/2)]^2, 1])}, {u, -kk, kk}, {v, -π, π}, Exclusions -> None, PlotRange -> All]]

特性と関係  (1)

CarlsonRDはその最初の2引数について対称である：

Wolfram Language code: CarlsonRD[x, y, z] == CarlsonRD[y, x, z]
Wolfram Research (2021), CarlsonRD, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRD.html （2023年に更新）.

テキスト

Wolfram Research (2021), CarlsonRD, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRD.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CarlsonRD." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRD.html.

APA

Wolfram Language. (2021). CarlsonRD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRD.html

BibTeX

@misc{reference.wolfram_2026_carlsonrd, author="Wolfram Research", title="{CarlsonRD}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRD.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrd, organization={Wolfram Research}, title={CarlsonRD}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRD.html}, note=[Accessed: 12-August-2026]}