WOLFRAM

Wolfram 语言与系统参考资料中心

ColumnwiseValue[cbody]

表示在 TransformColumns 或 ConstructColumns 运算中使用函数对行进行转换之前，先以列的形式对 cbody（函数主体的一部分）进行计算.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ColumnwiseValue

ColumnwiseValue[cbody]

表示在 TransformColumns 或 ConstructColumns 运算中使用函数对行进行转换之前，先以列的形式对 cbody（函数主体的一部分）进行计算.

更多信息

  • ColumnwiseValue 通常用作对表格数据进行转换的 Function 主体的一部分，以便预先计算出部分结果.
  • 用 Function[head[…,ColumnwiseValue[cbody],…]] 对 Tabular 对象 tab 进行转换时，cbody 中的 #col 将被替换为整个列 tab[[All,col]]，然后进行计算，得到 cval. 转换方程变为 Function[head[…,cval,…]].

范例

打开所有单元 关闭所有单元

基本范例  (1)

计算一列的均值，然后该列的所有元素都减去该均值：

Wolfram Language code: Tabular[{{1}, {2}, {3}}, {"col"}]
Wolfram Language code: TransformColumns[%, "new" -> Function[#col - ColumnwiseValue[Mean[#col]]]]

范围  (2)

用 ColumnwiseValue 使该列的所有元素都减去该列的均值：

Wolfram Language code: tab = ToTabular[<|"c" -> {3.71, -2.7, -5.29, 9.33, 6.26}|>, "Columns"]
Wolfram Language code: ConstructColumns[tab, "c-μ" -> (#c - ColumnwiseValue[Mean[#c]]&)]

这相当于先计算均值，然后在每一行中减去均值：

Wolfram Language code: mean = Mean[tab[[All, 1]]]
Wolfram Language code: ConstructColumns[tab, "c-μ" -> (#c - mean&)]

找出一个列中哪些元素大于中位数：

Wolfram Language code: tab = ToTabular[<|"c" -> {4.24, 1.14, -7.38, 6.74, 6.22, 7.5}|>, "Columns"];TransformColumns[tab, "above median" -> (#c > ColumnwiseValue[Median[#c]]&)]

将中位数包括在一个新的列中：

Wolfram Language code: TransformColumns[tab, {"median" -> (ColumnwiseValue[Median[#c]]&), "above median" -> (#c > ColumnwiseValue[Median[#c]]&)}]

使用算符形式只计算中位数一次：

Wolfram Language code: (TransformColumns["median" -> (ColumnwiseValue[Median[#c]]&)] /* TransformColumns["above_median" -> (#c > #median&)])[tab]

应用  (1)

取一个由数字构成的 Tabular 对象：

Wolfram Language code: tab = ToTabular[<|"obs" -> RandomReal[{-10, 10}, 5]|>, "Columns"]

对整个列进行操作，标准化 "obs" 列：

Wolfram Language code: TransformColumns[tab, "z-score" -> Function[ColumnwiseValue[Standardize[#obs]]]]

属性和关系  (2)

用 ColumnwiseThread 对整个列中的元素进行向量转换：

Wolfram Language code: tab = ToTabular[<|"v" -> {2.07, -0.75, 4.16, 7.28, 8.63, 7.93}|>, "Columns"]; ConstructColumns[tab, "z" -> (ColumnwiseThread[Accumulate[#v]]&)]

通过 ColumnwiseValue，每一行也可得到相同的列表：

Wolfram Language code: ConstructColumns[tab, "zlist" -> (ColumnwiseValue[Accumulate[#v]]&)]

取一个 Tabular 对象：

Wolfram Language code: tab = ToTabular[{"old" -> {a, b, c}}, "Columns"]

默认情况下，TransformColumns 依次对每一行进行计算：

Wolfram Language code: TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + Echo[RandomInteger[5], " random: "]]]

TransformColumns 与 ColumnwiseValue[expr] 一起使用时，先对 expr 进行计算，然后对每一行进行计算：

Wolfram Language code: TransformColumns[tab, "new" -> Function[Echo[#old, "row: "] + ColumnwiseValue[Echo[Total[#old], "total: "]]]]

TransformColumns 与 ColumnwiseThread[expr] 一起使用时，先对 expr 进行计算，然后同时计算整个列：

Wolfram Language code: TransformColumns[tab, "new" -> Function[ColumnwiseThread[Echo[#old, "column: "] + Echo[RandomInteger[5], " random: "]]]]
Wolfram Research (2025)，ColumnwiseValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

文本

Wolfram Research (2025)，ColumnwiseValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

CMS

Wolfram 语言. 2025. "ColumnwiseValue." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ColumnwiseValue.html.

APA

Wolfram 语言. (2025). ColumnwiseValue. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ColumnwiseValue.html 年

BibTeX

@misc{reference.wolfram_2026_columnwisevalue, author="Wolfram Research", title="{ColumnwiseValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/ColumnwiseValue.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_columnwisevalue, organization={Wolfram Research}, title={ColumnwiseValue}, year={2025}, url={https://reference.wolfram.com/language/ref/ColumnwiseValue.html}, note=[Accessed: 16-September-2026]}