WOLFRAM

Wolfram 语言与系统参考资料中心

CarlsonRJ[x,y,z,ρ]

给出 Carlson 椭圆积分 TemplateBox[{x, y, z, rho}, CarlsonRJ].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特定值  
导数和积分  
函数表示  
函数恒等和化简  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CarlsonRJ

CarlsonRJ[x,y,z,ρ]

给出 Carlson 椭圆积分 TemplateBox[{x, y, z, rho}, CarlsonRJ].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

数值运算：

Wolfram Language code: CarlsonRJ[2., 3., 5., 7.2]

可视化一系列参数：

Wolfram Language code: Plot[{CarlsonRJ[t, 3, 5, 4], CarlsonRJ[1, t, 5, 4], CarlsonRJ[1, 3, t, 4], CarlsonRJ[1, 3, 5, t]}, {t, -6, 6}, PlotLegends -> "Expressions"]

对于 ，CarlsonRJ 与第三类勒让德椭圆积分 TemplateBox[{n, phi, m}, EllipticPi3] 有关：

Wolfram Language code: (n/3)Sin[ϕ]^3CarlsonRJ[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1, 1 - n Sin[ϕ]^2] /. {ϕ -> 0.7, m -> 0.5, n -> -3}
Wolfram Language code: EllipticPi[n, ϕ, m] - EllipticF[ϕ, m] /. {ϕ -> 0.7, m -> 0.5, n -> -3}

范围  (14)

数值运算  (6)

数值运算：

Wolfram Language code: CarlsonRJ[3, 5, 1, 0.2]
Wolfram Language code: CarlsonRJ[3, 5, 1., -5]

高精度运算：

Wolfram Language code: N[CarlsonRJ[1 / 3, 1 / 5, 1 / 7, 1], 50]

输出的精度与输入的精度一致：

Wolfram Language code: CarlsonRJ[1 / 3, 1 / 5, 1, 1.234567890123456789012345]
Wolfram Language code: CarlsonRJ[1 / 3, 1 / 5, 1, 1.2345678901234567890123456789012345]

对复参数进行运算：

Wolfram Language code: CarlsonRJ[0.7 - 0.2I, 4, 2. + I / 3, 0.7 I]

高精度高效运算：

Wolfram Language code: Timing[CarlsonRJ[2, 4, 6, 3`500]]
Wolfram Language code: Timing[Precision@CarlsonRJ[2, 4, 6, 3`100000]]

CarlsonRJ 按元素遍历列表：

Wolfram Language code: CarlsonRJ[{1, 2, 3}, {2, 3, 1}, {3, 1, 2}, {0.1, 0.2, 0.5}]

CarlsonRJ 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: CarlsonRJ[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}], Interval[{4.56, 4.57}]]
Wolfram Language code: CarlsonRJ[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100], CenteredInterval[9 / 8, 1 / 100]]

特定值  (3)

简单的精确结果是自动生成的：

Wolfram Language code: CarlsonRJ[x, x, x, x] /. x -> EulerGamma
Wolfram Language code: CarlsonRJ[x, x, x, ρ] /. x -> Zeta[3]
Wolfram Language code: CarlsonRJ[x, y, Pi, Pi]

当 CarlsonRJ 的前三个参数之一为零时，CarlsonRJ 化简为完全椭圆积分 CarlsonRM：

Wolfram Language code: CarlsonRJ[0, x, y, ρ]

当 CarlsonRJ 的前三个参数中的一个参数等于最后一个参数，并且它们都不在负实数轴上时，CarlsonRJ 化简为 CarlsonRD：

Wolfram Language code: CarlsonRJ[x, y, 2 + 3I, 2 + 3I]

导数和积分  (2)

TemplateBox[{x, y, z, rho}, CarlsonRJ] 关于 的导数：

Wolfram Language code: D[CarlsonRJ[x, y, z, ρ], x]

