Wolfram 语言与系统参考资料中心

Chebyshev1FilterModel

Chebyshev1FilterModel[n]

创建阶数为 n 的第一类切比雪夫低通滤波器.

Chebyshev1FilterModel[{n,ω_c}]

使用截止频率 ω_c.

Chebyshev1FilterModel[{"type",spec}]

使用指定参数 spec 设计已知 "type" 的滤波器.

Chebyshev1FilterModel[{"type",spec},var]

以变量 var 的形式表示模型.

范例

打开所有单元关闭所有单元

基本范例 (2)

三阶第一类切比雪夫滤波器模型：

Wolfram Language code: tf = Chebyshev1FilterModel[3]

用变量表示滤波器模型：

Wolfram Language code: tf = Chebyshev1FilterModel[3, s]

所模拟的滤波器的波特幅值图：

Wolfram Language code: BodePlot[tf, GridLines -> Automatic, PlotLayout -> "Magnitude"]

使用完整规范设计第一类切比雪夫低通滤波器：

Wolfram Language code: tf = Chebyshev1FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}, s]//Chop

显示理想滤波器特征的幅值响应：

Wolfram Language code:

Plot[Abs[tf[I * ω]], {ω, 0, 3}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, 0.89}, {1, 0.89}, {1, 0.1}}], Line[{{2., 0.89}, {2., 0.1}, {3., 0.1}}]}]

范围 (5)

创建一个符号切比雪夫 1 型低通滤波器模型：

Wolfram Language code: Chebyshev1FilterModel[{2, ω}, s]//N

提取模型的计算：

Wolfram Language code: Chebyshev1FilterModel[{2, 1}, s]

用 24 位精度计算模型：

Wolfram Language code: Chebyshev1FilterModel[{2, N[1, 24]}, s]

设计第一类切比雪夫高通滤波器：

Wolfram Language code: BodePlot[Chebyshev1FilterModel[{"Highpass", {1., 2.}, {20., 1.}}], GridLines -> Automatic, PlotLayout -> "Magnitude"]

设计通带频率为 1 和 10 的 3 阶带通滤波器：

