WOLFRAM

Wolfram 语言与系统参考资料中心

ContainsAll[list1,list2]

如果 list1 包含 list2 的全部元素，则生成 True.

ContainsAll[list2]

运算符形式，当被应用的对象包含 list2 的全部元素时，生成 True.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
SameTest  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ContainsAll

ContainsAll[list1,list2]

如果 list1 包含 list2 的全部元素，则生成 True.

ContainsAll[list2]

运算符形式，当被应用的对象包含 list2 的全部元素时，生成 True.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

第一个列表包含第二个列表的全部元素：

Wolfram Language code: ContainsAll[{b, a, b, c}, {a, b}]

第一个列表不包含第二个列表的全部元素：

Wolfram Language code: ContainsAll[{b, a, b, c}, {a, b, d}]

范围  (4)

英文单词 facetious 含有全部5个元音：

Wolfram Language code: ContainsAll[Characters["facetious"], {"a", "e", "i", "o", "u"}]

使用 ContainsAll 的运算符形式：

Wolfram Language code: all5 = ContainsAll[{1, 2, 3, 4, 5}]
Wolfram Language code: all5[{2, 3, 1, 3}]
Wolfram Language code: all5[{4, 2, 3, 1, 6, 1, 5}]

查找演员阵容中含有和安吉丽娜·朱莉（Angelina Jolie）和布拉德·皮特（Brad Pitt）的影片：

Wolfram Language code: EntityList[EntityClass["Movie", "Cast" -> ContainsAll[{Entity["Person", "AngelinaJolie::8cggf"], Entity["Person", "BradPitt::6xy46"]}]]]

ContainsAll 适用于关联：

Wolfram Language code: ContainsAll[<|a -> x, b -> y, c -> z, d -> x|>, {x, y, z}]
Wolfram Language code: ContainsAll[<|a -> x, b -> y, c -> z, d -> x|>, <|1 -> x, 2 -> y, 3 -> z|>]

选项  (2)

SameTest  (2)

默认情况下，ContainsAll 认为等同元素是相同的：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[1, "Meters"], 10]
Wolfram Language code: ContainsAll[list, {Quantity[1/5, "Meters"], Quantity[1/2, "Meters"]}]

考虑单位的改变，只要它们表示的是完全相同的量：

Wolfram Language code: ContainsAll[list, {Quantity[20, "Centimeters"], Quantity[50, "Centimeters"]}]

数值近似不被认为是相同的对象：

Wolfram Language code: ContainsAll[list, {Quantity[20., "Centimeters"], Quantity[50., "Centimeters"]}]

使用 Equal 作为有数值公差的比较函数：

Wolfram Language code: ContainsAll[list, {Quantity[20., "Centimeters"], Quantity[50., "Centimeters"]}, SameTest -> Equal]

字符串比较在默认情况下对大小写敏感：

Wolfram Language code: ContainsAll[{"A", "B", "C"}, {"a", "b"}]

在比较之前转换为小写形式：

Wolfram Language code: ContainsAll[{"A", "B", "C"}, {"a", "b"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

应用  (4)

随机查找 10 个包含所有五个元音的英语单词：

Wolfram Language code: Select[RandomSample@DictionaryLookup[], ContainsAll[Characters[#], {"a", "e", "i", "o", "u"}]&, 10]

找出包含所有五个元音的最短法语单词：

Wolfram Language code: MinimalBy[Select[WordList[Language -> "French"], ContainsAll[Characters[#], {"a", "e", "i", "o", "u"}]&], StringLength]

取一段文本每个单词的首字符：

Wolfram Language code: firstchars = StringTake[#, 1]& /@ ExampleData[{"Text", "ToBeOrNotToBe"}, "Words"]

它不包括全部英文字母：

Wolfram Language code: ContainsAll[ToLowerCase[firstchars], CharacterRange["a", "z"]]
Wolfram Language code: Complement[CharacterRange["a", "z"], ToLowerCase[firstchars]]

更大的文本所含单词的首字母囊括了全部英文字母：

Wolfram Language code: Length[firstchars = StringTake[#, 1]& /@ ExampleData[{"Text", "OriginOfSpecies"}, "Words"]]
Wolfram Language code: ContainsAll[firstchars, CharacterRange["a", "z"]]

在文本中，这些单词的首字母并不全是大写字母：

Wolfram Language code: ContainsAll[firstchars, CharacterRange["A", "Z"]]

泛文漏字文 (pangrammatic lipogram) 是使用字母表中除一个字母外所有字母的文本：

Wolfram Language code: pangrammaticLipogramQ[text_, letter_] := ContainsAll[Characters[text], Complement[Alphabet[], {letter}]]
Wolfram Language code: pangrammaticLipogramQ["a jovial swain should not complain of any buxom fair who mocks his pain and thinks it gain to quiz his awkward air", "e"]

属性和关系  (3)

ContainsAll[list1,list2] 等价于 SubsetQ[list1,list2]：

Wolfram Language code: list1 = {5, 1, 0, 0, 0, 0, 4, 5, 0, 0};
Wolfram Language code: list2 = {1, 2, 3, 4, 5};
Wolfram Language code: {ContainsAll[list1, list2], SubsetQ[list1, list2]}

逆转 ContainsAll 的参数等价于使用 ContainsOnly：

Wolfram Language code: list1 = {3, 1, 0, 0, 4, 0, 3, 2, 4, 0};
Wolfram Language code: list2 = {1, 2, 3, 4, 5};
Wolfram Language code: {ContainsAll[list1, list2], ContainsOnly[list2, list1]}

ContainsAll[list,{}] 总是返回 True：

Wolfram Language code: ContainsAll[{1, 2}, {}]
Wolfram Language code: ContainsAll[{}, {}]
Wolfram Research (2015)，ContainsAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsAll.html.

文本

Wolfram Research (2015)，ContainsAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsAll.html.

CMS

Wolfram 语言. 2015. "ContainsAll." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsAll.html.

APA

Wolfram 语言. (2015). ContainsAll. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ContainsAll.html 年

BibTeX

@misc{reference.wolfram_2026_containsall, author="Wolfram Research", title="{ContainsAll}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsAll.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsall, organization={Wolfram Research}, title={ContainsAll}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsAll.html}, note=[Accessed: 14-September-2026]}