WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Conjugate[z]

または zは，複素数 z の複素共役を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Conjugate

Conjugate[z]

または zは，複素数 z の複素共役を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • は，co，conjあるいは\[Conjugate]として入力できる．
  • Conjugateは自動的にリストに縫い込まれる． »
  • ConjugateはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: Conjugate[1 + I]

conjを使って式を共役にする：

Wolfram Language code: (1 + I)

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Conjugate[x], {x, -3, 3}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Conjugate[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

スコープ  (24)

数値評価  (6)

数値的に評価する：

Wolfram Language code: Conjugate[.7]

複素数入力：

Wolfram Language code: Conjugate[.5 + I]

高精度で評価する：

Wolfram Language code: N[Conjugate[2 / 3 + I], 25]

出力精度は入力精度に従う：

Wolfram Language code: Conjugate[2.3000000000000000000000000 - 1 / I]

高精度で効率的に評価する：

Wolfram Language code: Conjugate[I + 1 / 3`100]//Timing
Wolfram Language code: Conjugate[5 I + 11 / 7`10000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Conjugate[{{1 / 2, -1 - I}, {-5 / 3, 1 / 2 + I}}]

MatrixFunctionを使って行列のConjugate関数を計算することもできる：

Wolfram Language code: MatrixFunction[Conjugate, {{1 / 2, -1 - I}, {-5 / 3, 1 / 2 + I}}]//FullSimplify

ConjugateはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: Conjugate[Interval[{-5, 5}]]
Wolfram Language code: Conjugate[CenteredInterval[-5 - 3I, 1 + I]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Conjugate[ Around[-1.1 + I, 0.01]]

特定の値  (3)

固定点におけるConjugateの値：

Wolfram Language code: Table[Conjugate[n ], {n, {2I , -1 / 3, 3 + 4I}}]

ゼロにおける値：

Wolfram Language code: Conjugate[0]

無限大における値：

Wolfram Language code: Conjugate[I Infinity]
Wolfram Language code: Conjugate[ComplexInfinity]

可視化  (4)

実数値上で と の実部と虚部をプロットする：

Wolfram Language code: ReImPlot[{x + I, Conjugate[x + I]}, {x, -3, 3}, PlotLegends -> Automatic]

関数の絶対値をプロットする：

Wolfram Language code: Plot[Abs[Conjugate[x + I]], {x, -3, 3}]

と TemplateBox[{z}, Conjugate]の三次元プロットを比較する：

Wolfram Language code: GraphicsRow[ComplexPlot3D[#, {z, -2 - 2I, 2 + 2I}, Mesh -> Automatic, RegionFunction -> Function[{z}, Abs[z] ≤ 2]]& /@ {z, Conjugate[z]}, ImageSize -> Medium]

関数の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Conjugate[z ^ 2]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

関数の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Conjugate[z ^ 2]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

関数の特性  (11)

Conjugateはすべての実数および虚数の入力について定義される：

Wolfram Language code: FunctionDomain[Conjugate[x], x]
Wolfram Language code: FunctionDomain[Conjugate[x], x, Complexes]

Conjugateの値域はすべての実数値と複素数値である：

Wolfram Language code: FunctionRange[Conjugate[x], x, y]
Wolfram Language code: FunctionRange[Conjugate[x], x, y, Complexes]

Conjugateは奇関数である：

Wolfram Language code: Conjugate[-z]

Conjugateは対合である．TemplateBox[{{(, TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox], )}}, Conjugate]=z：

Wolfram Language code: Conjugate[Conjugate[z]]

Conjugateは微分可能な関数ではない：

Wolfram Language code: D[Conjugate[x], x]

差分商は複素平面上で極限を持たない：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℂ]0](Conjugate[x + h] - Conjugate[x]/h)

極限は方向によって異なる値を持つ．例えば，実数方向ではである：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℝ]0](Conjugate[1 + h] - Conjugate[1]/h)

しかし，虚数方向の極限はである：

Wolfram Language code: Limit[(Conjugate[1 + h] - Conjugate[1]/h), h -> 0, Direction -> -I]