TemplateBox[{x, y, z, rho}, CarlsonRJ] 关于 的导数：

Wolfram Language code: D[CarlsonRJ[x, y, z, ρ], ρ]

TemplateBox[{x, y, z, rho}, CarlsonRJ] 关于 的不定积分：

Wolfram Language code: Integrate[CarlsonRJ[x, y, z, ρ], x]

函数表示  (1)

TraditionalForm 格式：

Wolfram Language code: CarlsonRJ[Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], ρ]//TraditionalForm

函数恒等和化简  (2)

CarlsonRJ 满足欧拉-泊松偏微分方程：

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRJ[x, z, y, ρ] + (1/2)(Subscript[∂, y]CarlsonRJ[x, z, y, ρ] - Subscript[∂, x]CarlsonRJ[x, z, y, ρ]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - ρ)Subscript[∂, x, ρ]CarlsonRJ[x, z, y, ρ] + (1/2)Subscript[∂, ρ]CarlsonRJ[x, z, y, ρ] - Subscript[∂, x]CarlsonRJ[x, z, y, ρ] == 0//FunctionExpand//FullSimplify

CarlsonRJ 满足欧拉齐次关系：

Wolfram Language code: xSubscript[∂, x]CarlsonRJ[x, z, y, ρ] + ySubscript[∂, y]CarlsonRJ[x, z, y, ρ] + zSubscript[∂, z]CarlsonRJ[x, z, y, ρ] + ρSubscript[∂, ρ]CarlsonRJ[x, z, y, ρ] == -(3/2)CarlsonRJ[x, z, y, ρ]//FunctionExpand//FullSimplify

应用  (1)

使用 CarlsonRJ 定义共形映射：

Wolfram Language code: f[w_] = (2 Cos[(w/2)]^2 /3 (1 + Cos[w]))(9 CarlsonRF[1, 1 - 2 Tan[(w/2)]^2, 1 - (1/3) Tan[(w/2)]^2] Tan[(w/2)] - 4 CarlsonRJ[1, 1 - 2 Tan[(w/2)]^2, 1 - (1/3) Tan[(w/2)]^2, Sec[(w/2)]^2] Tan[(w/2)]^3);

可视化具有恒定实部和虚部的线的图像：

Wolfram Language code: ParametricPlot[{Re[f[u + I v]], Im[f[u + I v]]}, {u, -Pi / 2, Pi / 2}, {v, 1*^-4, 3}, Mesh -> 15, PlotPoints -> 100]

属性和关系  (2)

CarlsonRJ 在前三个参数排列置换后不变：

Wolfram Language code: CarlsonRJ[x, y, z, ρ] == CarlsonRJ[z, x, y, ρ]

验证 CarlsonRJ 的参数关系的变化：

Wolfram Language code: With[{q = x + ((y - x)(z - x)/p - x)}, (p - x)CarlsonRJ[x, y, z, p] + (q - x)CarlsonRJ[x, y, z, q] == 3CarlsonRF[x, y, z] - 3CarlsonRC[(y z/x), (p q/x)]] /. {{x -> 2, y -> 3, z -> 5, p -> 7.}, {x -> 2, y -> 3, z -> 5, p -> 1.}, {x -> 2, y -> 3, z -> 5, p -> -4.}}
Wolfram Research (2021)，CarlsonRJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlsonRJ.html （更新于 2023 年）.

文本

Wolfram Research (2021)，CarlsonRJ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarlsonRJ.html （更新于 2023 年）.

CMS

Wolfram 语言. 2021. "CarlsonRJ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/CarlsonRJ.html.

APA

Wolfram 语言. (2021). CarlsonRJ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CarlsonRJ.html 年

BibTeX

@misc{reference.wolfram_2026_carlsonrj, author="Wolfram Research", title="{CarlsonRJ}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRJ.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrj, organization={Wolfram Research}, title={CarlsonRJ}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRJ.html}, note=[Accessed: 15-August-2026]}