WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Ceiling[x]

x 以上で最小の整数を返す．

Ceiling[x,a]

x 以上で最小の a の倍数を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
微分と積分  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Ceiling

Ceiling[x]

x 以上で最小の整数を返す．

Ceiling[x,a]

x 以上で最小の a の倍数を返す．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • StandardFormまたはInputFormを使っている場合，Ceiling[x]は，⌈x⌉，lc rcまたは
    \[LeftCeiling]x \[RightCeiling]を使うことでも入力が可能である． »
  • が任意の数値の形を取るとき，Ceiling[x]は整数を返す．x は明示的な数値でなくてもよい．
  • Ceiling[x]は複素数の実部と虚部に別々に適用される．
  • a が正の実数ではないなら，Ceiling[x,a]は式Ceiling[x,a]a Ceiling[x/a]によって定義される． »
  • 厳密な数値指定に対してCeilingを使うと，評価時に数値近似的な処理が行われる．この過程は大域変数$MaxExtraPrecisionの設定値の影響を受けることがある．
  • Ceilingは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (4)

最も近くの整数に切り上げる：

Wolfram Language code: Ceiling[2.4]
Wolfram Language code: Ceiling[2.6]

最も近くの10の倍数に切り上げる：

Wolfram Language code: Ceiling[226, 10]

実数の部分集合上で関数をプロットする：

Wolfram Language code: Plot[Ceiling[x], {x, -3, 3}]

lc と rc を使ってCeilingの簡単な表記を入力する：

Wolfram Language code: ⌈x⌉

スコープ  (30)

数値評価  (7)

数値的に評価する：

Wolfram Language code: Ceiling[5.37]
Wolfram Language code: Ceiling[-3.7]
Wolfram Language code: Ceiling[-10.3, 3.5]
Wolfram Language code: Ceiling[2Pi - E, 5 / 4]

複素入力：

Wolfram Language code: Ceiling[5.37 - 1.3I]

1引数のCeilingは常に厳密な結果を返す：

Wolfram Language code: Ceiling[123.4`45]

2引数の形は第2引数の精度に従う：

Wolfram Language code: Ceiling[100`45, 13.2456`10]

高精度で効率よく評価する：

Wolfram Language code: Ceiling[7545 / 4660`10000]//Timing
Wolfram Language code: N[Ceiling[(E + Pi) ^ 2 - E ^ 2 - Pi ^ 2 - 2 E Pi], 10^5]//Quiet//Timing

Ceilingは実数値区間を扱うことができる：

Wolfram Language code: Ceiling[Interval[{-1, 3 / 2}]]

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: **Ceiling**[{{1 / 2, -1}, {0, -1 / 2}}]

MatrixFunctionを使って行列のCeiling関数を計算することもできる：

Wolfram Language code: MatrixFunction[Ceiling, {{1 / 2, -1}, {0, -1 / 2}}]

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: Ceiling[ Around[-1, 0.01]]

特定の値  (6)

固定点におけるCeilingの値：

Wolfram Language code: Table[Ceiling[n ], {n, {1 / 7, 5 / 4, 7 / 3, 7 / 2}}]

ゼロにおける値：

Wolfram Language code: Ceiling[0]

Infinityにおける値：

Wolfram Language code: Ceiling[∞]

記号的に評価する：

Wolfram Language code: PiecewiseExpand[Ceiling[x, 2], 0 < x < 4]

Ceilingを記号的に操作する：

Wolfram Language code: Simplify[Ceiling[x] + Ceiling[x + 1]]
Wolfram Language code: Reduce[Ceiling[x] + Ceiling[2x + 1] == 0, x, Reals]

Ceiling[x]=2となるような x の値を求める：

Wolfram Language code: xval = x /. FindRoot[Ceiling[x] == 2, {x, 1.5}]
Wolfram Language code: Plot[Ceiling[x], {x, -2, 3}, Epilog -> Style[Point[{xval, Ceiling[xval]}], PointSize[Large], Red], ExclusionsStyle -> Dotted]

可視化  (4)

Ceiling関数をプロットする：

Wolfram Language code: Plot[Ceiling[x], {x, -3, 3}, Filling -> Axis]

2引数の形を可視化する：

Wolfram Language code: Plot[Ceiling[x, .5], {x, -3, 3}, Filling -> Axis]

Ceilingを三次元でプロットする：

Wolfram Language code: Plot3D[Ceiling[x, y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BlueGreenYellow"]

Ceilingを複素平面上でプロットする：

Wolfram Language code: ComplexPlot3D[Ceiling[z], {z, 3}, PlotLegends -> Automatic]

関数の特性  (9)

Ceilingは実数と複素数のすべての入力について定義される：

Wolfram Language code: FunctionDomain[Ceiling[x], x]
Wolfram Language code: FunctionDomain[Ceiling[x], x, Complexes]

Ceilingは無限に大きいあるいは小さい結果を生成できる：

Wolfram Language code: FunctionRange[Ceiling[x], x, y]//Quiet

Ceilingは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Ceiling[x], x]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Ceiling[x], x]
Wolfram Language code: FunctionDiscontinuities[Ceiling[x], x]

