ConvectionPDETerm

ConvectionPDETerm[vars,β]

対流係数，モデル変数 vars の対流項を表す．

ConvectionPDETerm[vars,β,pars]

モデルパラメータ pars を使う．

詳細

対流項は，熱力学，音響学，構造力学，流体力学等，数多くの分野で使われている．
対流は移流としても知られている．
対流係数がある対流は，大規模移動による従属変数の輸送過程である．

ConvectionPDETermは，偏微分方程式の一部として使われる微分演算子項を返す．

ConvectionPDETermを使って，従属変数，独立変数，時間変数の対流方程式がモデル化できる．
定常モデル変数 vars は vars={u[x₁,…,x_n],{x₁,…,x_n}}である．
時間依存モデル変数 vars は vars={u[t,x₁,…,x_n],{x₁,…,x_n}}または vars={u[t,x₁,…,x_n],t,{x₁,…,x_n}}である．
他のPDE項との関連での対流項は以下で与えられる．

対流の間，対流が起こっている媒介は輸送機構となるのに対し，拡散の場合の媒介は静止したままである．
対流係数は次の形を持つことができる．
{β₁,…,β_n} ベクトル
従属変数が{u₁,…,u_m}の偏微分方程式系についての対流は以下を表す．

以下は，PDE項の系との関連での対流項である．

対流係数はの形の階数3のテンソルである．各部分行列は単一の従属変数と同じ方法で指定できる長さのベクトルである．
記号対流係数はVectorSymbolで指定できる． »
保存型の対流係数は，時間，空間，パラメータ，従属変数に依存することがある．
次は，使用可能なパラメータpars である．
パラメータデフォルトシンボル

"CoordinateChart" "Cartesian"
係数はNeumannValueの意味をもたらすことはない．
与えられた独立変数に明示的に依存しないすべての数量の偏導関数は0であるとみなされる．
ConservativeConvectionPDETermと緊密な関係がある．

例題

すべて開くすべて閉じる

例 (4)

時間非依存対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {2}]

時間依存対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {2}]

2D定常対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {1, 0}]

基本項で構築された対流拡散方程式を解く：

Wolfram Language code:

vars = {u[x, y], {x, y}};
NDSolveValue[{DiffusionPDETerm[vars, 1] + ConvectionPDETerm[vars, {2, 0}] == SourcePDETerm[vars, -1], DirichletCondition[u[x, y] == 0, x == 0 || y == 0]}, u[x, y], {x, y}∈Rectangle[]]

結果を可視化する：

Wolfram Language code: ContourPlot[%, {x, y}∈Rectangle[]]

スコープ (10)

記号対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {a}]

記号ベクトル対流係数を持つ定常従属対流項を定義する：

Wolfram Language code:

β = VectorSymbol["β", {1}];
ConvectionPDETerm[{u[x], {x}}, β]

項をアクティブにする：

Wolfram Language code: %//Activate

記号ベクトル対流係数を置換して定常従属対流項を定義する：

Wolfram Language code:

β = VectorSymbol["β", {1}];
ConvectionPDETerm[{u[x], {x}}, β, <|β -> {1}|>]

記号ベクトル対流係数を置換して時間依存対流項を定義する：

Wolfram Language code:

β = VectorSymbol["β", {1}];
ConvectionPDETerm[{u[t, x], t, {x}}, β, <|β -> {1}|>]

1D軸対称時間非依存対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[r], {r}}, {2}, <|"RegionSymmetry" -> "Axisymmetric"|>]

Activateを項に適用する：

Wolfram Language code: Activate[%]

時間非依存2D対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, 1}]

非線形時間非依存2D対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, u[x, y] ^ 2}]

非線形時間依存2D対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{u[t, x, y], t, {x, y}}, {2, u[x, y] ^ 2}]

複数の従属変数で対流項を定義する：

Wolfram Language code: ConvectionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, {{{1, 0}, {0, 2}}, {{0, 0}, {0, 1}}}]

ストークス(Stokes)流れのモデルを定義する：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

記号方程式を設定する：

Wolfram Language code: stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, μ] == {0, 0, 0}

アプリケーション (3)

