Coth

Coth[z]

z の双曲線余接を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
Cosh[z]/Sinh[z]は自動的にCoth[z]に変換される．分解するにはTrigFactorList[expr]を使う．
特別な引数の場合，Cothは自動的に厳密値を計算する．
Cothは任意の数値精度で評価できる．
Cothは自動的にリストに縫い込まれる． »
CothはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

Cothは，双曲線余接関数である．これは，三角法で頻繁に使われる，Cot円関数の双曲線バージョンのようなものである．Coth[α] は，によって，対応する双曲線正弦関数と双曲線余弦関数の比として定義される．Cothはとしても定義される．ただし，は自然対数Logの底である．
Cothは，その引数が有理数の（自然）対数であるときは，自動的に厳密値に評価される．引数として厳密な数式が与えられると，Cothは任意の数値精度に評価されることがある．TrigFactorListを使って，Cothを含む式をSinh，Cosh，Sin，Cosを含む項に因子分解することができる．Cothを含む記号式の操作に便利なその他の演算には，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
Cothは要素単位でリストおよび行列に縫い込まれる．対照的に，MatrixFunctionを使って，正方行列の双曲線余接（つまり，通常のベキが行列のベキで置き換えられた双曲線余接関数のベキ級数）を与えることができる．
Coth[x]は，小さい負の x についてはに近付き，大きい正の x についてはに近付く．Cothは，Cotによって満足されるような，ピタゴラス(Pythagorean)の恒等式に似た恒等式を満足する．双曲線正弦関数の定義は，恒等式およびによって，複素引数にまで拡張される．Cothは整数について値において極を持ち，これらの点で評価するとComplexInfinityになる．Coth[z]は，原点付近で級数展開 $sum_(k=0)^infty(2^(2 k) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ を持つ．これはベルヌーイ(Bernoulli)数BernoulliBによって表すことができることもある．
Cothの逆関数はArcCothである．他の関連する数学関数には，Tanh，Cot，Coshがある．

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: Coth[1.2]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Coth[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Coth[z], {z, -π / 2 - 3I, π / 2 + 3I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Coth[x], {x, 0, 10}]

特異点における漸近展開：

Wolfram Language code: Series[Coth[x], {x, 2I π, 3}]

スコープ (47)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Coth[1.2]

高精度で評価する：

Wolfram Language code: N[Coth[12 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Coth[1.20000000000000000000000]

Cothは複素数の入力を取ることができる：

Wolfram Language code: Coth[2.5 + I]

Cothを高精度で効率よく評価する：

Wolfram Language code: Coth[1.2`500]//Timing

Wolfram Language code: Coth[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Coth[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

MatrixFunctionを使って行列のCoth関数を計算することもできる：

Wolfram Language code: MatrixFunction[Coth[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Coth[Interval[{Log[2], Log[7]}]]

Wolfram Language code: Coth[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Coth[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Coth[Around[Sqrt[3], 0.1]]

特定の値 (5)

固定された純粋な虚点におけるCothの値：

Wolfram Language code: Table[Coth[I(π/12)n], {n, 1, 6}]

無限大における値：

Wolfram Language code: Coth[Infinity]

Wolfram Language code: Coth[ComplexInfinity]

Cothの特異点：

Wolfram Language code: Coth[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := Coth[x] - Log[3];

Wolfram Language code: sol = Solve[f[x] == 0 && 0 < x, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 4}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

単純で厳密値は自動的に生成される：

Wolfram Language code: Coth[I Pi / 3]

より複雑な場合には明示的にFunctionExpandを使う必要がある：

Wolfram Language code: Coth[I Pi / 24]

Wolfram Language code: FunctionExpand[%]

可視化 (3)

Coth関数をプロットする：

Wolfram Language code: Plot[Coth[x], {x, -5, 5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Coth[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Coth[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code:

Table[PolarPlot[Coth[k ϕ], {ϕ, -π / 2, 3π}, Sequence[Frame -> True, Exclusions -> All, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {{-2, 2}, {-1.5, 1.5}}, PlotLabel -> "k=" <> ToString[k]]], {k, 1, 6}]

関数の特性 (12)

Cothは0を除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[Coth[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Coth[z], z, Complexes]

Cothは，開区間からのものを除くすべての実数値に達する：

Wolfram Language code: FunctionRange[Coth[x], x, y]

Cothは奇関数である：

Wolfram Language code: Coth[-x]

Cothは鏡特性を有する：

Wolfram Language code: FullSimplify[Coth[Conjugate[z]] == Conjugate[Coth[z]]]

Cothは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Coth[x], x]

しかし，有理型ではある：

Wolfram Language code: FunctionMeromorphic[Coth[x], x]

Cothは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[Coth[x], x]

Cothは単射である：

Wolfram Language code: FunctionInjective[Coth[x], x]

Wolfram Language code: Plot[{Coth[x], 2}, {x, -4, 4}]

Cothは全射ではない：

Wolfram Language code: FunctionSurjective[Coth[x], x]

Wolfram Language code: Limit[Coth[x], x -> ∞]

Wolfram Language code: Plot[{Coth[x], .5}, {x, -4, 4}]

Cothは非負でも非正でもない：

Wolfram Language code: FunctionSign[Coth[x], x]

零点に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Coth[x], x]

Wolfram Language code: FunctionDiscontinuities[Coth[x], x]

Cothは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Coth[x], x]

TraditionalFormによる表示：

Wolfram Language code: Coth[x]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Coth[x], x]

高次導関数：

Wolfram Language code: Table[D[Coth[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Coth[x], {x, n}]

積分 (3)

Cothの不定積分：

Wolfram Language code: Integrate[Coth[x], x]

原点を中心とした区間上の奇関数の定積分は0である：

Wolfram Language code: Integrate[Coth[x], {x, -1, 1}, PrincipalValue -> True]

その他の積分例：

Wolfram Language code: Integrate[Coth[x]Sinh[x], x]

Wolfram Language code: Integrate[x ^ 2Coth[x], x]

級数展開 (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Coth[x], {x, Log[2], 7}]

の周りのCothの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Coth[x], {x, Log[2], m}], {m, 0, 5, 2}];
Plot[{Coth[x], terms}, {x, .5, 1.5}]

Cothの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Coth[x], {x, 0, n}]

Cothはベキ級数に適用できる：

Wolfram Language code: Coth[x + (x^2/2) + (x^3/9) + O[x]^4]

積分変換 (2)

LaplaceTransformを使ってラプラス変換を計算する：

Wolfram Language code: LaplaceTransform[Coth[t], t, s]

FourierTransform：

Wolfram Language code: FourierTransform[Coth[ω], ω, t]

関数の恒等式と簡約 (6)

倍角のCoth：

Wolfram Language code: Expand[Coth[2x], Trig -> True]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Coth[4x]]

Wolfram Language code: TrigReduce[%]

総和のCoth：

Wolfram Language code: TrigExpand[Coth[x + y]]

双曲線関数の総和を積に変換する：

Wolfram Language code: TrigFactor[Coth[x] + Coth[y]]

Wolfram Language code: TrigExpand[%]

実変数を仮定して展開する：

Wolfram Language code: ComplexExpand[Coth[x + I y]]

指数関数に変換する：

Wolfram Language code: TrigToExp[Coth[z]]

関数表現 (4)

Cotを介した表現：

Wolfram Language code: Simplify[I Cot[I y]]

ベッセル(Bessel)関数を介した表現：

Wolfram Language code: Simplify[BesselI[-(1/2), x] / BesselI[(1/2), x]]

ヤコビ関数を介した表現：

Wolfram Language code: JacobiNS[z, 1]

Wolfram Language code: I JacobiSC[(π/2) - I z, 0]

マシュー(Mathieu)関数を介した表現：

Wolfram Language code: (I MathieuC[1, 0, I z]/MathieuS[1, 0, I z])

アプリケーション (5)

複素平面上で絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[Coth[x + I y]], {x, -2, 2}, {y, -2Pi, 2Pi}]

整数の平方根のニュートン(Newton)反復の閉じた形：

Wolfram Language code: With[{n = 3.}, Table[Sqrt[n]Coth[2 ^ k ArcTanh[Sqrt[n]]], {k, 0, 5}]]//Chop

明示的な反復と比較する：

Wolfram Language code: NestList[(# + 3 / #) / 2&, 1., 5]

積をCothで積分したボゾン松原周波数の総和：

Wolfram Language code: NIntegrate[Coth[x] / (x + 2), {x, 1 + 11Pi / 2I, -1 + 11Pi / 2I, -1 - 11Pi / 2I, 1 - 11Pi / 2I, 1 + 11Pi / 2I}]//Chop

Wolfram Language code: 2Pi I Sum[Residue[Coth[x] / (x + 2), {x, k I Pi}], {k, -5, 5}]//N//Chop

磁場における双極のための温度に依存するブリュアン関数：

Wolfram Language code: bf[j_, T_] := (1 + (1/2j))Coth[(1 + (1/2j))(1/T)] - (1/2j)Coth[(1/2j)(1/T)]

低温と高温における動作：

Wolfram Language code: Series[bf[j, T], {T, Infinity, 2}]

Wolfram Language code: Limit[bf[j, T], T -> 0, Assumptions -> j > 0, Direction -> -1]

Coth関数を不均一な部分として微分方程式を解く：

Wolfram Language code: DSolve[y'[x] - x y[x] - Coth[x] == 0, y[x], x]

特性と関係 (11)

Cothの基本的なパリティと周期性の特性は自動的に適用される：

Wolfram Language code: Coth[x + Pi I]

Wolfram Language code: Coth[-x]

Wolfram Language code: Coth[I x]

SimplifyとFullSimplifyを使ってCothを含む式を簡約する：

Wolfram Language code: Simplify[2Coth[2z] / (1 + Coth[z] ^ 2)]

Wolfram Language code: FullSimplify[Coth[Log[GoldenRatio]]]

FunctionExpandを使って累乗根における特別な値を表現する：

Wolfram Language code: FunctionExpand[Coth[I Pi / 16]]

逆関数で構成する：

Wolfram Language code: {Coth[ArcCoth[z]], Coth[2ArcCoth[z]], Coth[3ArcCoth[z]]}

Wolfram Language code: FunctionExpand[%]//Simplify

双曲線方程式を解く：

Wolfram Language code: Reduce[Coth[z]^2 + Coth[z + 2] == 1, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Coth[z]^3 - 3Coth[z + 1] + z == 3, {z, 1}]

双曲線方程式を簡約する：

Wolfram Language code: Reduce[Coth[a x + b] == c, x, Complexes]

積分：

Wolfram Language code: FourierTransform[Coth[t], t, s]//FullSimplify

総和と積分からCothを求める：

Wolfram Language code: Sum[1 / (z ^ 2 + k ^ 2 Pi ^ 2), {k, 1, Infinity}]//Simplify

Wolfram Language code: Integrate[Csch[t] ^ 2, {t, I Pi / 2, z}]

Cothは特殊関数の特別な場合に見られる：

Wolfram Language code: {WeierstrassP[I z, {3, 1}], JacobiCS[I z, 0]}

Cothは数値関数である：

Wolfram Language code: Attributes[Coth]

Wolfram Language code: NumericQ[Coth[2 + E]]

考えられる問題 (4)

機械精度の入力は正しい答を出すためには不十分である：

Wolfram Language code: Coth[10. ^ 30 I]

厳密な入力を与えると正しい答が返される：

Wolfram Language code: N[Coth[10 ^ 30I], 20]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Coth[10 ^ 100 I], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Coth[10 ^ 100I], 20]]

Cothが真性特異点を持つ無限大にはベキ級数は存在しない：

Wolfram Language code: Series[Coth[x], {x, Infinity, 2}]

TraditionalFormでは引数の前後に丸カッコが必要である：

Wolfram Language code: coth x

Wolfram Language code: coth(x)

おもしろい例題 (1)

無限大におけるCothをプロットする：

Wolfram Language code:

ContourPlot[Arg[Coth[1 / (x + I y)]], {x, -1 / 4, 1 / 4}, {y, -1 / 2, 1 / 2}, Exclusions -> {}, PlotPoints -> 60, MaxRecursion -> 1, Contours -> 10]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Coth

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (5)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (5)

特性と関係 (11)

考えられる問題 (4)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Coth

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (5)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (5)

特性と関係 (11)

考えられる問題 (4)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX