WOLFRAM

Wolfram 语言与系统参考资料中心

ClipPlanes

是 Graphics3D 的一个选项，用于指定一个剪切平面的列表，可以从得到的窗口切除三维场景中的部分.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ClipPlanes

ClipPlanes

是 Graphics3D 的一个选项，用于指定一个剪切平面的列表，可以从得到的窗口切除三维场景中的部分.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

使用 ClipPlanes 指定剪切平面：

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 1, 2}}]]

为每个物体指定剪切平面：

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}, 1 / 2], Style[Sphere[], Red, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 1, 2}}]]}]

用 ClipPlanesStyle 来显示剪切平面：

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {1, 0, 1}}]}, ClipPlanesStyle -> Opacity[0.3]]

范围  (7)

用 InfinitePlane 来指定剪切平面：

Wolfram Language code: Graphics3D[{Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}]]

使用多个平面：

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}], InfinitePlane[{{0, 0, 0}, {0, 0, -1}, {1, 0, -1}}]}]

用平面方程的系数指定平面：

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {1, 1, -2, 0}]

剪切三维图像：

Wolfram Language code: Image3D[RandomReal[1, {5, 10, 10}], ClipPlanes -> InfinitePlane[{{0, 0, 0}, {1, 1, 1}, {1, 1, 0}}]]

剪切单个物体：

Wolfram Language code: Graphics3D[{Cone[], Style[Sphere[], ClipPlanes -> InfinitePlane[{{1, 0, .5}, {0, 0, 1}, {1, 1, 1}}]]}]

将 ClipPlanes 指定为一个指令：

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}], ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}}], Sphere[{1, 0, 0}]}]

为图形基元列表指定剪切平面：

Wolfram Language code: Graphics3D[{Sphere[{0, 0, 0}], Sphere[{1, 1, 0}], Style[{Sphere[{0, 1, 0}], Sphere[{1, 0, 0}]}, ClipPlanes -> InfinitePlane[{{0, 0, 0.8}, {0, 1, 0.8}, {1, 1, 0.8}}]]}]

推广和延伸  (3)

可用 ClipPlanesStyle 来设计剪切平面的样式：

Wolfram Language code: Graphics3D[{Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 0, 1}, {0, 1, 1}}], ClipPlanesStyle -> Directive[Opacity[0.5], Green]]

一系列的样式被依次应用到指定平面上：

Wolfram Language code: Graphics3D[{Sphere[]}, ClipPlanes -> {InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}}], InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {0, 1, 1}}]}, ClipPlanesStyle -> {Directive[Red, Opacity[0.3]], Directive[Green, Opacity[0.3]]}]

可以为被 Style 操作过的剪切平面单独设计样式：

Wolfram Language code: Graphics3D[{Style[Sphere[{0, 0, 0}], ClipPlanes -> InfinitePlane[{{0, 0, .5}, {0, 1, .5}, {1, 0, .5}}], ClipPlanesStyle -> Directive[Blue, Opacity[0.3]]], Style[Sphere[{1, 0, 0}], ClipPlanes -> InfinitePlane[{{0, -.5, 0}, {0, -.5, 1}, {1, -.5, 0}}], ClipPlanesStyle -> Directive[Red, Opacity[0.3]]]}]

属性和关系  (1)

可以对剪切过的基元的内部用 FaceForm 的第二个参数来添加样式：

Wolfram Language code: Graphics3D[{FaceForm[Green, Pink], Cone[]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {0, 1, 1}, {0, 1, 0}}]]

可能存在的问题  (1)

大的点或基元在旋转的时候可能会展现出无法预测的行为：

Wolfram Language code: Graphics3D[{PointSize[.5], Sphere[{.1, -.1, 0}], Point[{.1, -.1, 0}]}, ClipPlanes -> InfinitePlane[{{0, 0, 0}, {1, 1, 1}, {1, 1, 0}}]]

巧妙范例  (2)

切去球面的几个部分：

Wolfram Language code: Graphics3D[{FaceForm[Red, Blue], Sphere[{0, 0, 0}, 1.85]}, ClipPlanes -> Flatten@Table[InfinitePlane[{x, y, z}, {{x y, -x ^ 2 - z ^ 2, y z}, {-z, 0, x}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}], Axes -> True]
Wolfram Language code: Graphics3D[{FaceForm[Red, Blue], Sphere[{0, 0, 0}, 1.85]}, ClipPlanes -> Flatten@Table[InfinitePlane[{x, y, z}, {{x y, -x ^ 2 - z ^ 2, y z}, {-z, 0, x}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}], Axes -> True, ClipPlanesStyle -> GrayLevel[0.7, 0.3]]

将 ClipPlanes 应用于解剖结构：

Wolfram Language code: With[{z = 400}, AnatomyPlot3D[{Entity["AnatomicalStructure", "LeftUpperLimb"], ClipPlanes -> {InfinitePlane[{{0, -300, z}, {300, -300, z + 200}, {200, 0, z}}]}, Entity["AnatomicalStructure", "SkinOfLeftUpperLimb"]}]]
Wolfram Research (2014)，ClipPlanes，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClipPlanes.html （更新于 2016 年）.

文本

Wolfram Research (2014)，ClipPlanes，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClipPlanes.html （更新于 2016 年）.

CMS

Wolfram 语言. 2014. "ClipPlanes." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/ClipPlanes.html.

APA

Wolfram 语言. (2014). ClipPlanes. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ClipPlanes.html 年

BibTeX

@misc{reference.wolfram_2026_clipplanes, author="Wolfram Research", title="{ClipPlanes}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ClipPlanes.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clipplanes, organization={Wolfram Research}, title={ClipPlanes}, year={2016}, url={https://reference.wolfram.com/language/ref/ClipPlanes.html}, note=[Accessed: 13-September-2026]}