WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Confirm[expr]

expr が失敗とはみなされないことを確認する．その他の場合は囲い込んでいる直近のEncloseにエラーをスローする．

Confirm[expr,info]

expr が確認されなければ info を評価して，スローするエラーにその結果を含める．

Confirm[expr,info,tag]

スローする任意のエラーに指定されたタグを使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

Confirm

Confirm[expr]

expr が失敗とはみなされないことを確認する．その他の場合は囲い込んでいる直近のEncloseにエラーをスローする．

Confirm[expr,info]

expr が確認されなければ info を評価して，スローするエラーにその結果を含める．

Confirm[expr,info,tag]

スローする任意のエラーに指定されたタグを使う．

詳細

  • Confirm[expr,…]は，expr の確認に成功した場合は expr を返す．
  • Confirm[expr,…]は，expr が以下のいずれかの形を含む場合は expr が失敗であるとみなし，エラーをスローする．
  • Failure[…]
    Missing[…]
    $Failed
    $Canceled
    $Aborted
  • Confirmは，タグが与えられた場合はスコープが動的になり，それ以外の場合はスコープが語彙的になる． »
  • info のデフォルト値はNullである．
  • expr は，info がNullで exprが以前の確認関数からのFailureである場合以外は，スローされる前にFailureで包み込まれる． »
  • Confirmによって生成されたFailureオブジェクトには以下のフィールドが含まれる．
  • "Information"Confirm[expr,info,…]からの info
    "Expression"Confirm[expr,…]からの expr
  • これらのフィールドの値は failure["prop"]を使ってあるいは直接Enclose[expr,"prop"]から取り出すことができる．

例題

すべて開く すべて閉じる

例  (2)

Confirm[expr]は，expr が失敗とはみなされないときは expr を与える：

Wolfram Language code: Enclose[f[x, Confirm[y], z]]

Confirmは，失敗に遭遇すると，評価を中止して囲い込んでいるEncloseにエラーをスローする：

Wolfram Language code: Enclose[f[x, Confirm[$Failed], z]]

引数の失敗を伝播する関数を定義する：

Wolfram Language code: addtwo[x_] := Enclose[Confirm[x] + 2]
Wolfram Language code: addtwo[4]
Wolfram Language code: addtwo[Missing[]]

スコープ  (4)

Confirmは，エラーをスローするときは，評価を中止して一致するEncloseを返す：

Wolfram Language code: Enclose[Echo[1];Confirm[$Failed];Echo[2]]

info は expr が確認できない場合にしか評価されない：

Wolfram Language code: Enclose[Confirm[2, Echo["info was evaluated"]]]
Wolfram Language code: Enclose[Confirm[$Failed, Echo["info was evaluated"]]]

動的にキャッチされるようにタグでConfirmを呼び出す関数を作成する：

Wolfram Language code: f[x_] := g[3 + Confirm[x, Null, "fooTag"]]
Wolfram Language code: h[y_] := Enclose[f[y], Identity, "fooTag"]
Wolfram Language code: h[2]
Wolfram Language code: h[$Canceled]

タグがない場合はConfirmのスコープは語彙的になる：

Wolfram Language code: f2[x_] := g[3 + Confirm[x]]
Wolfram Language code: h2[y_] := Enclose[f2[y]]
Wolfram Language code: h2[2]

失敗は，別の確認関数にスローされたとき以外は，スローされる前にFailureで包み込まれる：

Wolfram Language code: Enclose[Confirm[Missing[]]]
Wolfram Language code: Enclose[Confirm[%]]

info がNullではないときは，この動作は無効になる：

Wolfram Language code: Enclose[Confirm[%, "foo"]]

アプリケーション  (1)

失敗が検出されるとメッセージが出力される：

Wolfram Language code: mountainElevation::inv = "Could not interpret `` as a mountain.";
Wolfram Language code: mountainElevation[name_] := Enclose[ Confirm[Interpreter["Mountain"][name], Message[mountainElevation::inv, name]]["Elevation"], $Failed&]
Wolfram Language code: mountainElevation["k2"]
Wolfram Language code: mountainElevation[π]

特性と関係  (1)

ConfirmはConfirmByでエミュレートできる：

Wolfram Language code: Enclose[f[Confirm[Missing[]]]]
Wolfram Language code: Enclose[f[ConfirmBy[Missing[], # =!= $Canceled && !FailureQ[#] && !MissingQ[#]&]]]

考えられる問題  (3)

Confirmは，タグを与えるか語彙のEncloseの中に置くかしなければならない：

Wolfram Language code: Confirm[2]

タグがないConfirmは，シンボルConfirmのインスタンスをタグが付いたバリアントで置換することで機能する：

Wolfram Language code: Enclose[Hold[Confirm]]

タグ付きのConfirmには，一致するタグを持つEncloseが必要である：

Wolfram Language code: Enclose[Confirm[$Failed, Null, "foo"], Identity, "bar"]
Wolfram Research (2020), Confirm, Wolfram言語関数， https://reference.wolfram.com/language/ref/Confirm.html.

テキスト

Wolfram Research (2020), Confirm, Wolfram言語関数， https://reference.wolfram.com/language/ref/Confirm.html.

CMS

Wolfram Language. 2020. "Confirm." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Confirm.html.

APA

Wolfram Language. (2020). Confirm. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Confirm.html

BibTeX

@misc{reference.wolfram_2026_confirm, author="Wolfram Research", title="{Confirm}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Confirm.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_confirm, organization={Wolfram Research}, title={Confirm}, year={2020}, url={https://reference.wolfram.com/language/ref/Confirm.html}, note=[Accessed: 13-September-2026]}