WOLFRAM

Wolfram 语言与系统参考资料中心

ConnectSystemModelComponents[{"c1"∈comp1,…},{"c1.a""c2.b",…}]

通过将元件 "c1" 的接口 "a" 与元件 "c2" 的接口 "b" 等相连接创建一个系统模型.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
选项  
GraphLayout  
应用  
A DC Motor  
A Lowpass Filter  
An Inerter  
属性和关系  
Neat 巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

ConnectSystemModelComponents

ConnectSystemModelComponents[{"c1"∈comp1,…},{"c1.a""c2.b",…}]

通过将元件 "c1" 的接口 "a" 与元件 "c2" 的接口 "b" 等相连接创建一个系统模型.

更多信息和选项

  • ConnectSystemModelComponents 组装元件并创建一个新的系统模型. 这些连接传达值并在系统中设置守恒定律.
  • ConnectSystemModelComponents 返回 SystemModel[…].
  • ConnectSystemModelComponents["NewModel",…] 将创建的模型命名为 "NewModel".
  • ConnectSystemModelComponents["PackageA.NewModel",…] 把 "NewModel" 插入到 "PackageA" 中.
  • compi 可以是一个 SystemModel对象、SystemModel 接受的完整模型名称字符串或模型简称.
  • 在 ConnectSystemModelComponents[…,spec] 中，spec 是一个 Association，其中的键为：
  • "ParameterValues"{p1val1,…}参数值
    "InitialValues"{v1val1,…}初始值
    "ExtendsModels"{partial1,…}所基于的部分模型
    "DiscreteVariables"{v1,v2,…}仅在事件发生时变化的变量
    "SimulationSettings"{opt1val1,…}模型仿真选项
  • 当设置为 ConnectSystemModelComponents[…,"ExtendsModels"partial] 时，会将新模型与 Modelica 中已定义的 partial SystemModel 结合在一起. »
  • 通过使用 "ExtendsModels"{"partial1",…} 一个模型可以跨越多个模型.
  • 在其上进行构建的部分模通常在 Interfaces 包中被定义. 例如，SystemModels["Modelica.Electrical.Analog.Interfaces.*","model"|"block"] 可用于查找内置电子模型库中的部分模型 (partial models).
  • "InitialValues" 对应于 Modelica 模型中的 start 属性.
  • 在 "SimulationsSettings"->{opt1val1,…} 中允许的选项包括：
  • "Method"仿真方法
    "StartTime"仿真开始时间
    "StopTime"仿真停止时间
  • 可用的自适应步长 "Method" 值包括：
  • "DASSL"DASSL DAE 求解器
    "CVODES"CVODES ODE 求解器
  • 自适应步长法的选项包括：
  • "InterpolationPoints"插值点数
    "Tolerance"自适应步长的公差
  • 可用的固定步长"Method"值包括：
  • "Euler"显式 1 阶欧拉方法
    "Heun"2 阶 Heun 方法
    "RungeKutta"显式四阶 Runge-Kutta 法
  • 固定步长法的选项包括：
  • "StepSize"固定步长
  • 可以使用 GraphLayout 选项控制创建的模型图的布局.

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建简单的电路：

Wolfram Language code: components = {"L"∈"Modelica.Electrical.Analog.Basic.Inductor", "AC"∈"Modelica.Electrical.Analog.Sources.SineVoltage", "G"∈"Modelica.Electrical.Analog.Basic.Ground"};
Wolfram Language code: connections = {"G.p" -> "AC.n", "AC.p" -> "L.n", "L.p" -> "AC.n"};
Wolfram Language code: model = ConnectSystemModelComponents[components, connections]

显示电感中的电流和电压：

Wolfram Language code: SystemModelPlot[model, {"L.i", "L.v"}, 5]

用简写名称指代 Modelica.Blocks 中的 Abs 和 Sine 元件：

