WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CompoundRenewalProcess[rdist,jdist]

再生時間分布 rdist，ジャンプサイズ分布 jdist の合成再生過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CompoundRenewalProcess

CompoundRenewalProcess[rdist,jdist]

再生時間分布 rdist，ジャンプサイズ分布 jdist の合成再生過程を表す．

詳細

  • CompoundRenewalProcessはまた，再生報酬過程あるいは累積再生過程としても知られている．
  • CompoundRenewalProcessは，連続 rdist の連続時間過程，離散 rdist の離散時間過程，連続 jdist の連続状態過程，そして離散 jdist の離散状態過程である．
  • 分布 rdist は非負の領域を持つ任意の一変量分布でよい．分布 jdist は任意の一変量分布でよい．
  • 時間 における状態は で与えられる．ただし， は独立同分布の確率変数で jdist に従い， はRenewalProcess[jdist]に従う．
  • CompoundRenewalProcessは，Mean，Variance，RandomFunction等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (1)

ガンマ再生時間と指数ジャンプを持つ合成再生過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundRenewalProcess[GammaDistribution[.3, 1.7], ExponentialDistribution[0.3]];
Wolfram Language code: data = RandomFunction[𝒫, {50}]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

スコープ  (3)

離散ジャンプを持つ合成再生過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundRenewalProcess[GammaDistribution[2, .7], GeometricDistribution[.4]];
Wolfram Language code: data = RandomFunction[𝒫, {30}, 4]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

連続ジャンプを持つ合成再生過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundRenewalProcess[GammaDistribution[2, .3], NormalDistribution[0, 2]];
Wolfram Language code: data = RandomFunction[𝒫, {30}, 4]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

過程母数推定：

Wolfram Language code: sample = RandomFunction[CompoundRenewalProcess[BorelTannerDistribution[.3, 4], GammaDistribution[2, 5]], {1, 10 ^ 3}];

サンプルデータから分布母数を推定する：

Wolfram Language code: EstimatedProcess[sample, CompoundRenewalProcess[BorelTannerDistribution[p, n], GammaDistribution[a, b]]]

アプリケーション  (2)

改装開店した商店に，形状母数2，速度母数30のアーラン分布に従って顧客が来店する．この商店は，販売促進の一環として，来店客全員に粗品を贈呈している．粗品の値は，形状母数14，尺度母数3のWeibullDistributionに従う．改装開店初日の営業時間である12時間について，粗品にかかる費用の過程のシミュレーションを行い，費用総額の期待値を求める：

Wolfram Language code: giftProcess = CompoundRenewalProcess[ErlangDistribution[2, 30], WeibullDistribution[14, 3]];

この過程のシミュレーションを12時間行う：

Wolfram Language code: data = RandomFunction[giftProcess, {12}, 3];
Wolfram Language code: ListStepPlot[data]

初日に贈られる粗品の費用総額の期待値：

Wolfram Language code: Mean[N@giftProcess[12]]

粗品費用の分布のシミュレーションを行う：

Wolfram Language code: data1 = RandomVariate[giftProcess[12], 10 ^ 3];

経験的確率密度関数：

Wolfram Language code: Histogram[data1, 50, "PDF"]

商店が450ドルから600ドルを粗品に費やす経験的確率：

Wolfram Language code: Probability[450 < p < 600, pdata1]//N

ステップがNormalDistributionに従うランダムウォーク過程を定義する：

Wolfram Language code: proc = CompoundRenewalProcess[PascalDistribution[1, 1], NormalDistribution[.2, 1.3]];

シミュレーションを行う：

Wolfram Language code: sample = RandomFunction[proc, {100}]
Wolfram Language code: ListLinePlot[sample]

平均値関数：

Wolfram Language code: Mean[proc[t]]

特性と関係  (3)

CompoundRenewalProcessはジャンプ過程である：

Wolfram Language code: proc = CompoundRenewalProcess[BorelTannerDistribution[.1, 2], NormalDistribution[]];
Wolfram Language code: path = RandomFunction[proc, {40}]; f = path["PathFunction"]; jumps = path["Times"];
Wolfram Language code: Plot[f[t], {t, 0, 40}, Exclusions -> jumps, ExclusionsStyle -> Red]

合成更新過程は弱定常ではない：

Wolfram Language code: WeakStationarity[CompoundRenewalProcess[BorelTannerDistribution[.3, 4], PascalDistribution[3, .4]]]

BinomialProcessは，合成更新過程の特殊ケースである：

Wolfram Language code: proc = CompoundRenewalProcess[PascalDistribution[1, p], BernoulliDistribution[1]];

平均値関数は一致する：

Wolfram Language code: proc[t]//Mean
Wolfram Language code: Mean[BinomialProcess[p][t]]

経験的共分散関数を作る：

Wolfram Language code: sample1 = RandomFunction[proc /. p -> .3, {30}, 10 ^ 3];
Wolfram Language code: cov1[s_, t_] := Covariance[sample1["SliceData", s], sample1["SliceData", t]]
Wolfram Language code: sample2 = RandomFunction[BinomialProcess[.3], {0, 30}, 10 ^ 3];
Wolfram Language code: cov2[s_, t_] := Covariance[sample2["SliceData", s], sample2["SliceData", t]]

共分散関数を比較する：

Wolfram Language code: DiscretePlot3D[#[s, t], {s, 1, 15}, {t, 1, 15}, ExtentSize -> 1 / 2, ColorFunction -> "Rainbow", PlotRange -> {0, 4}]& /@ {cov1, cov2}
Wolfram Research (2012), CompoundRenewalProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html.

テキスト

Wolfram Research (2012), CompoundRenewalProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html.

CMS

Wolfram Language. 2012. "CompoundRenewalProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html.

APA

Wolfram Language. (2012). CompoundRenewalProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html

BibTeX

@misc{reference.wolfram_2026_compoundrenewalprocess, author="Wolfram Research", title="{CompoundRenewalProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_compoundrenewalprocess, organization={Wolfram Research}, title={CompoundRenewalProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/CompoundRenewalProcess.html}, note=[Accessed: 16-September-2026]}