Ceilingは非減少である：

Wolfram Language code: FunctionMonotonicity[Ceiling[x], x]

Ceilingは単射ではない：

Wolfram Language code: FunctionInjective[Ceiling[x, 5], x]
Wolfram Language code: Plot[{Ceiling[x, 5], 5}, {x, -20, 20}, PlotStyle -> {Thick}]

Ceilingは全射ではない：

Wolfram Language code: FunctionSurjective[Ceiling[x, 5], x]
Wolfram Language code: Plot[{Ceiling[x, 5], -2}, {x, -20, 20}, PlotStyle -> {Thick}]

Ceilingは非負でも非正でもない：

Wolfram Language code: FunctionSign[Ceiling[x], x]

Ceilingは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Ceiling[x], x]

TraditionalFormによる表示：

Wolfram Language code: Ceiling[n]//TraditionalForm

微分と積分  (4)

x についての一次導関数：

Wolfram Language code: D[Ceiling[x], x]

a についての一次導関数：

Wolfram Language code: D[Ceiling[x, a], a]//FullSimplify

Ceilingの定積分：

Wolfram Language code: Integrate[Ceiling[x], {x, 0, E}]
Wolfram Language code: Integrate[Ceiling[x ^ 2], {x, 0, 3}]

級数展開：

Wolfram Language code: Series[Ceiling[x ^ 2], {x, 1, 2}, Assumptions -> Element[x, Reals]]

アプリケーション  (4)

の切上げをプロットする：

Wolfram Language code: Plot[Ceiling[x + x ^ 2], {x, -3, 3}]

の切上げをプロットする：

Wolfram Language code: Plot3D[Ceiling[x y], {x, -2, 2}, {y, -2, 2}]

自身を数える数列：

Wolfram Language code: Table[Ceiling[(Sqrt[8k + 1] - 1) / 2], {k, 21}]

ハトの巣原理による箱の中の要素の最小数：

Wolfram Language code: Plot3D[Ceiling[n / k], {k, 1, 10}, {n, 1, 10}, Mesh -> False, AxesLabel -> {"boxes", "elements", None}]

特性と関係  (10)

負の数は最も近い整数に切り上げる：

Wolfram Language code: Ceiling[{-2.4, -2.5, -2.6}]

a>0のとき，Ceiling[x,a]は x 以上の a の最小の倍数を与える：

Wolfram Language code: Ceiling[16, 3]

a のその他の値については，Ceiling[x,a]は以下の式で定義される：

Wolfram Language code: FunctionExpand[Ceiling[x, a]]

a<0のとき，結果は x 以下になる：

Wolfram Language code: {Ceiling[x, a], %} /. {x -> 16, a -> -3}

Ceiling[x,-a]はFloor[x,a]に等しい：

Wolfram Language code: FullSimplify[Ceiling[x, -a] == Floor[x, a]]

CeilingをPiecewiseに変換する：

Wolfram Language code: PiecewiseExpand[Ceiling[x ^ 2], 0 < x < 2]

Ceiling関数のネストを外す：

Wolfram Language code: PiecewiseExpand[Ceiling[x + 1 / 3 + Ceiling[1 - x / 2] ^ 3], x∈Reals && -1 < x < 1]

Ceilingを含む式を簡約する：

Wolfram Language code: Reduce[Ceiling[x + (1/2)] == 2 Ceiling[x]∧-1 < x < 1 , {x}, Reals]

複素平面上のCeiling関数：

Wolfram Language code: DensityPlot[Abs[Ceiling[x + I y]], {x, -3, 3}, {y, -3, 3}]

CeilingはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[Ceiling[k], k]
Wolfram Language code: DifferenceRootReduce[Ceiling[k, 3], k]

Ceilingの母関数：

Wolfram Language code: GeneratingFunction[Ceiling[n, 4], n, x]
Wolfram Language code: Series[%, {x, 0, 10}]

Ceilingの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Ceiling[n, 4], n, x]

考えられる問題  (1)

Ceilingは自動的に値を結合しない：

Wolfram Language code: Ceiling[π ^ 2 + 2π + 1 - (π + 1) ^ 2]
Wolfram Language code: Simplify[%]

おもしろい例題  (1)

Ceilingのフーリエ(Fourier)級数の収束：

Wolfram Language code: Plot[Evaluate[Table[x + 1 / 2 + Sum[Sin[2Pi k x] / k, {k, 1, o}] / Pi, {o, 10}]], {x, -2, 2}]
Wolfram Research (1988), Ceiling, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ceiling.html （2007年に更新）.

テキスト

Wolfram Research (1988), Ceiling, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ceiling.html （2007年に更新）.

CMS

Wolfram Language. 1988. "Ceiling." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Ceiling.html.

APA

Wolfram Language. (1988). Ceiling. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ceiling.html

BibTeX

@misc{reference.wolfram_2026_ceiling, author="Wolfram Research", title="{Ceiling}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Ceiling.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ceiling, organization={Wolfram Research}, title={Ceiling}, year={2007}, url={https://reference.wolfram.com/language/ref/Ceiling.html}, note=[Accessed: 06-September-2026]}