WOLFRAM

Wolfram 语言与系统参考资料中心

ConvectionPDETerm[vars,β]

表示具有对流系数 和模型变量 vars 的对流项 .

ConvectionPDETerm[vars,β,pars]

使用模型参数 pars.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ConvectionPDETerm

ConvectionPDETerm[vars,β]

表示具有对流系数 和模型变量 vars 的对流项 .

ConvectionPDETerm[vars,β,pars]

使用模型参数 pars.

更多信息

  • 对流项用于许多领域，例如热力学、声学、结构力学和流体动力学等.
  • 对流 (Convection) 也称作 Advection.
  • 对流系数为 的对流是因变量 由于宏观运动而传输的过程：
  • ConvectionPDETerm 返回微分算子项，该项将用作偏微分方程的一部分：
  • ConvectionPDETerm 可用来模拟对流方程，其中因变量为 ，自变量为 ，时间变量为 .
  • 平稳模拟变量 vars 为 vars={u[x1,…,xn],{x1,…,xn}}.
  • 与时间相关的模型变量 vars 为 vars={u[t,x1,…,xn],{x1,…,xn}} 或 vars={u[t,x1,…,xn],t,{x1,…,xn}}.
  • 与其他偏微分方程项结合使用的对流项 由下式给出：
  • 在对流过程中，发生对流的介质是传输机制，这与介质保持静止的扩散相反.
  • 对流系数 具有以下形式：
  • {β1,…,βn}(beta_(1),...,beta_(n))vector
  • 对于因变量为 {u1,…,um} 的偏微分方程组，对流表示：
  • 对流项在相关的偏微分方程组中：
  • 对流系数 是秩为 3 的张量，形如 ，其中各子矩阵 为长度为 的向量，其指定方式与单个因变量的指定方式相同.
  • 符号式对流系数可以通过 VectorSymbol 指定. »
  • 保守对流系数 可取决于时间、空间、参数和因变量.
  • 可以给出以下参数 pars：
  • 参数默认符号
    "CoordinateChart""Cartesian"
  • 系数 不影响 NeumannValue 的意义.
  • 所有不明确依赖于给定自变量的量，其偏导数均被视为零.
  • ConservativeConvectionPDETerm 密切相关.

范例

打开所有单元 关闭所有单元

基本范例  (4)

定义与时间无关的对流项：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {2}]

定义与时间相关的对流项：

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {2}]

定义二维平稳对流项：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {1, 0}]

求解由基本项构建的对流扩散方程：

Wolfram Language code: vars = {u[x, y], {x, y}}; NDSolveValue[{DiffusionPDETerm[vars, 1] + ConvectionPDETerm[vars, {2, 0}] == SourcePDETerm[vars, -1], DirichletCondition[u[x, y] == 0, x == 0 || y == 0]}, u[x, y], {x, y}∈Rectangle[]]

可视化结果：

Wolfram Language code: ContourPlot[%, {x, y}∈Rectangle[]]

范围  (10)

定义符号对流项：

Wolfram Language code: ConvectionPDETerm[{u[t, x], t, {x}}, {a}]

用符号式向量对流系数定义稳态相关对流项：

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[x], {x}}, β]

激活该项：

Wolfram Language code: %//Activate

定义一个稳态相关对流项，并用符号式向量对流系数替换：

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[x], {x}}, β, <|β -> {1}|>]

定义一个时间相关对流项，并用符号式向量对流系数替换：

Wolfram Language code: β = VectorSymbol["β", {1}]; ConvectionPDETerm[{u[t, x], t, {x}}, β, <|β -> {1}|>]

定义一维轴对称时间无关对流项：

Wolfram Language code: ConvectionPDETerm[{u[r], {r}}, {2}, <|"RegionSymmetry" -> "Axisymmetric"|>]

对该项应用 Activate：

Wolfram Language code: Activate[%]

定义与时间无关的二维对流项：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, 1}]

定义与时间无关的非线性二维对流项：

Wolfram Language code: ConvectionPDETerm[{u[x, y], {x, y}}, {2, u[x, y] ^ 2}]

定义与时间相关的非线性二维对流项：

Wolfram Language code: ConvectionPDETerm[{u[t, x, y], t, {x, y}}, {2, u[x, y] ^ 2}]

使用多个因变量定义对流项：

Wolfram Language code: ConvectionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, {{{1, 0}, {0, 2}}, {{0, 0}, {0, 1}}}]

定义斯托克斯流模型：

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

建立符号方程：

Wolfram Language code: stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, μ] == {0, 0, 0}

应用  (3)

使用 DiffusionPDETerm 模拟大坝下的物种扩散. 设置区域：