Wolfram Language code: BodePlot[Chebyshev1FilterModel[{"Bandpass", 3, {1, 10}}], {0.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

使用中心频率 1 和品质因数 1/3：

Wolfram Language code:

BodePlot[Chebyshev1FilterModel[{"Bandpass", 3, {{1, 1 / 3}}}], {0.01, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

使用完整规范设计第一类切比雪夫带通滤波器：

Wolfram Language code: tf = Chebyshev1FilterModel[{"Bandpass", {0.1, 1., 10., 100.}, {60, -20Log10[1 / Sqrt[2]]}}];

Wolfram Language code: BodePlot[tf, {0.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

创建一个带阻滤波器，其通带频率为 1 和 10，衰减阶数为 3：

Wolfram Language code: BodePlot[Chebyshev1FilterModel[{"Bandstop", 3, {1, 10}}], {0.1, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

使用中心频率 1 和品质因数 1/3：

Wolfram Language code:

BodePlot[Chebyshev1FilterModel[{"Bandstop", 3, {{1, 1 / 3}}}], {0.01, 100}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

给出详细指定，创建一个切比雪夫 1 型带阻滤波器：

Wolfram Language code:

tf = Chebyshev1FilterModel[{"Bandstop", {0.1, 1., 10., 100.}, {1, 20}}];
BodePlot[tf, {0.01, 1000.}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

应用 (5)

设计第一类切比雪夫低通滤波器：

Wolfram Language code: tf = Chebyshev1FilterModel[{"Lowpass", {1., 2.}, {1, 40}}];

滤除正弦信号中的高频噪声：

Wolfram Language code:

ω = 1 / 5;input = (Sin[ω t] + 1 / 2 Sin[25ω t]) UnitStep[t];
response1 = OutputResponse[tf, input, {t, 0, 100}][[1]];

第一类切比雪夫滤波器把响应的相位平移了 Arg[tf[ω ]]，其中 ω 是输入正弦波的频率：

Wolfram Language code: Plot[{input, response1}, {t, 20, 100}]

对相位平移进行校正：

Wolfram Language code:

delay = Arg[tf[I ω]] / ω//First//First;
Plot[Evaluate[Flatten[{input, response1 /. t -> (t - delay)}]], {t, 20, 100}]

根据低通原型设计第一类切比雪夫高通滤波器：

Wolfram Language code: tf2 = TransferFunctionTransform[1 / #&, tf];

滤除输入中的低频正弦波：

Wolfram Language code: Plot[Evaluate[Flatten[{input, OutputResponse[tf2, input, {t, 0, 100}]}]], {t, 20, 100}]

用 Chebyshev 1 型近似设计一个数字低通滤波器，满足以下通带和阻带频率以及衰减要求：

Wolfram Language code:

Subscript[ω, p] = 0.4π;Subscript[ω, s] = 0.6π;
Subscript[a, p] = 1;Subscript[a, s] = 20;

假定采样周期为 1，获取等价模拟频率：

Wolfram Language code: {Subscript[Ω, p] = 2 Tan[(0.4π/2)], Subscript[Ω, s] = 2 Tan[(0.6π/2)]}

计算模拟 Chebyshev 1 型转换函数：

Wolfram Language code: tf = Chebyshev1FilterModel[{"Lowpass", {Subscript[Ω, p], Subscript[Ω, s]}, {Subscript[a, p], Subscript[a, s]}}, s]

转换成离散时间模型：

Wolfram Language code: dtf = ToDiscreteTimeModel[tf, 1, z]//Chop

绘制幅值：

Wolfram Language code:

BodePlot[dtf, {0.1 π, π}, PlotLayout -> "Magnitude", GridLines -> {{Subscript[ω, p], Subscript[ω, s]}, {10^-Subscript[a, p] / 20, 10^-Subscript[a, s] / 20}}, ScalingFunctions -> {"Linear", "Absolute"}, PlotRange -> All]

创建可以近似离散时间切比雪夫 1 型 IIR 滤波器的长度为 31 的 FIR 滤波器：

Wolfram Language code: OutputResponse[dtf, KroneckerDelta[n], {n, 0, 30}]//Chop

绘制 FIR 滤波器：

Wolfram Language code: ListPlot[%, PlotRange -> All, Filling -> 0]

用切比雪夫滤波器的 FIR 近似平滑金融数据：

Wolfram Language code:

data = Transpose[FinancialData["GE", {"Jan. 1, 2012", "Jan. 1, 2013"}]["Path"]];
fir = OutputResponse[ToDiscreteTimeModel[Chebyshev1FilterModel[{3, 1.}], 1], KroneckerDelta[n], {n, 0, 40}]//Chop//Flatten;
DateListPlot[{Transpose[data], Transpose[{data[[1]], -ListConvolve[fir, data[[2]], 4]}]}, PlotRange -> All, PlotLegends -> {"original", "smoothed"}]

使用离散时间第一类切比雪夫低通滤波器对图像进行滤波：

Wolfram Language code:

h = ToDiscreteTimeModel[Chebyshev1FilterModel[{"Lowpass", 3, 0.75}], 1];
RecurrenceFilter[h, [image]]

使用第一类切比雪夫高通滤波器对图像进行滤波：

Wolfram Language code:

h = ToDiscreteTimeModel[Chebyshev1FilterModel[{"Highpass", 3, 0.75}], 1];
RecurrenceFilter[h, [image]]

属性和关系 (8)

阻带衰减随阶数 n 的增加而增加：

Wolfram Language code:

tf = Chebyshev1FilterModel[{"Lowpass", #}]& /@ {1, 2, 3};
BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude", PlotLegends -> {1, 2, 3}]

"Bandpass" 滤波器的通带宽度随品质因数 q 的增加而减小：

Wolfram Language code:

tf = Chebyshev1FilterModel[{"Bandpass", 2, {{1, #}}}]& /@ {0.5, 1., 3.};
BodePlot[tf, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude", PlotRange -> {0, -80}, PlotLegends -> {0.5, 1., 3.}]

三阶第一类切比雪夫 "Lowpass" 滤波器的相位响应：

Wolfram Language code: BodePlot[Chebyshev1FilterModel[{"Lowpass", 3}], {0.1, 10.}, PlotLayout -> "Phase", GridLines -> Automatic]

比较不同阶数的滤波器的相位响应：

Wolfram Language code:

BodePlot[Chebyshev1FilterModel[{"Lowpass", #}]& /@ {1, 2, 3}, {0.1, 10.}, PlotLayout -> "Phase", GridLines -> Automatic, PlotLegends -> {1, 2, 3}]

品质因数不同的 "Bandpass" 滤波器的相位响应：

Wolfram Language code:

BodePlot[Chebyshev1FilterModel[{"Bandpass", 2, {{1, #}}}]& /@ {1., 3., 5.}, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Phase", PlotLegends -> {1., 3., 5.}]

比较第一类和第二类切比雪夫低通滤波器：

Wolfram Language code: t1 = Chebyshev1FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}, s]

Wolfram Language code: t2 = Chebyshev2FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}, s]

Wolfram Language code:

Plot[{Abs[t1[I * ω]], Abs[t2[I * ω]]}, {ω, 0, 3}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, 0.89}, {1, 0.89}, {1, 0.1}}], Line[{{2., 0.89}, {2., 0.1}, {3., 0.1}}]}]

提取第一类切比雪夫多项式的次数：

Wolfram Language code: SystemsModelOrder[StateSpaceModel[Chebyshev1FilterModel[{"Lowpass", {1., 2.}, {1., 20.}}]]]

求 Chebyshev 1 型滤波器的极点：

Wolfram Language code:

tfm = Chebyshev1FilterModel[11];
poles = TransferFunctionPoles[tfm]

绘制 Butterworth 滤波器的极点：

Wolfram Language code: PoleZeroPlot[tfm, ...]

实现低通数字 Chebyshev 1 型滤波器：

Wolfram Language code: dtf = ToDiscreteTimeModel[Chebyshev1FilterModel[11], 1]

绘制数字 Chebyshev 1 型滤波器的极点：

Wolfram Language code:

poles = TransferFunctionPoles[dtf];
ListPlot[{Re[#], Im[#]}& /@ poles[[1, 1]], PlotRange -> {{-1, 1}, {-1, 1}}, PlotStyle -> PointSize[Large], Epilog -> {Dotted, Circle[]}, AspectRatio -> 1]

把低通滤波器转化为高通滤波器：

Wolfram Language code:

lo = Chebyshev1FilterModel[3];
hi = TransferFunctionTransform[(1 / #&), lo];

Wolfram Language code: BodePlot[{lo, hi}, {0.1, 10}, GridLines -> Automatic, PlotLayout -> "Magnitude"]

Top

		{"Lowpass",n}	阶数为 n、截止频率为 1 的低通滤波器
		{"Lowpass",n,ω_p}	截至频率为 ω_p
		{"Lowpass",{ω_p,ω_s},{a_p,a_s}}	使用完整的滤波器规范（给出通带和阻带的截至频率和衰减）

		{"Highpass",n}	截止频率为 1 的高通滤波器
		{"Highpass",n,ω_p}	截至频率为 ω_p
		{"Highpass",{ω_s,ω_p},{a_s,a_p}}	完整的滤波器规范

		{"Bandpass",n,{ω_p₁,ω_p₂}}	通带频率为 ω_p1 和 ω_p2 的带通滤波器
		{"Bandpass",n,{{ω,q}}}	中心频率为 ω，品质因数为 q
		{"Bandpass",{ω_s1,ω_p1,ω_p2,ω_s2},{a_s,a_p}}	完整的滤波器规范

		{"Bandstop",n,{ω_p1,ω_p2}}	通带频率为 ω_p1 和 ω_p2 的带阻滤波器
		{"Bandstop",n,{{ω,q}}}	中心频率为 ω，品质因数为 q
		{"Bandstop",{ω_p1,ω_s1,ω_s2,ω_p2},{a_p,a_s}}	完整的滤波器规范

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Chebyshev1FilterModel

更多信息

范例

基本范例 (2)

范围 (5)

应用 (5)

属性和关系 (8)

文本

CMS

APA

BibTeX

BibLaTeX

Chebyshev1FilterModel

更多信息

范例

基本范例 (2)

范围 (5)

应用 (5)

属性和关系 (8)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX