WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ContainsAny[list1,list2]

list1が list2の要素のいずれかを含む場合にTrueを返す．

ContainsAny[list2]

適用されたオブジェクトが list2の要素のいずれかを含む場合にTrueを返す，この関数の演算子形である．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
SameTest  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ContainsAny

ContainsAny[list1,list2]

list1が list2の要素のいずれかを含む場合にTrueを返す．

ContainsAny[list2]

適用されたオブジェクトが list2の要素のいずれかを含む場合にTrueを返す，この関数の演算子形である．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

第1リストは第2リストの要素のいくつかを含む：

Wolfram Language code: ContainsAny[{b, a, b}, {a, b, c}]

第1リストは第2リストの要素は何も含まない：

Wolfram Language code: ContainsAny[{d, f, e}, {a, b, c}]

スコープ  (5)

0から100までの整数からランダムに取り出す：

Wolfram Language code: RandomInteger[1000]

この数に偶数桁が含まれるかどうかを調べる：

Wolfram Language code: ContainsAny[IntegerDigits[%], {0, 2, 4, 6, 8}]

ContainsAnyの演算子形を使う：

Wolfram Language code: weekend = ContainsAny[{Saturday, Sunday}]
Wolfram Language code: weekend[{Monday, Thursday, Tuesday}]
Wolfram Language code: weekend[{Monday, Saturday, Tuesday}]

数カ国のトンネルを求める：

Wolfram Language code: EntityList[EntityClass["Tunnel", {"Countries" -> ContainsAny[{Entity["Country", "HongKong"], Entity["Country", "China"]}]}]]

スピルバーグ(Steven Spielberg)が監督し，与えられたリスト中の俳優が出演している映画を探す：

Wolfram Language code: EntityList[EntityClass["Movie", {"Director" -> Entity["Person", "StevenSpielberg::76z25"], "Cast" -> ContainsAny[{Entity["Person", "HarrisonFord::y8237"], Entity["Person", "TomHanks::57d8x"]}]}]]

ContainsAnyは連想に使うことができる：

Wolfram Language code: ContainsAny[<|a -> x, b -> y, c -> z|>, {y, Y}]
Wolfram Language code: ContainsAny[<|a -> x, b -> y, c -> z|>, <|1 -> y, 2 -> Y|>]

オプション  (2)

SameTest  (2)

デフォルトで，ContainsAnyは要素が等しければ同じであるとみなす：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[6, "Meters"], 3]
Wolfram Language code: ContainsAny[list, {Quantity[1, "Meters"], Quantity[2, "Meters"]}]

両者が全く同じ量を表している場合は，単位の違いが考慮される：

Wolfram Language code: ContainsAny[list, {Quantity[100, "Centimeters"], Quantity[200, "Centimeters"]}]

近似された数値は同じオブジェクトとはみなされない：

Wolfram Language code: ContainsAny[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}]

Equalを比較関数として使って数値許容度を持たせる：

Wolfram Language code: ContainsAny[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}, SameTest -> Equal]

文字列の比較は，デフォルトで大文字小文字の違いに敏感である：

Wolfram Language code: ContainsAny[{"A", "B", "C"}, {"a", "b"}]

比較の前に小文字に変換する：

Wolfram Language code: ContainsAny[{"A", "B", "C"}, {"a", "b"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

アプリケーション  (1)

英訳の「ドン・キホーテ」に含まれる単語のリストを得る：

Wolfram Language code: Length[words = ExampleData[{"Text", "DonQuixoteIEnglish"}, "Words"]]

これには，現代ヨーロッパのいくつかの国の名前が含まれている：

Wolfram Language code: ContainsAny[words, CanonicalName[CountryData["Europe"]]]

しかし，当時存在しなかった南米諸国は含まれてはならない：

Wolfram Language code: ContainsAny[words, CanonicalName[CountryData["SouthAmerica"]]]

特性と関係  (6)

ContainsAny[list1,list2]は，リストの非空の共通集合を調べることに等しい：

Wolfram Language code: list1 = {5, 8, 8, 3};
Wolfram Language code: list2 = {9, 10, 7, 2};
Wolfram Language code: {ContainsAny[list1, list2], Intersection[list2, list1] =!= {}}

ContainsAny[list1,list2]はIntersectingQ[list1,list2]に等しい：

Wolfram Language code: list1 = {7, 1, 10, 5};
Wolfram Language code: list2 = {5, 5, 9, 10};
Wolfram Language code: {ContainsAny[list1, list2], IntersectingQ[list2, list1]}

ContainsAnyはその引数の対称関数である．つまり，ContainsAny[list1,list2]==ContainsAny[list2,list1]である：

Wolfram Language code: list1 = {3, 3, 10, 9};
Wolfram Language code: list2 = {4, 3, 0, 5};
Wolfram Language code: {ContainsAny[list1, list2], ContainsAny[list2, list1]}

ContainsAny[list1,list2]の否定はContainsNone[list1,list2]に等しい：

Wolfram Language code: list1 = {4, 3, 5, 7}
Wolfram Language code: list2 = {8, 10, 9, 5}
Wolfram Language code: {Not[ContainsAny[list1, list2]], ContainsNone[list2, list1]}

ContainsAny[list,{}]は，常にFalseを返す：

Wolfram Language code: ContainsAny[{1, 2}, {}]
Wolfram Language code: ContainsAny[{}, {}]

文字列のリストに対して使う場合は，大文字小文字の違いに敏感である：

Wolfram Language code: ContainsAny[{"A", "B"}, {"a", "b", "c"}]
Wolfram Language code: ContainsAny[{"A", "B"}, {"A", "b", "c"}]
Wolfram Research (2015), ContainsAny, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsAny.html.

テキスト

Wolfram Research (2015), ContainsAny, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsAny.html.

CMS

Wolfram Language. 2015. "ContainsAny." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsAny.html.

APA

Wolfram Language. (2015). ContainsAny. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ContainsAny.html

BibTeX

@misc{reference.wolfram_2026_containsany, author="Wolfram Research", title="{ContainsAny}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsAny.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsany, organization={Wolfram Research}, title={ContainsAny}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsAny.html}, note=[Accessed: 15-September-2026]}