Wolfram Language code: Subscript[Ω, dam] = Rectangle[{6, 3}, {12, 18}]; Subscript[Ω, sediment] = RegionDifference[Rectangle[{0, 0}, {18, 6}], Subscript[Ω, dam]];

设置模型：

Wolfram Language code: model = DiffusionPDETerm[{u[x, y], {x, y}}, 10 ^ -4]

解方程：

Wolfram Language code: solution = NDSolveValue[{model == 0, DirichletCondition[u[x, y] == 16, x ≤ 6 && y == 6], DirichletCondition[u[x, y] == 8, x ≥ 12 && y == 6]}, u, {x, y}∈Subscript[Ω, sediment]]

计算通量：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

可视化结果：

Wolfram Language code: Show[ ..., VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]] ]//Quiet

求大坝下的物种浓度. 构造模型：

Wolfram Language code: op = DiffusionPDETerm[{c[x, y], {x, y}}, 1] + ConvectionPDETerm[{c[x, y], {x, y}}, flux /. u -> solution] + 2 * 10 ^ -5c[x, y];

解方程：

Wolfram Language code: concentration = NDSolveValue[{op == 0, DirichletCondition[c[x, y] == 100, x ≤ 6 && y == 6], DirichletCondition[c[x, y] == 50, x ≥ 12 && y == 6] }, c, {x, y}∈Subscript[Ω, sediment]]

可视化物种浓度：

Wolfram Language code: Show[ ..., ContourPlot[concentration[x, y], {x, y}∈concentration["ElementMesh"], ...], VectorPlot[Evaluate[flux /. u -> solution], {x, 0, 18}, {y, 0, 6}, Rule[...]] ]//Quiet

定义斯托克斯流模型：

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

建立方程；

Wolfram Language code: eqn = stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1] == {0, 0, 0}

定义一个逐渐缩小的区域：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1, 1 / 2}], Rectangle[{1, 1 / 10}, {2, 2 / 5}]];

设置边界条件：

Wolfram Language code: bcs = {DirichletCondition[ {u[x, y] == 4 * 0.3 * y * (0.5 - y) / (0.41) ^ 2, v[x, y] == 0.}, x == 0.], DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, 0 < x < 2], DirichletCondition[p[x, y] == 0., x == 2]};

解方程：

Wolfram Language code: {xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

可视化解：

Wolfram Language code: VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

将斯托克斯流模型扩展为纳维-斯托克斯流模型. 定义斯托克斯流模型：

Wolfram Language code: stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

定义纳维-斯托克斯流模型：

Wolfram Language code: navierStokesModel[vars_, μ_, ρ_] := stokesModel[vars, μ] + ConvectionPDETerm[vars, {{ρ vars[[1, {1, 2}]], 0, 0}, {0, ρ vars[[1, {1, 2}]], 0}, {0, 0, 0}}]

建立方程：

Wolfram Language code: eqn = navierStokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1, 10 ^ -3] == {0, 0, 0}

定义区域：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}];

设置边界条件：

Wolfram Language code: bcs = {DirichletCondition[ {u[x, y] == 1, v[x, y] == 0}, y == 1], DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, y < 1], DirichletCondition[p[x, y] == 0, x == 0 && y == 1]};

解方程：

Wolfram Language code: {xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

可视化解；

Wolfram Language code: VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]

可能存在的问题  (2)

如果流速场为 0，对流项的值为 0：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, 0]
Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {0}]

符号对流系数需要有足够的长度：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, v]

指定符号式向量对流系数的方法是通过 VectorSymbol：

Wolfram Language code: vs = VectorSymbol["v", {1}]; ConvectionPDETerm[{u[x], {x}}, vs]

激活该项：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs]//Activate

用实际值替换 VectorSymbol：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, vs, <|vs -> {1}|>]

另一种方法是将符号对流系数指定为向量：

Wolfram Language code: ConvectionPDETerm[{u[x], {x}}, {v}, <|v -> 1|>]
Wolfram Research (2020)，ConvectionPDETerm，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConvectionPDETerm.html （更新于 2026 年）.

文本

Wolfram Research (2020)，ConvectionPDETerm，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConvectionPDETerm.html （更新于 2026 年）.

CMS

Wolfram 语言. 2020. "ConvectionPDETerm." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2026. https://reference.wolfram.com/language/ref/ConvectionPDETerm.html.

APA

Wolfram 语言. (2020). ConvectionPDETerm. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConvectionPDETerm.html 年

BibTeX

@misc{reference.wolfram_2026_convectionpdeterm, author="Wolfram Research", title="{ConvectionPDETerm}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ConvectionPDETerm.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_convectionpdeterm, organization={Wolfram Research}, title={ConvectionPDETerm}, year={2026}, url={https://reference.wolfram.com/language/ref/ConvectionPDETerm.html}, note=[Accessed: 16-September-2026]}