Conjugateは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Conjugate[x], x, Complexes]

あらゆるところで特異だが，連続的である：

Wolfram Language code: FunctionSingularities[Conjugate[x], x, Complexes]
Wolfram Language code: FunctionDiscontinuities[Conjugate[x], x, Complexes]

Conjugateは実線上で非減少である：

Wolfram Language code: FunctionMonotonicity[Conjugate[x], x]

Conjugateは実線上で単射である：

Wolfram Language code: FunctionInjective[Conjugate[x], x]
Wolfram Language code: Plot[{Conjugate[x], 1}, {x, -4, 4}]

Conjugateは実線上で全射である：

Wolfram Language code: FunctionSurjective[Conjugate[x], x]
Wolfram Language code: Plot[{Conjugate[x], -2.5}, {x, -4, 4}]

Conjugateは非負でも非正でもない：

Wolfram Language code: FunctionSign[Conjugate[x], x]

TraditionalFormによる表示：

Wolfram Language code: Conjugate[z]//TraditionalForm

アプリケーション  (6)

BraKet記法を使って複素数値のリストのスカラー積を定義する：

Wolfram Language code: BraKet[{a_}, {b_}] := Conjugate[a].b

定義を適用する：

Wolfram Language code: BraKet[{{1, I}}, {{1I, 2}}]

複素数値の有理関数を実数の分母を持つ関数に書き換える：

Wolfram Language code: toRealDenominator[rat_] := With[{c = ComplexExpand[Conjugate[Denominator[rat]]]}, Expand[Numerator[rat] c] / Expand[Denominator[rat] c]]
Wolfram Language code: toRealDenominator[1 / (x ^ 2 + 3 I x - 2 + 4I)]

もとの関数を復元する：

Wolfram Language code: Cancel[%]

メビウス(Möbius)変換を実装する：

Wolfram Language code: MöbiusTransformation[a_, z_] := (z - a) / (1 - Conjugate[a] z)

同心円の画像をプロットする：

Wolfram Language code: a = 1 + 2I; ParametricPlot[Evaluate[Table[{Re[MöbiusTransformation[a, ρ Exp[I ϕ]]], Im[MöbiusTransformation[a, ρ Exp[I ϕ]]]}, {ρ, 0, 1, 1 / 10}]], {ϕ, 0, 2Pi}]

実数値の関数をzとzの関数として書く：

Wolfram Language code: toCCForm[f_, {x_, y_}, z_] := f /. {x -> (z + Conjugate[z]) / 2, y -> (z - Conjugate[z]) / (2I)}
Wolfram Language code: toCCForm[x^3 - 3 x y^2, {x, y}, z] //Simplify

正則関数はzに依存しない：

Wolfram Language code: toCCForm[x^3 - 3 x y^2 + I (3 x^2 y - y^3), {x, y}, z]//Simplify

Conjugateを使って幾何学的な領域をt描画する：

Wolfram Language code: Block[{z = x + I y}, RegionPlot[Abs[Conjugate[z] Re[z] + z Im[z]] < 1, {x, -2, 2}, {y, -2, 2}]]

量子力学では，有限個の状態を持つ系が単にベクトルで，物理量がそれに作用する行列で表される．次の状態の電子のようなスピン1/2粒子について考える：

Wolfram Language code: s = {(1/Sqrt[5]), (2I/Sqrt[5])};

角運動量の 成分についての演算子は以下の行列で与えられる：

Wolfram Language code: jz = (ℏ/2)PauliMatrix[3]

この状態で期待される角運動量 をとして計算する：

Wolfram Language code: Conjugate[s].jz.s

この角運動量における不確定性は である：

Wolfram Language code: σz = Simplify[Sqrt[Conjugate[s].jz.jz.s - (Conjugate[s].jz.s)^2], ℏ > 0]

角運動量の 成分の不確定性も同様に計算できる：

Wolfram Language code: jy = (ℏ/2)PauliMatrix[2]
Wolfram Language code: σy = Simplify[Sqrt[Conjugate[s].jy.jy.s - (Conjugate[s].jy.s)^2], ℏ > 0]