Wolfram Language code: comp = {"a"∈"Abs", "sine"∈"Sources.Sine"};
Wolfram Language code: conn = {"sine.y" -> "a.u"};
Wolfram Language code: model = ConnectSystemModelComponents[comp, conn]
Wolfram Language code: SystemModelPlot[model, {"a.y"}, 2]

范围  (5)

创建一个区块示例，对正弦波进行均匀采样：

Wolfram Language code: comp = {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"Discrete.Sampler"};
Wolfram Language code: conn = {"sine.y""sample.u"};
Wolfram Language code: model = ConnectSystemModelComponents[comp, conn]

仿真并绘制采样信号：

Wolfram Language code: SystemModelPlot[model, {"sample.y"}, 2]

给组件中的参数赋值：

Wolfram Language code: comp = {"inAdd"∈"DocumentationExamples.Basic.InputAdd", "cSource"∈"Modelica.Blocks.Sources.Constant"};
Wolfram Language code: conn = {"cSource.y""inAdd.u"};

将正弦波的振幅设置为 3：

Wolfram Language code: model = ConnectSystemModelComponents[comp, conn, <|"ParameterValues" -> {"inAdd.sine.amplitude" -> 3}|>]

模拟并绘制输出：

Wolfram Language code: SystemModelPlot[model, {"inAdd.y"}, 2]

用热导管连接两个具有热容量的物质：

Wolfram Language code: comp = {"mass1"∈"HeatCapacitor", "mass2"∈"HeatCapacitor", "conduction"∈"ThermalConductor"};
Wolfram Language code: conn = {"mass1.port""conduction.port_a", "conduction.port_b""mass2.port"};
Wolfram Language code: model = ConnectSystemModelComponents[comp, conn]

设定热容量、质量和初始温度：

Wolfram Language code: model2 = SystemModel[model, {"conduction.G" -> 10, "mass1.C" -> 15, "mass2.C" -> 40, "mass1.T" -> 373.15, "mass2.T" -> 273.15}];

显示已达到温度平衡：

Wolfram Language code: SystemModelPlot[model2, {"mass1.T", "mass2.T"}, 5]

创建一个与弹簧相连的质块：

Wolfram Language code: comp = {"fixed"∈"Modelica.Mechanics.Translational.Components.Fixed", "spring"∈"Modelica.Mechanics.Translational.Components.Spring", "mass"∈"Modelica.Mechanics.Translational.Components.Mass"};
Wolfram Language code: conn = {"fixed.flange""spring.flange_a", "spring.flange_b""mass.flange_a"};

移动物体的初始位置，拉伸弹簧：

Wolfram Language code: model = ConnectSystemModelComponents[comp, conn, <|"InitialValues" -> {"mass.s" -> 2}|>]

显示质块位置是怎样振荡的：

Wolfram Language code: SystemModelPlot[model, {"mass.s"}, 10]

构建一个阻尼 3D 摆：

Wolfram Language code: comp = {"world"∈"Modelica.Mechanics.MultiBody.World", "rev"∈"Modelica.Mechanics.MultiBody.Joints.Revolute", "damper"∈"Modelica.Mechanics.Rotational.Components.Damper", "body"∈"Modelica.Mechanics.MultiBody.Parts.Body"};
Wolfram Language code: conn = {"world.frame_b""rev.frame_a", "damper.flange_b""rev.axis", "rev.support""damper.flange_a", "body.frame_a""rev.frame_b"};

设置参数的值：

Wolfram Language code: model = ConnectSystemModelComponents[comp, conn, <|"ParameterValues" -> {"rev.useAxisFlange" -> True, "body.r_CM" -> {1, 0, 0}, "damper.d" -> 0.1}|>]

仿真并以动画演示摆的路径：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: graphics = sim["Graphics3D", t];
Wolfram Language code: pendulum[x_ ? NumberQ] := pendulum[x] = Show[graphics /. t -> x, PlotRange -> {{-1.2, 1.2}, {-1.2, 0.1}, {-.2, .2}}, ImageSize -> 300]
Wolfram Language code: Animate[Evaluate[pendulum[x]], {x, 0, 10}, AnimationRate -> 0.5, AnimationRunning -> False, SaveDefinitions -> True, TrackedSymbols :> {pendulum, x, graphics}]

