WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ColumnwiseValue[cbody]

関数本体の一部である cbody は，TransformColumnsあるいはTransformColumns演算で行を変換するためにこの関数を使う前に，列ごとに一度評価されることを示す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ColumnwiseValue

ColumnwiseValue[cbody]

関数本体の一部である cbody は，TransformColumnsあるいはTransformColumns演算で行を変換するためにこの関数を使う前に，列ごとに一度評価されることを示す．

詳細

  • ColumnwiseValueは，通常，表形式データの変換を行う前に，部分的な結果を事前計算するために，Function本体の一部として使われる．
  • Function[head[…,ColumnwiseValue[cbody],…]]でTabularオブジェクト tab を変換する際，cbody 中の #colの任意のインスタンスが列全体で置換され(tab[[All,col]])，値 cval を得るために評価される．変換関数はFunction[head[…,cval,…]]になる．

例題

すべて開く すべて閉じる

例  (1)

列の平均を計算し，列のすべての項目からこれを引く：

Wolfram Language code: Tabular[{{1}, {2}, {3}}, {"col"}]
Wolfram Language code: TransformColumns[%, "new" -> Function[#col - ColumnwiseValue[Mean[#col]]]]

スコープ  (2)

ColumnwiseValueを使って列の平均をその値から引く：

Wolfram Language code: tab = ToTabular[<|"c" -> {3.71, -2.7, -5.29, 9.33, 6.26}|>, "Columns"]
Wolfram Language code: ConstructColumns[tab, "c-μ" -> (#c - ColumnwiseValue[Mean[#c]]&)]

これは，最初に一度平均値を計算し次に各行からこれを引くことに等しい：

Wolfram Language code: mean = Mean[tab[[All, 1]]]
Wolfram Language code: ConstructColumns[tab, "c-μ" -> (#c - mean&)]

列中のどの要素が中央値より上であるかを求める：

Wolfram Language code: tab = ToTabular[<|"c" -> {4.24, 1.14, -7.38, 6.74, 6.22, 7.5}|>, "Columns"];TransformColumns[tab, "above median" -> (#c > ColumnwiseValue[Median[#c]]&)]

中央値を持つ一定の値の列を含める：

Wolfram Language code: TransformColumns[tab, {"median" -> (ColumnwiseValue[Median[#c]]&), "above median" -> (#c > ColumnwiseValue[Median[#c]]&)}]

演算子形を使って中央値を一度だけ計算する：

Wolfram Language code: (TransformColumns["median" -> (ColumnwiseValue[Median[#c]]&)] /* TransformColumns["above_median" -> (#c > #median&)])[tab]

アプリケーション  (1)

数のTabularオブジェクトを取得する：

Wolfram Language code: tab = ToTabular[<|"obs" -> RandomReal[{-10, 10}, 5]|>, "Columns"]

列全体を操作して"obs"列を標準化する：

Wolfram Language code: TransformColumns[tab, "z-score" -> Function[ColumnwiseValue[Standardize[#obs]]]]

特性と関係  (2)

ColumnwiseThreadを使って列全体のベクトル値変換を計算する：

Wolfram Language code: tab = ToTabular[<|"v" -> {2.07, -0.75, 4.16, 7.28, 8.63, 7.93}|>, "Columns"]; ConstructColumns[tab, "z" -> (ColumnwiseThread[Accumulate[#v]]&)]

ColumnwiseValueを使うと，各行について同じリストが得られる：

Wolfram Language code: ConstructColumns[tab, "zlist" -> (ColumnwiseValue[Accumulate[#v]]&)]

Tabularオブジェクトを取る：

Wolfram Language code: tab = ToTabular[{"old" -> {a, b, c}}, "Columns"]

TransformColumnsは，デフォルトで，各行を連続的に操作する：

Wolfram Language code: TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + Echo[RandomInteger[5], " random: "]]]

TransformColumnsとColumnwiseValue[expr]を使うと，まず expr を一度だけ評価して次に各行を処理する：

Wolfram Language code: TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + ColumnwiseValue[Echo[Total[#old], "total: "]]]]

TransformColumnsとColumnwiseThread[expr]を使うと，expr を一度評価して，列全体を処理する：

Wolfram Language code: TransformColumns[tab, "new" -> Function[ColumnwiseThread[Echo[#old, "column: "] + Echo[RandomInteger[5], " random: "]]]]
Wolfram Research (2025), ColumnwiseValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

テキスト

Wolfram Research (2025), ColumnwiseValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

CMS

Wolfram Language. 2025. "ColumnwiseValue." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

APA

Wolfram Language. (2025). ColumnwiseValue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ColumnwiseValue.html

BibTeX

@misc{reference.wolfram_2026_columnwisevalue, author="Wolfram Research", title="{ColumnwiseValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnwiseValue.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_columnwisevalue, organization={Wolfram Research}, title={ColumnwiseValue}, year={2025}, url={https://reference.wolfram.com/language/ref/ColumnwiseValue.html}, note=[Accessed: 07-September-2026]}