WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoulombF[l,η,r]

正則クーロン(Coulomb)波動関数 TemplateBox[{l, eta, r}, CoulombF]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特別な値  
可視化  
関数の特性  
級数展開  
関数表現  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CoulombF

CoulombF[l,η,r]

正則クーロン(Coulomb)波動関数 TemplateBox[{l, eta, r}, CoulombF]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • CoulombF[l,η,r]は常微分方程式 の解である．
  • CoulombF[l,η,r]は の近くで に比例する．
  • CoulombF[l,η,r]は大きい と何らかの位相シフト についてになる傾向がある．
  • CoulombFはからまでの複素 平面上に不連続な分枝切断線を持つ．
  • CoulombFは特定の引数については自動的に厳密値に評価される．
  • CoulombFは任意の数値精度で評価することができる．
  • CoulombFは自動的にリストに縫い込まれる．
  • CoulombFはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: CoulombF[3, 0.12, 7.]

任意精度で評価する：

Wolfram Language code: N[CoulombF[3, 2, 5], 50]

斥力()と引力)の相互作用についてクーロン波動関数をプロットする：

Wolfram Language code: Plot[{CoulombF[0, 0.3, r], CoulombF[0, -0.3, r]}, {r, 0, 10}]

複素数プロット：

Wolfram Language code: ComplexPlot[CoulombF[3 / 2, 1 / 4, z], {z, -3 - 3I, 3 + 3I}]

原点における級数展開：

Wolfram Language code: Series[CoulombF[0, 2, r], {r, 0, 2}]

大きい半径についての漸近動作：

Wolfram Language code: Asymptotic[CoulombF[ℓ, η, r], r -> ∞]

スコープ  (20)

数値評価  (5)

数値的に評価する：