推广和延伸  (1)

Rule、DirectedEdge 和 UndirectedEdge 可被用来建立连接：

Wolfram Language code: comp1 = {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"ZeroOrderHold"};

用 Rule 来指定连接：

Wolfram Language code: conn1 = {"sine.y" -> "sample.u"};
Wolfram Language code: model1 = ConnectSystemModelComponents[comp1, conn1]

用 DirectedEdge 和 UndirectedEdge 来指定连接：

Wolfram Language code: comp2 = Append[comp1, "foh"∈"FirstOrderHold"];
Wolfram Language code: conn2 = {"sine.y""sample.u", "sample.y""foh.u"};
Wolfram Language code: model2 = ConnectSystemModelComponents[comp2, conn2]

仿真并绘制信号：

Wolfram Language code: Column[{SystemModelPlot[model1, {"sample.y"}, 2], SystemModelPlot[model2, {"foh.y"}, 2]}]

选项  (3)

GraphLayout  (3)

GraphLayout 可用于指定模型图的布局：

Wolfram Language code: comp = {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"ZeroOrderHold", "foh"∈"FirstOrderHold"};
Wolfram Language code: conn = {"sine.y""sample.u", "sample.y""foh.u"};
Wolfram Language code: ConnectSystemModelComponents[comp, conn, GraphLayout -> "LinearEmbedding"]

默认情况下使用加权为 "SpringElectricalEmbedding" 的边：

Wolfram Language code: comp = {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"ZeroOrderHold"};
Wolfram Language code: conn = {"sine.y" -> "sample.u"};
Wolfram Language code: ConnectSystemModelComponents[comp, conn, GraphLayout -> {"SpringElectricalEmbedding", "EdgeWeighted" -> True}]

关闭自动布局：

Wolfram Language code: comp = {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"ZeroOrderHold"};
Wolfram Language code: conn = {"sine.y" -> "sample.u"};
Wolfram Language code: ConnectSystemModelComponents[comp, conn, GraphLayout -> None]

应用  (3)

A DC Motor  (1)

通过连接电气和机械组件创建一个直流电机模型：

Wolfram Language code: components = {"step1"∈"Blocks.Sources.Step", "resistor1"∈"Analog.Basic.Resistor", "inductor1"∈"Analog.Basic.Inductor", "EMF1"∈"RotationalEMF", "ground1"∈"Analog.Basic.Ground", "signalVoltage1"∈"Analog.Sources.SignalVoltage", "inertia1"∈"Rotational.Components.Inertia"};
Wolfram Language code: connections = {"resistor1.n""inductor1.p", "inductor1.n""EMF1.p", "step1.y""signalVoltage1.v", "signalVoltage1.p""resistor1.p", "EMF1.n""signalVoltage1.n", "ground1.p""signalVoltage1.n", "EMF1.flange""inertia1.flange_a"};
Wolfram Language code: model = ConnectSystemModelComponents[components, connections]

显示直流电机的角速度：

Wolfram Language code: SystemModelPlot[model, "inertia1.w", 10]

A Lowpass Filter  (1)

创建一个数字低通滤波器：

Wolfram Language code: a = LeastSquaresFilterKernel[{"Lowpass", 0.1}, 20];

把滤波器转换为传递函数：

Wolfram Language code: h = ListZTransform[a, z];
Wolfram Language code: tf = TransferFunctionModel[h, z, SamplingPeriod -> 0.01]//TransferFunctionCancel

创建滤波器的模型：

Wolfram Language code: lowPass = CreateSystemModel[tf];

创建一个信号发生源：

