WOLFRAM

Wolfram 语言与系统参考资料中心

Conjugate[z]

或 z，给出复数 z 的复共轭.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
函数的属性  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Conjugate

Conjugate[z]

或 z，给出复数 z 的复共轭.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值计算：

Wolfram Language code: Conjugate[1 + I]

用 conj 表示共轭表达式：

Wolfram Language code: (1 + I)

在实数的子集上绘图：

Wolfram Language code: Plot[Conjugate[x], {x, -3, 3}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Conjugate[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

范围  (24)

数值计算  (6)

数值计算：

Wolfram Language code: Conjugate[.7]

复数输入：

Wolfram Language code: Conjugate[.5 + I]

高精度计算：

Wolfram Language code: N[Conjugate[2 / 3 + I], 25]

输出的精度与输入的精度一致：

Wolfram Language code: Conjugate[2.3000000000000000000000000 - 1 / I]

高精度条件下进行高效计算：

Wolfram Language code: Conjugate[I + 1 / 3`100]//Timing
Wolfram Language code: Conjugate[5 I + 11 / 7`10000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Conjugate[{{1 / 2, -1 - I}, {-5 / 3, 1 / 2 + I}}]

或用 MatrixFunction 计算矩阵形式的 Conjugate 函数：

Wolfram Language code: MatrixFunction[Conjugate, {{1 / 2, -1 - I}, {-5 / 3, 1 / 2 + I}}]//FullSimplify

Conjugate 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: Conjugate[Interval[{-5, 5}]]
Wolfram Language code: Conjugate[CenteredInterval[-5 - 3I, 1 + I]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Conjugate[ Around[-1.1 + I, 0.01]]

特殊值  (3)

在固定点处的 Conjugate 的值：

Wolfram Language code: Table[Conjugate[n ], {n, {2I , -1 / 3, 3 + 4I}}]

零处的值：

Wolfram Language code: Conjugate[0]

无穷远处的值：

Wolfram Language code: Conjugate[I Infinity]
Wolfram Language code: Conjugate[ComplexInfinity]

可视化  (4)

在实数上绘制 和 的实部和虚部：

Wolfram Language code: ReImPlot[{x + I, Conjugate[x + I]}, {x, -3, 3}, PlotLegends -> Automatic]

绘制 函数的绝对值：

Wolfram Language code: Plot[Abs[Conjugate[x + I]], {x, -3, 3}]

在三个维度上比较 和 TemplateBox[{z}, Conjugate] 的图形：

Wolfram Language code: GraphicsRow[ComplexPlot3D[#, {z, -2 - 2I, 2 + 2I}, Mesh -> Automatic, RegionFunction -> Function[{z}, Abs[z] ≤ 2]]& /@ {z, Conjugate[z]}, ImageSize -> Medium]

绘制 函数的实部:

Wolfram Language code: ComplexContourPlot[Re[Conjugate[z ^ 2]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

绘制 函数的虚部:

Wolfram Language code: ComplexContourPlot[Im[Conjugate[z ^ 2]], {z, -3 - 3 I, 3 + 3I}, Contours -> 20]

函数的属性  (11)

Conjugate 对所有实数和复数输入有定义：

Wolfram Language code: FunctionDomain[Conjugate[x], x]
Wolfram Language code: FunctionDomain[Conjugate[x], x, Complexes]

Conjugate 的值域是全体实数和复数：

Wolfram Language code: FunctionRange[Conjugate[x], x, y]
Wolfram Language code: FunctionRange[Conjugate[x], x, y, Complexes]

Conjugate 是奇函数：

Wolfram Language code: Conjugate[-z]

Conjugate 是对合的，即 TemplateBox[{{(, TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox], )}}, Conjugate]=z：

Wolfram Language code: Conjugate[Conjugate[z]]

Conjugate 不是可微函数：

Wolfram Language code: D[Conjugate[x], x]

该差商在复平面上没有极限：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℂ]0](Conjugate[x + h] - Conjugate[x]/h)

极限在不同方向上具有不同的值，例如，在实数方向上为 ：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℝ]0](Conjugate[1 + h] - Conjugate[1]/h)

但在虚数方向上，极限为 ：

Wolfram Language code: Limit[(Conjugate[1 + h] - Conjugate[1]/h), h -> 0, Direction -> -I]

Conjugate 不是解析函数：

Wolfram Language code: FunctionAnalytic[Conjugate[x], x, Complexes]

函数处处奇异，但是是连续的：

Wolfram Language code: FunctionSingularities[Conjugate[x], x, Complexes]
Wolfram Language code: FunctionDiscontinuities[Conjugate[x], x, Complexes]

Conjugate 在实轴上非递减：

Wolfram Language code: FunctionMonotonicity[Conjugate[x], x]

Conjugate 在实轴上是单射函数：

Wolfram Language code: FunctionInjective[Conjugate[x], x]
Wolfram Language code: Plot[{Conjugate[x], 1}, {x, -4, 4}]

Conjugate 在实轴上是满射函数：

Wolfram Language code: FunctionSurjective[Conjugate[x], x]
Wolfram Language code: Plot[{Conjugate[x], -2.5}, {x, -4, 4}]

Conjugate 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Conjugate[x], x]

TraditionalForm 格式：

Wolfram Language code: Conjugate[z]//TraditionalForm

应用  (6)

利用 BraKet 符号为复值列表定义标量积：

Wolfram Language code: BraKet[{a_}, {b_}] := Conjugate[a].b

应用该定义：

Wolfram Language code: BraKet[{{1, I}}, {{1I, 2}}]

将复数值的有理函数改写为有实数分母的分式：

Wolfram Language code: toRealDenominator[rat_] := With[{c = ComplexExpand[Conjugate[Denominator[rat]]]}, Expand[Numerator[rat] c] / Expand[Denominator[rat] c]]
Wolfram Language code: toRealDenominator[1 / (x ^ 2 + 3 I x - 2 + 4I)]

恢复原分式：

Wolfram Language code: Cancel[%]

执行一个 Möbius 转换：

Wolfram Language code: MöbiusTransformation[a_, z_] := (z - a) / (1 - Conjugate[a] z)

绘制同心圆的图像：

Wolfram Language code: a = 1 + 2I; ParametricPlot[Evaluate[Table[{Re[MöbiusTransformation[a, ρ Exp[I ϕ]]], Im[MöbiusTransformation[a, ρ Exp[I ϕ]]]}, {ρ, 0, 1, 1 / 10}]], {ϕ, 0, 2Pi}]

将一个实数值函数写作 z 和 z 的函数：

Wolfram Language code: toCCForm[f_, {x_, y_}, z_] := f /. {x -> (z + Conjugate[z]) / 2, y -> (z - Conjugate[z]) / (2I)}
Wolfram Language code: toCCForm[x^3 - 3 x y^2, {x, y}, z] //Simplify

正则函数独立于 z：

Wolfram Language code: toCCForm[x^3 - 3 x y^2 + I (3 x^2 y - y^3), {x, y}, z]//Simplify

用 Conjugate 描述几何区域：

Wolfram Language code: Block[{z = x + I y}, RegionPlot[Abs[Conjugate[z] Re[z] + z Im[z]] < 1, {x, -2, 2}, {y, -2, 2}]]

在量子力学中，具有有限多个状态的系统由单位向量表示，而物理量则由作用于它们的矩阵表示. 考虑处于以下状态的自旋为 1/2 的粒子，如电子：

Wolfram Language code: s = {(1/Sqrt[5]), (2I/Sqrt[5])};

角动量 分量的算子由以下矩阵给出：

Wolfram Language code: jz = (ℏ/2)PauliMatrix[3]

计算该状态下的期望角动量为 ：

Wolfram Language code: Conjugate[s].jz.s

角动量的不确定性为 ：

Wolfram Language code: σz = Simplify[Sqrt[Conjugate[s].jz.jz.s - (Conjugate[s].jz.s)^2], ℏ > 0]

角动量 分量的不确定性计算方法与此类似：

Wolfram Language code: jy = (ℏ/2)PauliMatrix[2]
Wolfram Language code: σy = Simplify[Sqrt[Conjugate[s].jy.jy.s - (Conjugate[s].jy.s)^2], ℏ > 0]

不确定性原理给出了不确定性乘积的下限，：

Wolfram Language code: Simplify[σy σz > (ℏ/2)Abs[ Conjugate[s].(jy.jz - jz.jy).s] , ℏ > 0]

属性和关系  (7)

自动执行某些转换：

Wolfram Language code: Conjugate[1 / z]
Wolfram Language code: Conjugate[Re[z]]

Conjugate 是它本身的逆：

Wolfram Language code: Conjugate[Conjugate[z]]

化简包含 Conjugate 的表达式：

Wolfram Language code: z Conjugate[z]
Wolfram Language code: FullSimplify[%]
Wolfram Language code: Conjugate[z1 z2] - Conjugate[z1]Conjugate[z2]
Wolfram Language code: FullSimplify[%]

假定实数值变量：

Wolfram Language code: Conjugate[x + I y]
Wolfram Language code: ComplexExpand[%]

假定一般的复数值变量：

Wolfram Language code: ComplexExpand[Conjugate[z], z]
Wolfram Language code: ComplexExpand[Conjugate[Sqrt[z]], z]

Conjugate 作为 ComplexExpand 中的一个选项值：

Wolfram Language code: ComplexExpand[Re[x], x, TargetFunctions -> {Conjugate}]

在复平面内沿一条线进行符号积分和数值积分：

Wolfram Language code: Integrate[Conjugate[x ^ 2], {x, -2 + I, Pi + 2I}]
Wolfram Language code: N[%]
Wolfram Language code: NIntegrate[Conjugate[x ^ 2], {x, -2 + I, Pi + 2I}]

求出矩阵的厄密共轭：

Wolfram Language code: m = RandomComplex[{-1 - I, 1 + I}, {2, 2}];
Wolfram Language code: Conjugate[Transpose[m]]//MatrixForm

用 ConjugateTranspose 代替：

Wolfram Language code: ConjugateTranspose[m]//MatrixForm

可能存在的问题  (4)

Conjugate 并不总是传送参数：

Wolfram Language code: Conjugate[Sin[z]]
Wolfram Language code: Conjugate[Exp[z]]

对 Conjugate 求导是不可能的：

Wolfram Language code: D[Conjugate[t], t]

定义导数的极限与方向相关，因此不存在：

Wolfram Language code: Limit[DifferenceQuotient[Conjugate[z], {z, h}], h -> 0, Direction -> 1]
Wolfram Language code: Limit[DifferenceQuotient[Conjugate[z], {z, h}], h -> 0, Direction -> I]

使用 ComplexExpand 得到实值变量的微分表达式：

Wolfram Language code: D[ComplexExpand[Conjugate[x + I y]], y]

Conjugate 可以对数值参数保持不计算：

Wolfram Language code: Conjugate[ArcSin[(-1 - 2 E - E ^ 2 + (1 + E) ^ 2)]]
Wolfram Language code: Simplify[%]

Conjugate 的机器精度的数值计算可能给出错误结果：

Wolfram Language code: Conjugate[ArcSin[(-1 - 2 E - E ^ 2 + (1 + E) ^ 2) + 10 ^ -20]]
Wolfram Language code: N[%]

取代用任意精度计算：

Wolfram Language code: N[%%, 20]
Wolfram Research (1988)，Conjugate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Conjugate.html （更新于 2021 年）.

文本

Wolfram Research (1988)，Conjugate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Conjugate.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "Conjugate." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/Conjugate.html.

APA

Wolfram 语言. (1988). Conjugate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Conjugate.html 年

BibTeX

@misc{reference.wolfram_2026_conjugate, author="Wolfram Research", title="{Conjugate}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Conjugate.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_conjugate, organization={Wolfram Research}, title={Conjugate}, year={2021}, url={https://reference.wolfram.com/language/ref/Conjugate.html}, note=[Accessed: 07-October-2026]}