WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChannelSend[channel,msg]

指定のメッセージ msg を指定のチャネルに送る．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ChannelSend

ChannelSend[channel,msg]

指定のメッセージ msg を指定のチャネルに送る．

詳細とオプション

  • ChannelSend[channel,…]では，channel はチャネルオブジェクトとして，あるいはChannelObject内で使われている任意の形で指定することができる．
  • メッセージ msg は任意の式でよい．
  • デフォルト設定の$AllowExternalChannelFunctions=Falseでは，ChannelSend[channel,…]は認定チャネルとユーザ所有のチャネルにしか使えない．
  • すべてのメッセージは，チャネルブローカサーバを介して送信される前に内部でWXFにシリアル化される．ただし，そのままの文字列はそのまま送信される．
  • 将来リリースされる可能性のあるWolfram言語ベースっではないチャネルブローカクライアントは，文字列メッセージのみをサポートする可能性が高いため，プログラムのメッセージをそのようなクライアントと前方互換にする場合は，JSONやXMLのような言語に依存しない文字列形式で符号化することが推奨される．
  • ChannelSendはメッセージがブローカに送信されるまでブロックするだけである．ブローカの受領を確認するまで待機はしない．

例題

すべて開く すべて閉じる

例  (1)

チャネルを聞き始め，そのチャネルにメッセージを送る：

Wolfram Language code: CreateChannel["example"]; listener = ChannelListen["example"]

チャネルにメッセージを送る：

Wolfram Language code: ChannelSend["example", "message"]

ChannelListenerオブジェクトのために指定されたフォームを使ったリスナからのメッセージも可能である：

Wolfram Language code: listener["Message"]

チャネルを削除する：

Wolfram Language code: DeleteChannel["example"];

スコープ  (2)

メッセージを連想として送る：

Wolfram Language code: CreateChannel["example"]; ChannelSend["example", <|"a" -> 1|>]

規則あるいは規則のリストとして送る：

Wolfram Language code: ChannelSend["example", "a" -> 1]
Wolfram Language code: ChannelSend["example", {"a" -> 1, "b" -> 2}]

任意のWolfram言語コードとして送る：

Wolfram Language code: ChannelSend["example", Unevaluated[Speak["hello"]]]

現行のノートブックを送る：

Wolfram Language code: ChannelSend["example", NotebookGet[InputNotebook[]]]

完了する：

Wolfram Language code: DeleteChannel["example"];

JSON文字列として符号化されたデータを送信するチャネルを作る：

Wolfram Language code: CreateChannel["json"]

チャネルを聞き始める：

Wolfram Language code: listener = ChannelListen["json"]

データを符号化して送信する：

Wolfram Language code: mydata = <| "string" -> "hello world", "integer" -> 42, "real" -> 1.21, "list" -> {"one", 2, 3.4}, "association" -> <|"key" -> "value"|> |>; ChannelSend["json", ExportString[mydata, "RawJSON"]]

受信されたデータを取り出して復号化する：

Wolfram Language code: listener["Message"]
Wolfram Language code: ImportString[%, "RawJSON"]

完了する：

Wolfram Language code: DeleteChannel["json"];

アプリケーション  (1)

圧縮したノートブックを受信して新規ウィンドウで開くチャネルリスナ：

Wolfram Language code: CreateChannel["nb"]; listener = ChannelListen["nb", CreateWindow[ReleaseHold[#Message]]&]

ノートブックを作成し，そのチャネルに送る：

Wolfram Language code: nb = DocumentNotebook[{TextCell["My Notebook", "Title"], ExpressionCell[x ^ 2, "Input"]}]
Wolfram Language code: ChannelSend["nb", nb]

受け取ったノートブック：

完了する：

Wolfram Language code: DeleteChannel["nb"];

特性と関係  (2)

ChannelSendで送られたメッセージは，ChannelListenで作ったリスナで受け取ることができる：

Wolfram Language code: CreateChannel["example"]; listener = ChannelListen["example"]

完了する：

Wolfram Language code: DeleteChannel["example"];

ChannelSendが送信したメッセージは，セキュリティのために，内容によってはチャネルリスナによって未評価のままで置かれるかもしれない：

Wolfram Language code: CreateChannel["example"]; listener = ChannelListen["example"]; Scan[ChannelSend["example", #]&, {123, myFunction[1]}]

myFunctionへの呼び出しは HoldComplete でラップされて読まれる：

Wolfram Language code: listener["Message", All]

完了する：

Wolfram Language code: DeleteChannel["example"];

考えられる問題  (1)

ChannelSendは非同期に戻るため，チャネルに送信されたメッセージをそのチャネルに接続されたリスナが直ちに利用できるわけではない：

Wolfram Language code: channel = CreateChannel["x"]; listener = ChannelListen[channel];

メッセージを送信し，直ちにリスナから取り出そうとする：

Wolfram Language code: ChannelSend[channel, "hello"]; listener["Message"]

メッセージの送信後に短いポーズを挟むと，リスナがメッセージを受信する時間ができる：

Wolfram Language code: ChannelSend[channel, "world"]; Pause[0.1]; listener["Message"]

Whileループを使ってメッセージがリスナから利用できるようになるまで待つこともできる：

Wolfram Language code: receivedQ = False; listener2 = ChannelListen[channel, (receivedQ = True)&]; ChannelSend[channel, "world"]; While[!receivedQ, Pause[.001]]; listener2["Message"]

完了する：

Wolfram Language code: DeleteChannel[channel];
Wolfram Research (2016), ChannelSend, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChannelSend.html （2020年に更新）.

テキスト

Wolfram Research (2016), ChannelSend, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChannelSend.html （2020年に更新）.

CMS

Wolfram Language. 2016. "ChannelSend." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/ChannelSend.html.

APA

Wolfram Language. (2016). ChannelSend. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChannelSend.html

BibTeX

@misc{reference.wolfram_2026_channelsend, author="Wolfram Research", title="{ChannelSend}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ChannelSend.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_channelsend, organization={Wolfram Research}, title={ChannelSend}, year={2020}, url={https://reference.wolfram.com/language/ref/ChannelSend.html}, note=[Accessed: 15-August-2026]}