不確定性原理は不確定性の積の下限，を与える：

Wolfram Language code: Simplify[σy σz > (ℏ/2)Abs[ Conjugate[s].(jy.jz - jz.jy).s] , ℏ > 0]

特性と関係  (7)

変換の中には自動的に行われるものもある：

Wolfram Language code: Conjugate[1 / z]
Wolfram Language code: Conjugate[Re[z]]

Conjugateはそれ自身の逆関数である：

Wolfram Language code: Conjugate[Conjugate[z]]

Conjugateを含む式を簡約する：

Wolfram Language code: z Conjugate[z]
Wolfram Language code: FullSimplify[%]
Wolfram Language code: Conjugate[z1 z2] - Conjugate[z1]Conjugate[z2]
Wolfram Language code: FullSimplify[%]

実数値の変数を想定する：

Wolfram Language code: Conjugate[x + I y]
Wolfram Language code: ComplexExpand[%]

一般的な複素数値の変数を想定する：

Wolfram Language code: ComplexExpand[Conjugate[z], z]
Wolfram Language code: ComplexExpand[Conjugate[Sqrt[z]], z]

ConjugateをComplexExpandのオプション値として使う：

Wolfram Language code: ComplexExpand[Re[x], x, TargetFunctions -> {Conjugate}]

複素平面上の線に沿って記号的および数値的に積分する：

Wolfram Language code: Integrate[Conjugate[x ^ 2], {x, -2 + I, Pi + 2I}]
Wolfram Language code: N[%]
Wolfram Language code: NIntegrate[Conjugate[x ^ 2], {x, -2 + I, Pi + 2I}]

行列のエルミート(Hermite)共役を求める：

Wolfram Language code: m = RandomComplex[{-1 - I, 1 + I}, {2, 2}];
Wolfram Language code: Conjugate[Transpose[m]]//MatrixForm

代りにConjugateTransposeを使う：

Wolfram Language code: ConjugateTranspose[m]//MatrixForm

考えられる問題  (4)

Conjugateは，常に引数に伝播する訳ではない：

Wolfram Language code: Conjugate[Sin[z]]
Wolfram Language code: Conjugate[Exp[z]]

Conjugateの微分は不可能である：

Wolfram Language code: D[Conjugate[t], t]

導関数を定義する極限は方向に依存するため存在しない：

Wolfram Language code: Limit[DifferenceQuotient[Conjugate[z], {z, h}], h -> 0, Direction -> 1]
Wolfram Language code: Limit[DifferenceQuotient[Conjugate[z], {z, h}], h -> 0, Direction -> I]

ComplexExpandを使って実数値の変数について微分可能な式を得る：

Wolfram Language code: D[ComplexExpand[Conjugate[x + I y]], y]

Conjugateは，数値の引数については，評価されずに残ることがある：

Wolfram Language code: Conjugate[ArcSin[(-1 - 2 E - E ^ 2 + (1 + E) ^ 2)]]
Wolfram Language code: Simplify[%]

Conjugateを機械精度で数値的に評価すると，誤った結果が返されることがある：

Wolfram Language code: Conjugate[ArcSin[(-1 - 2 E - E ^ 2 + (1 + E) ^ 2) + 10 ^ -20]]
Wolfram Language code: N[%]

代りに任意精度の評価を行う：

Wolfram Language code: N[%%, 20]
Wolfram Research (1988), Conjugate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Conjugate.html （2021年に更新）.

テキスト

Wolfram Research (1988), Conjugate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Conjugate.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Conjugate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Conjugate.html.

APA

Wolfram Language. (1988). Conjugate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Conjugate.html

BibTeX

@misc{reference.wolfram_2026_conjugate, author="Wolfram Research", title="{Conjugate}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Conjugate.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conjugate, organization={Wolfram Research}, title={Conjugate}, year={2021}, url={https://reference.wolfram.com/language/ref/Conjugate.html}, note=[Accessed: 04-September-2026]}