Wolfram Language code: signal = CreateSystemModel["Signal", {y[t] == Abs[Sin[t Cos[2t]]]t}, t, <|"ExtendsModels" -> "Modelica.Blocks.Interfaces.SignalSource"|>];

把信号源连接到滤波器：

Wolfram Language code: model = ConnectSystemModelComponents["FilteredSignal", {"signal"∈signal, "filter"∈lowPass}, {"signal.y""filter.u"}]

仿真并绘制输出信号和滤波后的信号：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, {"signal.y", "filter.y"}]

An Inerter  (1)

生成一个惯质，其两端所受的力与相对加速度成正比：

Wolfram Language code: inerter = CreateSystemModel["Inerter", {f[t] == b(Subscript[v, rel]'[t])}, t, <|"ExtendsModels" -> "Translational.Interfaces.PartialCompliantWithRelativeStates"|>];

比较在阻尼系统中添加惯质会如何影响振动：

Wolfram Language code: comp = {"damper"∈"Modelica.Mechanics.Translational.Components.Damper", "mass"∈"Modelica.Mechanics.Translational.Components.Mass", "force"∈"Modelica.Mechanics.Translational.Sources.Force", "vibration"∈"RealInput", "fixed"∈"Modelica.Mechanics.Translational.Components.Fixed", "spring"∈"Modelica.Mechanics.Translational.Components.Spring"};
Wolfram Language code: conn = {"fixed.flange" -> "spring.flange_a", "fixed.flange" -> "damper.flange_a", "damper.flange_b" -> "mass.flange_a", "spring.flange_b" -> "mass.flange_a", "force.flange" -> "mass.flange_a", "vibration" -> "force.f"};
Wolfram Language code: damping = ConnectSystemModelComponents[comp, conn]
Wolfram Language code: inerterDamping = ConnectSystemModelComponents[Append[comp, "inerter"∈inerter], Join[conn, {"inerter.flange_b" -> "mass.flange_a", "inerter.flange_a" -> "fixed.flange"}]]

设置参数值并用正弦振动力仿真系统：

Wolfram Language code: d = 300;
Wolfram Language code: b = 700;
Wolfram Language code: c = 275;
Wolfram Language code: m = 2000;
Wolfram Language code: vibr = Function[t, Sin[10t]];
Wolfram Language code: tstop = 50;
Wolfram Language code: simInerter = SystemModelSimulate[inerterDamping, tstop, <|"Inputs" -> {"vibration" -> vibr}, "ParameterValues" -> {"inerter.b" -> b, "damper.d" -> d, "spring.c" -> c, "mass.m" -> m}|>];
Wolfram Language code: simDamper = SystemModelSimulate[damping, tstop, <|"Inputs" -> {"vibration" -> vibr}, "ParameterValues" -> {"damper.d" -> d, "spring.c" -> c, "mass.m" -> m}|>];

阻尼效应具有相似的幅度：

Wolfram Language code: SystemModelPlot[{simInerter, simDamper}, {"mass.s"}, PlotLegends -> {"Inerter", "No inerter"}]

通过使用惯质作用在阻尼器部件上的力被显著减小：

Wolfram Language code: damperForceInerter = simInerter[{"damper.f"}]//First;
Wolfram Language code: damperForce = simDamper[{"damper.f"}]//First;
Wolfram Language code: Plot[{Abs[damperForceInerter[t]], Abs[damperForce[t]]}, {t, 0, 10}, PlotLegends -> {"Inerter", "No inerter"}]

属性和关系  (3)

用 CreateSystemModel 基于微分方程创建模型：

Wolfram Language code: model = CreateSystemModel[{Subscript[y, 1]'[t] == Subscript[y, 1][t] + Subscript[y, 2][t], Subscript[y, 2]'[t] == Subscript[y, 1][t] + Sin[t]}, t];
Wolfram Language code: SystemModelPlot[{model, 2.5}, {"y_1", "y_2"}]

可以与使用 ConnectSystemModelComponents 类似的方式使用 CreateSystemModel：

Wolfram Language code: model = CreateSystemModel[{"sine.y""sample.u"}, t, {"sine"∈"Modelica.Blocks.Sources.Sine", "sample"∈"ZeroOrderHold"}];
Wolfram Language code: SystemModelPlot[{model, 2}, {"sample.y"}]

利用基于现有组件的分层模型可以快速创建更大的系统：

Wolfram Language code: components = {"controller"∈"Systems.Components.LQControlSystem", "gear"∈"Systems.Components.GearBox", "motor"∈"Systems.Components.ElectricalMotor", "pendulum"∈"Systems.Components.Pendulum"};
Wolfram Language code: connections = {"pendulum.angle""controller.angle", "pendulum.position""controller.xPos", "motor.flange""gear.flange_a", "gear.flange_b""pendulum.flange_a", "motor.u""controller.y"};

用控制器构建 3D 倒立摆模型：

Wolfram Language code: model = ConnectSystemModelComponents[components, connections]

可以使用几个组件构建一个复杂的多域系统：

Wolfram Language code: model["Summary"]

Neat 巧妙范例  (1)

显示图中顶点之间的热传导：

Wolfram Language code: g = HararyGraph[4, 13];
Wolfram Language code: {vlist, elist} = {VertexList[g], EdgeList[g]};
Wolfram Language code: {nv, ne} = Length /@ {vlist, elist};

定义元件：

Wolfram Language code: vcomp = Map["v" <> ToString[#]∈"HeatCapacitor"&, vlist];
Wolfram Language code: ecomp = Table["e" <> ToString[i]∈"ThermalConductor", {i, ne}];
Wolfram Language code: complist = Join[vcomp, ecomp];

定义连接：

Wolfram Language code: connlist = Join@@Table[With[{e = ToString /@ elist[[i]], is = ToString[i]}, {"v" <> e[[1]] <> ".port""e" <> is <> ".port_a", "v" <> e[[2]] <> ".port""e" <> is <> ".port_b"}], {i, ne}];

创建一个模型并设置初始值和参数值：

Wolfram Language code: m = ConnectSystemModelComponents["ThermalGraph", complist, connlist, GraphLayout -> None];
Wolfram Language code: SetSystemModel[m, Join[{"v1.T" -> 320}, Table["e" <> ToString[i] <> ".G" -> 10, {i, ne}], Table["v" <> ToString[i] <> ".C" -> 15, {i, nv}]]];

仿真并用动画演示模型，用颜色表明温度：

Wolfram Language code: sim = SystemModelSimulate[m, 5];
Wolfram Language code: temps = Table[i -> ColorData["TemperatureMap"][Rescale[sim["v" <> ToString[i] <> ".T", t], {293, 297}]], {i, nv}];
Wolfram Language code: vgraph[x_ ? NumberQ] := vgraph[x] = Graph[vlist, elist, VertexStyle -> (temps /. t -> x), VertexSize -> 0.3]
Wolfram Language code: Animate[Evaluate[vgraph[x]], {x, 0, 5}, AnimationRate -> 0.5, SaveDefinitions -> True, AnimationRunning -> False]
Wolfram Research (2018)，ConnectSystemModelComponents，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html （更新于 2020 年）.

文本

Wolfram Research (2018)，ConnectSystemModelComponents，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html （更新于 2020 年）.

CMS

Wolfram 语言. 2018. "ConnectSystemModelComponents." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html.

APA

Wolfram 语言. (2018). ConnectSystemModelComponents. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html 年

BibTeX

@misc{reference.wolfram_2026_connectsystemmodelcomponents, author="Wolfram Research", title="{ConnectSystemModelComponents}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_connectsystemmodelcomponents, organization={Wolfram Research}, title={ConnectSystemModelComponents}, year={2020}, url={https://reference.wolfram.com/language/ref/ConnectSystemModelComponents.html}, note=[Accessed: 14-September-2026]}