WOLFRAM

Wolfram 语言与系统参考资料中心

CoordinateBounds[coords]

给出由 coords 定义的区域的边界在每个维度的范围列表 {{xmin,xmax},{ymin,ymax},…}.

CoordinateBounds[coords,δ]

在每个维度把范围坐标外扩 ±δ.

CoordinateBounds[coords,Scaled[s]]

在每个维度外扩缩放量 s.

CoordinateBounds[coords,{p1,p2,…}]

在各个维度分别外扩 p1, p2, ….

CoordinateBounds[coords,{{p1min,p1max},{p2min,p2max},…}]

给出 {{xmin-p1min,xmax+p1max},{ymin-p2min,ymax+p2max},…}.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CoordinateBounds

CoordinateBounds[coords]

给出由 coords 定义的区域的边界在每个维度的范围列表 {{xmin,xmax},{ymin,ymax},…}.

CoordinateBounds[coords,δ]

在每个维度把范围坐标外扩 ±δ.

CoordinateBounds[coords,Scaled[s]]

在每个维度外扩缩放量 s.

CoordinateBounds[coords,{p1,p2,…}]

在各个维度分别外扩 p1, p2, ….

CoordinateBounds[coords,{{p1min,p1max},{p2min,p2max},…}]

给出 {{xmin-p1min,xmax+p1max},{ymin-p2min,ymax+p2max},…}.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

找出二维情况下坐标点集的边界：

Wolfram Language code: CoordinateBounds[{{0, 1}, {1, 2}, {2, 1}, {3, 2}, {4, 0}}]

往各方向外扩 1：

Wolfram Language code: CoordinateBounds[{{0, 1}, {1, 2}, {2, 1}, {3, 2}, {4, 0}}, 1]

在各维度外扩边界范围的 1/4：

Wolfram Language code: CoordinateBounds[{{0, 1}, {1, 2}, {2, 1}, {3, 2}, {4, 0}}, Scaled[1 / 4]]

范围  (4)

求五边形顶点的边界坐标范围：

Wolfram Language code: CirclePoints[5]
Wolfram Language code: CoordinateBounds[%]

求参差不齐的数组中数据对的边界坐标范围：

Wolfram Language code: CoordinateBounds[{{1, 2}, {{{{{5, 6}}}}, {9, 10}}}]

求一组二维点的边界坐标范围，并在所有方向上向外扩展一个单位：

Wolfram Language code: pts = {{3, -3}, {3, 3}, {-3, 3}, {-3, -3}};
Wolfram Language code: CoordinateBounds[pts, 1]

在水平和垂直方向上外扩不同的量：

Wolfram Language code: CoordinateBounds[pts, {1, 2}]

在四个方向上分别指定不同的外扩：

Wolfram Language code: CoordinateBounds[pts, {{1, 2}, {3, 4}}]

获取不同类型的三维坐标：

Wolfram Language code: coords = {{{0.0736388, 2.2431, -0.34123}, {-1.1412, 0.75341, 5.34125}}, {π, E, Sqrt[2]}, {Exp[2], Log[10000], Csc[(1/10)]}, {{{2, 1, 7}, {-9, -5, 7}}, {{-2, 9, 5}, {8, -9, 9}}}};

找出它们的边界：

Wolfram Language code: CoordinateBounds[coords]

在每个维度上外扩 1：

Wolfram Language code: CoordinateBounds[coords, 1]

在每个维度上外扩一定比例：

Wolfram Language code: CoordinateBounds[coords, Scaled[.1]]

在不同维度上外扩不同的量：

Wolfram Language code: CoordinateBounds[coords, {.1, Scaled[.2], .3}]

外扩不同的最大值和最小值：

Wolfram Language code: CoordinateBounds[coords, {0, 1}]

在每个方向上进行不同的外扩：

Wolfram Language code: CoordinateBounds[coords, {{0, 1}, {1.5, 0.5}, {1 / 2, 1 / 3}}]

推广和延伸  (1)

当有坐标不是数值时，结果通常用带有 Min 和 Max 的表达式表示：

Wolfram Language code: CoordinateBounds[{{1, 2}, {a, b}, {3, 2}}]

应用  (1)

求南美洲各国的三元组 {面积, 人口, GDP} 数据：

Wolfram Language code: EntityValue[EntityClass["Country", "SouthAmerica"], {"Area", "Population", "GDP"}]

求三个量的范围：

Wolfram Language code: CoordinateBounds[%]

属性和关系  (4)

一般来说，CoordinateBounds[coords] 是 CoordinateBoundingBox[coords] 的转置：

Wolfram Language code: coords = RandomReal[1, {12, 4}];
Wolfram Language code: CoordinateBounds[coords]
Wolfram Language code: Transpose[CoordinateBoundingBox[coords]]

对矩阵中的坐标，CoordinateBounds[coords] 等价于 Map[MinMax, Transpose[coords]]：

Wolfram Language code: coords = RandomInteger[{-9, 9}, {47, 6}];
Wolfram Language code: CoordinateBounds[coords]
Wolfram Language code: Map[MinMax, Transpose[coords]]

取一个随机多边形：

Wolfram Language code: pol = RandomPolygon[10]

求其坐标的范围：

Wolfram Language code: CoordinateBounds[PolygonCoordinates[pol]]

将 RegionBounds 应用于多边形可以得到相同的结果：

Wolfram Language code: RegionBounds[pol]
Wolfram Language code: Graphics[{Opacity[0.5], pol, EdgeForm[Magenta], FaceForm[], Rectangle@@Transpose[%]}, Frame -> True]

在法国境内随机采集 500 个地理位置：

Wolfram Language code: gps = RandomGeoPosition[Entity["Country", "France"], 500]

求纬度和经度值的坐标范围：

Wolfram Language code: CoordinateBounds[LatitudeLongitude[gps]]

可通过 GeoBounds 获得同样的结果，以度数形式表示：

Wolfram Language code: GeoBounds[gps]

在地图上绘制这 500 个点和边界框：

Wolfram Language code: GeoGraphics[{GeoBoundsRegion[%], Orange, Point[gps]}]
Wolfram Research (2015)，CoordinateBounds，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBounds.html.

文本

Wolfram Research (2015)，CoordinateBounds，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBounds.html.

CMS

Wolfram 语言. 2015. "CoordinateBounds." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoordinateBounds.html.

APA

Wolfram 语言. (2015). CoordinateBounds. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoordinateBounds.html 年

BibTeX

@misc{reference.wolfram_2026_coordinatebounds, author="Wolfram Research", title="{CoordinateBounds}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateBounds.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinatebounds, organization={Wolfram Research}, title={CoordinateBounds}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateBounds.html}, note=[Accessed: 11-September-2026]}