WOLFRAM

Wolfram 语言与系统参考资料中心

CarlsonRD[x,y,z]

给出 Carlson 椭圆积分 TemplateBox[{x, y, z}, CarlsonRD].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
指定值  
导数和积分  
函数表示  
函数恒等和化简  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CarlsonRD

CarlsonRD[x,y,z]

给出 Carlson 椭圆积分 TemplateBox[{x, y, z}, CarlsonRD].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

数字计算：

Wolfram Language code: CarlsonRD[2., 3., 5.]

绘制 CarlsonRD：

Wolfram Language code: Plot[Table[CarlsonRD[3, y, z], {y, {1 / 2, 2, 5}}]//Evaluate, {z, 0, 10}, PlotLegends -> "Expressions"]

CarlsonRD 与限制在 中的勒让德椭圆积分的复合函数有关：

Wolfram Language code: (m/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {ϕ -> Pi / 3, m -> 0.43}
Wolfram Language code: EllipticF[ϕ, m] - EllipticE[ϕ, m] /. {ϕ -> Pi / 3, m -> 0.43}

范围  (15)

数值计算  (6)

进行 CarlsonRD 的数值计算：

Wolfram Language code: CarlsonRD[3 / 5, 11, 22 / 7.]

更高精度的计算：

Wolfram Language code: N[CarlsonRD[1, 7, 11], 50]

输出的精度可以追溯输入的精度：

Wolfram Language code: CarlsonRD[1, 7, 11.2345678901234567890123]
Wolfram Language code: CarlsonRD[1, 7, 11.234567890123456789012345678901234567]

复数参数的计算：

Wolfram Language code: CarlsonRD[1 + I, 1 - 2I, 5.]

高效地高精度计算：

Wolfram Language code: Timing[CarlsonRD[11, 1, 34`500]]
Wolfram Language code: Timing[Precision[CarlsonRD[11, 1, 34`100000]]]

CarlsonRD 以元素方式线性作用于列表：

Wolfram Language code: CarlsonRD[{1, 2, 3, 4, 5}, 3, 4.]

CarlsonRD 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: CarlsonRD[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRD[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

指定值  (2)

自动生成简单精确值：

Wolfram Language code: CarlsonRD[x, x, x]
Wolfram Language code: CarlsonRD[x, x, y]
Wolfram Language code: CarlsonRD[x, y, y]

当 CarlsonRD 的一个参数为零时，CarlsonRD 可以用完全椭圆积分 CarlsonRE 和 CarlsonRK 表示：

Wolfram Language code: CarlsonRD[0, x, y]

导数和积分  (2)

关于 的 TemplateBox[{x, y, z}, CarlsonRD] 的导数：

Wolfram Language code: D[CarlsonRD[x, y, z], x]

关于 的 TemplateBox[{x, y, z}, CarlsonRD] 的导数：

Wolfram Language code: D[CarlsonRD[x, y, z], z]

TemplateBox[{x, y, z}, CarlsonRD] 关于 的不定积分：

Wolfram Language code: Integrate[CarlsonRD[x, y, z], x]

TemplateBox[{x, y, z}, CarlsonRD] 关于 的不定积分：

Wolfram Language code: Integrate[CarlsonRD[x, y, z], z]

函数表示  (1)

TraditionalForm 格式：

Wolfram Language code: CarlsonRD[x, y, z]//TraditionalForm

函数恒等和化简  (4)

有关 CarlsonRD、CarlsonRF 和 CarlsonRG 的方程式：

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

CarlsonRD 的一些循环置换恒等：

Wolfram Language code: CarlsonRD[x, y, z] + CarlsonRD[y, z, x] + CarlsonRD[z, x, y] == (3/Sqrt[x]Sqrt[y]Sqrt[z])//FullSimplify
Wolfram Language code: z CarlsonRD[x, y, z] + x CarlsonRD[y, z, x] + y CarlsonRD[z, x, y] == 3CarlsonRF[x, y, z]//FullSimplify
Wolfram Language code: z(x + y)CarlsonRD[x, y, z] + x(y + z)CarlsonRD[y, z, x] + y(z + x)CarlsonRD[z, x, y] == 6CarlsonRG[x, y, z]//FunctionExpand//FullSimplify

CarlsonRD 满足欧拉-泊松偏微分方程：

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, y]CarlsonRD[x, y, z] - Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - z)Subscript[∂, x, z]CarlsonRD[x, y, z] + (1/2)(Subscript[∂, z]CarlsonRD[x, y, z] - 3Subscript[∂, x]CarlsonRD[x, y, z]) == 0//FunctionExpand//FullSimplify

CarlsonRD 满足欧拉齐次关系：

Wolfram Language code: xSubscript[∂, x]CarlsonRD[x, y, z] + ySubscript[∂, y]CarlsonRD[x, y, z] + zSubscript[∂, z]CarlsonRD[x, y, z] == -(3/2)CarlsonRD[x, y, z]//FunctionExpand//FullSimplify

应用  (2)

沿着地球经线的距离：

Wolfram Language code: With[{a = UnitConvert[GeodesyData["ITRF00", "SemimajorAxis"], $UnitSystem], e = GeodesyData["ITRF00", "Eccentricity"], ϕ = 29°}, a(1 - e^2)(Sin[ϕ]CarlsonRF[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1] + (e^2/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1])]

与 GeoDistance 的结果相比较：

Wolfram Language code: GeoDistance[GeoPosition[{0, 0}], GeoPosition[{29, 0}]]

铝膜气球参数化（两片平面塑料在其边缘处缝合并对其充气）：

Wolfram Language code: With[{kk = N[π CarlsonRK[2, 4]]}, ParametricPlot3D[{JacobiCN[u, (1/2)]Cos[v], JacobiCN[u, (1/2)]Sin[v], (1/Sqrt[2])(u - (1/3)JacobiSN[u, (1/2)]^3CarlsonRD[JacobiCN[u, (1/2)]^2, JacobiDN[u, (1/2)]^2, 1])}, {u, -kk, kk}, {v, -π, π}, Exclusions -> None, PlotRange -> All]]

属性和关系  (1)

CarlsonRD 就其前两个参数而言是对称的：

Wolfram Language code: CarlsonRD[x, y, z] == CarlsonRD[y, x, z]
Wolfram Research (2021)，CarlsonRD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlsonRD.html （更新于 2023 年）.

文本

Wolfram Research (2021)，CarlsonRD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlsonRD.html （更新于 2023 年）.

CMS

Wolfram 语言. 2021. "CarlsonRD." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/CarlsonRD.html.

APA

Wolfram 语言. (2021). CarlsonRD. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CarlsonRD.html 年

BibTeX

@misc{reference.wolfram_2026_carlsonrd, author="Wolfram Research", title="{CarlsonRD}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRD.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrd, organization={Wolfram Research}, title={CarlsonRD}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRD.html}, note=[Accessed: 15-September-2026]}