WOLFRAM

Wolfram 语言与系统参考资料中心

ContainsAny[list1,list2]

如果 list1 含有 list2 中的任何元素则产生 True.

ContainsAny[list2]

当所应用的对象含有 list2 中的任何元素时产生 True 的运算符形式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
SameTest  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ContainsAny

ContainsAny[list1,list2]

如果 list1 含有 list2 中的任何元素则产生 True.

ContainsAny[list2]

当所应用的对象含有 list2 中的任何元素时产生 True 的运算符形式.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

第一个列表中含有第二个列表中的一些元素：

Wolfram Language code: ContainsAny[{b, a, b}, {a, b, c}]

第一个列表中不含有第二个列表中的任何元素：

Wolfram Language code: ContainsAny[{d, f, e}, {a, b, c}]

范围  (5)

在0到1000间取任意整数：

Wolfram Language code: RandomInteger[1000]

查看这个数的各个数位中是否有偶数：

Wolfram Language code: ContainsAny[IntegerDigits[%], {0, 2, 4, 6, 8}]

在运算符形式中使用 ContainsAny：

Wolfram Language code: weekend = ContainsAny[{Saturday, Sunday}]
Wolfram Language code: weekend[{Monday, Thursday, Tuesday}]
Wolfram Language code: weekend[{Monday, Saturday, Tuesday}]

找出几个国家的隧道：

Wolfram Language code: EntityList[EntityClass["Tunnel", {"Countries" -> ContainsAny[{Entity["Country", "HongKong"], Entity["Country", "China"]}]}]]

找到史蒂文斯皮尔伯格导演的电影，演员阵容包括给定列表中的任何演员：

Wolfram Language code: EntityList[EntityClass["Movie", {"Director" -> Entity["Person", "StevenSpielberg::76z25"], "Cast" -> ContainsAny[{Entity["Person", "HarrisonFord::y8237"], Entity["Person", "TomHanks::57d8x"]}]}]]

ContainsAny 对结合有效：

Wolfram Language code: ContainsAny[<|a -> x, b -> y, c -> z|>, {y, Y}]
Wolfram Language code: ContainsAny[<|a -> x, b -> y, c -> z|>, <|1 -> y, 2 -> Y|>]

选项  (2)

SameTest  (2)

默认情况下， ContainsAny 认为同一的元素是同样的：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[6, "Meters"], 3]
Wolfram Language code: ContainsAny[list, {Quantity[1, "Meters"], Quantity[2, "Meters"]}]

只要表示的数量相同，单位换算已被考虑到：

Wolfram Language code: ContainsAny[list, {Quantity[100, "Centimeters"], Quantity[200, "Centimeters"]}]

数值近似不视为相同对象：

Wolfram Language code: ContainsAny[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}]

Equal 可以用作比较函数得到数值容忍度：

Wolfram Language code: ContainsAny[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}, SameTest -> Equal]

默认情况下字符串比较是区分大小写的：

Wolfram Language code: ContainsAny[{"A", "B", "C"}, {"a", "b"}]

比较前转换成小写：

Wolfram Language code: ContainsAny[{"A", "B", "C"}, {"a", "b"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

应用  (1)

取唐吉诃德第一卷英语翻译中的一列词：

Wolfram Language code: Length[words = ExampleData[{"Text", "DonQuixoteIEnglish"}, "Words"]]

其中包含某些现代欧洲国家的名字：

Wolfram Language code: ContainsAny[words, CanonicalName[CountryData["Europe"]]]

但其中不能含有当时还不存在的南美洲国家：

Wolfram Language code: ContainsAny[words, CanonicalName[CountryData["SouthAmerica"]]]

属性和关系  (6)

ContainsAny[list1,list2] 等价于检测列表的非空交集：

Wolfram Language code: list1 = {5, 8, 8, 3};
Wolfram Language code: list2 = {9, 10, 7, 2};
Wolfram Language code: {ContainsAny[list1, list2], Intersection[list2, list1] =!= {}}

ContainsAny[list1,list2] 等价于 IntersectingQ[list1,list2]：

Wolfram Language code: list1 = {7, 1, 10, 5};
Wolfram Language code: list2 = {5, 5, 9, 10};
Wolfram Language code: {ContainsAny[list1, list2], IntersectingQ[list2, list1]}

ContainsAny 是其自变量的对称函数. 即， ContainsAny[list1,list2]==ContainsAny[list2,list1]：

Wolfram Language code: list1 = {3, 3, 10, 9};
Wolfram Language code: list2 = {4, 3, 0, 5};
Wolfram Language code: {ContainsAny[list1, list2], ContainsAny[list2, list1]}

ContainsAny[list1,list2] 的否定等价于 ContainsNone[list1,list2]：

Wolfram Language code: list1 = {4, 3, 5, 7}
Wolfram Language code: list2 = {8, 10, 9, 5}
Wolfram Language code: {Not[ContainsAny[list1, list2]], ContainsNone[list2, list1]}

ContainsAny[list,{}] 始终返回 False：

Wolfram Language code: ContainsAny[{1, 2}, {}]
Wolfram Language code: ContainsAny[{}, {}]

作用于字符串的列表时区分大小写：

Wolfram Language code: ContainsAny[{"A", "B"}, {"a", "b", "c"}]
Wolfram Language code: ContainsAny[{"A", "B"}, {"A", "b", "c"}]
Wolfram Research (2015)，ContainsAny，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsAny.html.

文本

Wolfram Research (2015)，ContainsAny，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ContainsAny.html.

CMS

Wolfram 语言. 2015. "ContainsAny." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsAny.html.

APA

Wolfram 语言. (2015). ContainsAny. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ContainsAny.html 年

BibTeX

@misc{reference.wolfram_2026_containsany, author="Wolfram Research", title="{ContainsAny}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsAny.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsany, organization={Wolfram Research}, title={ContainsAny}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsAny.html}, note=[Accessed: 16-September-2026]}