Wolfram Language code: N[CoulombF[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombF[1 / 2, -7, 1]]

高精度で評価する：

Wolfram Language code: N[CoulombF[1 / 2, 7, 1], 50]

出力精度は入力精度に従う：

Wolfram Language code: CoulombF[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombF[-2 / 5, -3, 1.2345678910111213141516171819202122]

複素数入力：

Wolfram Language code: CoulombF[2 / 3, 0.7 + 0.1 I, 3.2]

高精度で効率的に評価する：

Wolfram Language code: CoulombF[11, -3, 70`100]//N//Timing
Wolfram Language code: CoulombF[11, -3, 70`1000]//N//Timing

CoulombFはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: CoulombF[Interval[{0.234, 0.235}], Interval[{0.345, 0.346}], Interval[{0.456, 0.457}]]
Wolfram Language code: CoulombF[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

特別な値  (3)

原点における極限値：

Wolfram Language code: Limit[CoulombF[0, 2, r], r -> 0]

パラメータ η の値が0のとき，CoulombFは球ベッセル関数に簡約される：

Wolfram Language code: CoulombF[n, 0, r]

CoulombFの最初の正の零点を求める：

Wolfram Language code: rzero = r /. FindRoot[CoulombF[0, 3, r], {r, 9}]
Wolfram Language code: Plot[CoulombF[0, 3, r], {r, 0, 20}, Epilog -> Style[Point[{rzero, CoulombF[0, 3, rzero]}], PointSize[Large], Red]]

可視化  (3)

CoulombF関数をプロットする：

Wolfram Language code: Plot[CoulombF[2, 0, x], {x, 0, 4π}]

TemplateBox[{2, 0, z}, CoulombF]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

TemplateBox[{2, 0, z}, CoulombF]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

r=TemplateBox[{2, 0, {k, , phi}}, CoulombF]での極プロット：

Wolfram Language code: Table[PolarPlot[...], {k, 1, 8}]

関数の特性  (7)

CoulombFの定義域：

Wolfram Language code: FunctionDomain[CoulombF[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombF[n, η, z], z, Complexes]

CoulombFは η の解析関数である：

Wolfram Language code: FunctionAnalytic[CoulombF[n, η, x], η]

CoulombF[2,0,x]は単射ではない：

Wolfram Language code: FunctionInjective[CoulombF[2, 0, x], x]
Wolfram Language code: Plot[{CoulombF[2, 0, x], 1 / 2}, {x, -4π, 4π}]

CoulombF[2,0,x]は非負でも非正でもない：

Wolfram Language code: FunctionSign[CoulombF[2, 0, x], x]

CoulombF[2,0,x]は零点で特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[CoulombF[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombF[2, 0, x], x]

CoulombFは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[CoulombF[2, 0, x], x]

TraditionalFormによる表示：

Wolfram Language code: CoulombF[n, η, z]//TraditionalForm

級数展開  (1)

Seriesを使って零点と無限大におけるテイラー(Taylor)展開を求める：

Wolfram Language code: Series[CoulombF[1, 2, x], {x, 0, 3}]//FullSimplify
Wolfram Language code: Series[CoulombF[1, 2, x], {x, ∞, 3}]//FullSimplify

の周りのCoulombFについての最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[CoulombF[1, 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{CoulombF[1, 2, x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

関数表現  (1)

他のクーロン関数を介した表現：

Wolfram Language code: (CoulombH2[ℓ, η, r] - CoulombH1[ℓ, η, r]) / (2I)//FullSimplify

アプリケーション  (3)

クーロン波動方程式を解く：

Wolfram Language code: DSolve[{y''[r] + (1 - (2η/r) - (ℓ(ℓ + 1)/r^2))y[r] == 0}, y[r], r]

電荷が と で距離 と相対運動エネルギー で隔てられた2つの点粒子間のクーロンポテンシャルを持つ放射状シュレディンガー(Schrödinger)方程式の波動関数：

Wolfram Language code: w[𝓈_] := CoulombF[ℓ, 𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "SpeedOfLight"]Sqrt[(Quantity[1, "ElectronMass"]/2ℰ)], (𝓈/Quantity[1, "ReducedPlanckConstant"])Sqrt[2Quantity[1, "ElectronMass"]ℰ]]

波動関数がエネルギーと分離距離の特定の値についてシュレディンガー方程式を満足することを確認する：

Wolfram Language code: -(Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])w''[𝓈] + ((Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])(ℓ(ℓ + 1)/𝓈^2) + (𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "ReducedPlanckConstant"]Quantity[1, "SpeedOfLight"]/𝓈))w[𝓈] == ℰ w[𝓈] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}

波動関数をプロットする：

Wolfram Language code: Plot[w[Quantity[s, "Angstroms"]] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}, {s, 0, 50}]

CoulombFのWKB近似を構築する：

Wolfram Language code: wkbCoulombF[el_, eta_, r_ ? NumberQ] := Module[{rhoT = eta + √(eta^2 + el(el + 1)), a, phi}, CompoundExpression[...] ]

WKB近似を実際の関数と比較する：

Wolfram Language code: Plot[{CoulombF[3, 17, r], wkbCoulombF[3, 17, r]}, {r, 0, 50}, PlotStyle -> {Thick, Dashed}]

特性と関係  (2)

CoulombFはCoulombH1とCoulombH2の線形結合である：

Wolfram Language code: (CoulombH1[ℓ, η, r] - CoulombH2[ℓ, η, r]) / (2I)//FullSimplify

CoulombFはHypergeometric1F1Regularizedと複素平面の一部の領域で関連している：

Wolfram Language code: coulombF[el_, eta_, r_] := With[{z = -2I r, w = 1 + el + I eta}, Exp[(LogGamma[el + 1 + I eta] + LogGamma[el + 1 - I eta]) / 2 + I Pi / 2 w]z ^ (el + 1)Exp[-z / 2]Hypergeometric1F1Regularized[w, 2 el + 2, z] / 2 ]
Wolfram Language code: Plot[{CoulombF[3, 1, r], coulombF[3, 1, r]}, {r, 0, 16}, PlotStyle -> {Thick, Dashed}, PlotLegends -> {"built-in", "alternative"}]

しかし，記述された定義はに分枝切断線を持つのに対し，組込みのCoulombFはに分枝切断線を持つ：

Wolfram Language code: {Labeled[ComplexPlot[CoulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "built-in"], Labeled[ComplexPlot[coulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "alternative"]}

おもしろい例題  (1)

TemplateBox[{{3, /, 5}, {{-, 1}, /, 2}, rho}, CoulombF]のリーマン面をプロットする：

Wolfram Language code: With[{ℓ = 3 / 5, η = -1 / 2, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[2π I k ℓ]CoulombF[ℓ, η, r Exp[I φ]]]}, {k, -1, 1}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]]]
Wolfram Research (2021), CoulombF, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoulombF.html （2023年に更新）.

テキスト

Wolfram Research (2021), CoulombF, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoulombF.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CoulombF." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CoulombF.html.

APA

Wolfram Language. (2021). CoulombF. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoulombF.html

BibTeX

@misc{reference.wolfram_2026_coulombf, author="Wolfram Research", title="{CoulombF}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombF.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombf, organization={Wolfram Research}, title={CoulombF}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombF.html}, note=[Accessed: 04-September-2026]}