DiffusionPDETermを使ってダムの下の種の拡散をモデル化する．領域を設定する：

Wolfram Language code:

Subscript[Ω, dam] = Rectangle[{6, 3}, {12, 18}];
Subscript[Ω, sediment] = RegionDifference[Rectangle[{0, 0}, {18, 6}], Subscript[Ω, dam]];

モデルを設定する：

Wolfram Language code: model = DiffusionPDETerm[{u[x, y], {x, y}}, 10 ^ -4]

方程式を解く：

Wolfram Language code:

solution = NDSolveValue[{model == 0, DirichletCondition[u[x, y] == 16, x ≤ 6 && y == 6], DirichletCondition[u[x, y] == 8, x ≥ 12 && y == 6]}, u, {x, y}∈Subscript[Ω, sediment]]

流束を計算する：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

結果を可視化する：

Wolfram Language code:

Show[
	..., 
	VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]]
	]//Quiet

ダムの下の種の濃度を求める．モデルを構築する：

Wolfram Language code:

op = DiffusionPDETerm[{c[x, y], {x, y}}, 1] + ConvectionPDETerm[{c[x, y], {x, y}}, flux /. u -> solution] + 2 * 10 ^ -5c[x, y];

方程式を解く：

Wolfram Language code:

concentration = NDSolveValue[{op == 0, 
	DirichletCondition[c[x, y] == 100, x ≤ 6 && y == 6], DirichletCondition[c[x, y] == 50, x ≥ 12 && y == 6]
	}, c, {x, y}∈Subscript[Ω, sediment]]

種の濃度を可視化する：

Wolfram Language code:

Show[
	..., 
	ContourPlot[concentration[x, y], {x, y}∈concentration["ElementMesh"], ...], 
	VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]]
	]//Quiet

ストークス流れのモデルを定義する：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

方程式を設定する：

Wolfram Language code: eqn = stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1] == {0, 0, 0}

狭まる領域を定義する：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1, 1 / 2}], Rectangle[{1, 1 / 10}, {2, 2 / 5}]];

境界条件を設定する：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 4 * 0.3 * y * (0.5 - y) / (0.41) ^ 2, v[x, y] == 0.}, x == 0.], DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, 0 < x < 2], 
	DirichletCondition[p[x, y] == 0., x == 2]};

方程式を解く：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

解を可視化する：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

ストークス流れのモデルを拡大してナビエ(Navier)・ストークス流れのモデルにする．ストークス流れのモデルを定義する：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

ナビエ・ストークス流れのモデルを定義する：

Wolfram Language code:

navierStokesModel[vars_, μ_, ρ_] := stokesModel[vars, μ] + ConvectionPDETerm[vars, {{ρ vars[[1, {1, 2}]], 0, 0}, {0, ρ vars[[1, {1, 2}]], 0}, {0, 0, 0}}]

方程式を設定する：

Wolfram Language code: eqn = navierStokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1, 10 ^ -3] == {0, 0, 0}

領域を定義する：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}];

境界条件を設定する：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 1, v[x, y] == 0}, y == 1], DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, y < 1], 
	DirichletCondition[p[x, y] == 0, x == 0 && y == 1]};

方程式を解く：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

解を可視化する：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]

考えられる問題 (2)

流速場が0の対流項を評価すると0になる：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, 0]

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {0}]

記号対流係数は十分な長さである必要がある：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, v]

記号ベクトル対流係数の指定にはVectorSymbolを使用する：

Wolfram Language code:

vs = VectorSymbol["v", {1}];
ConvectionPDETerm[{u[x], {x}}, vs]

項をアクティブにする：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs]//Activate

VectorSymbolに実際の値を代入する：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs, <|vs -> {1}|>]

記号対流係数をベクトルとして指定することもできる：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {v}, <|v -> 1|>]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ConvectionPDETerm

詳細

例題

例 (4)

スコープ (10)

アプリケーション (3)

考えられる問題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

	パラメータ	デフォルト	シンボル
	"CoordinateChart"	"Cartesian"

ConvectionPDETerm

詳細

例題

例 (4)

スコープ (10)

アプリケーション (3)

考えられる問題 (2)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX