WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ContainsNone[list1,list2]

list1が list2の要素を何も含んでいない場合はTrueを返す．

ContainsNone[list2]

適用したオブジェクトが list2の要素を何も含んでいない場合にTrueを返す，この関数の演算子形である．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
SameTest  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ContainsNone

ContainsNone[list1,list2]

list1が list2の要素を何も含んでいない場合はTrueを返す．

ContainsNone[list2]

適用したオブジェクトが list2の要素を何も含んでいない場合にTrueを返す，この関数の演算子形である．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

第1リストは第2リストのどの要素も含んでいない：

Wolfram Language code: ContainsNone[{c, d, c}, {a, b}]

最初のリストは2番目のリストの要素を含んでいる：

Wolfram Language code: ContainsNone[{c, d, c, a}, {a, b}]

スコープ  (5)

5つの母音のどれも含んでいない英単語がある：

Wolfram Language code: ContainsNone[Characters["rhythm"], {"a", "e", "i", "o", "u"}]

ContainsNoneの演算子形を使う：

Wolfram Language code: noweekend = ContainsNone[{Saturday, Sunday}]
Wolfram Language code: noweekend[{Monday, Thursday, Tuesday}]
Wolfram Language code: noweekend[{Monday, Saturday, Tuesday}]

音楽作品を選ぶ：

Wolfram Language code: EntityList[EntityClass["MusicWork", {"FirstReleaseDate" -> DateObject[{1950}, "Year", "Gregorian", -6.], "Composers" -> ContainsNone[{Entity["Person", "NatKingCole::5czsz"], Entity["Person", "ColePorter::44j37"]}]}]]

ペドロ・アルモドバル(Pedro Almodóvar)が監督し，指定された俳優が誰も出演していない映画を求める：

Wolfram Language code: EntityList[EntityClass["Movie", {"Director" -> Entity["Person", "PedroAlmodovar::8n5q5"], "Cast" -> ContainsNone[{Entity["Person", "AntonioBanderas::2tm43"], Entity["Person", "PenelopeCruz::92q5z"]}]}]]

ContainsNoneは連想に使うことができる：

Wolfram Language code: ContainsNone[<|a -> x, b -> y, c -> z|>, {r, t}]
Wolfram Language code: ContainsNone[<|a -> x, b -> y, c -> z|>, <|1 -> r, 2 -> t|>]

オプション  (2)

SameTest  (2)

デフォルトで，ContainsNoneは要素が等しければ同じであるとみなす：

Wolfram Language code: list = Subdivide[Quantity[0, "Meters"], Quantity[6, "Meters"], 3]
Wolfram Language code: ContainsNone[list, {Quantity[1, "Meters"], Quantity[2, "Meters"]}]

単位の違いは，それらが厳密に同じ数量を表している場合にのみ考慮される：

Wolfram Language code: ContainsNone[list, {Quantity[100, "Centimeters"], Quantity[200, "Centimeters"]}]

近似された数値は同じオブジェクトとはみなされない：

Wolfram Language code: ContainsNone[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}]

Equalを比較関数として使って数値許容度を持たせる：

Wolfram Language code: ContainsNone[list, {Quantity[100., "Centimeters"], Quantity[200., "Centimeters"]}, SameTest -> Equal]

文字列の比較は，デフォルトで大文字小文字の違いに敏感である：

Wolfram Language code: ContainsNone[{"A", "B", "C"}, {"a", "b"}]

比較の前に小文字に変換する：

Wolfram Language code: ContainsNone[{"A", "B", "C"}, {"a", "b"}, SameTest -> (SameQ[ToLowerCase[#1], ToLowerCase[#2]]&)]

アプリケーション  (2)

このテキスト中の単語のリストを取る：

Wolfram Language code: Length[words = ExampleData[{"Text", "AliceInWonderland"}, "Words"]]

この単語のリストは以下のどれも含まない：

Wolfram Language code: ContainsNone[ToLowerCase[words], {"bird", "fish", "flower"}]

しかし，「rabbit」が加わるとそうではなくなる：

Wolfram Language code: ContainsNone[ToLowerCase[words], {"rabbit", "bird", "fish", "flower"}]

リポグラムは指定された文字を含まないテキストのことである：

Wolfram Language code: lipogramQ[text_, letter_] := ContainsNone[Characters[text], {letter}]

「e」という文字を含まない英単語で最長のものと求める：

Wolfram Language code: MaximalBy[Select[DictionaryLookup[], lipogramQ[#, "e"]&], StringLength]

特性と関係  (5)

ContainsNone[list1,list2]は，リストの空の共通集合について検定することに等しい：

Wolfram Language code: list1 = {6, 7, 2, 8, 1};
Wolfram Language code: list2 = {4, 9, 3, 10, 4};
Wolfram Language code: {ContainsNone[list1, list2], Intersection[list2, list1] === {}}

ContainsNone[list1,list2]はDisjointQ[list1,list2]に等しい：

Wolfram Language code: list1 = {7, 6, 10, 8, 0};
Wolfram Language code: list2 = {0, 7, 0, 2, 1};
Wolfram Language code: {ContainsNone[list1, list2], DisjointQ[list2, list1]}

ContainsNoneは，その引数の対称関数である．つまり，ContainsNone[list1,list2]==ContainsNone[list2,list1]である：

Wolfram Language code: list1 = {6, 0, 10, 8, 8};
Wolfram Language code: list2 = {5, 9, 2, 7, 7};
Wolfram Language code: {ContainsNone[list1, list2], ContainsNone[list2, list1]}

ContainsNone[list1,list2]の否定はContainsAny[list1,list2]に等しい：

Wolfram Language code: list1 = {6, 5, 10, 8, 4};
Wolfram Language code: list2 = {7, 1, 10, 0, 2};
Wolfram Language code: {Not[ContainsNone[list1, list2]], ContainsAny[list1, list2]}

ContainsNone[list,{}]は，常にTrueを返す：

Wolfram Language code: ContainsNone[{1, 2}, {}]
Wolfram Language code: ContainsNone[{}, {}]
Wolfram Research (2015), ContainsNone, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsNone.html.

テキスト

Wolfram Research (2015), ContainsNone, Wolfram言語関数， https://reference.wolfram.com/language/ref/ContainsNone.html.

CMS

Wolfram Language. 2015. "ContainsNone." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ContainsNone.html.

APA

Wolfram Language. (2015). ContainsNone. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ContainsNone.html

BibTeX

@misc{reference.wolfram_2026_containsnone, author="Wolfram Research", title="{ContainsNone}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ContainsNone.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_containsnone, organization={Wolfram Research}, title={ContainsNone}, year={2015}, url={https://reference.wolfram.com/language/ref/ContainsNone.html}, note=[Accessed: 16-September-2026]}