WOLFRAM

Wolfram 语言与系统参考资料中心

CoulombF[l,η,r]

给出规则的库仑波函数 TemplateBox[{l, eta, r}, CoulombF].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特定值  
可视化  
函数的属性  
级数展开  
函数表示  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CoulombF

CoulombF[l,η,r]

给出规则的库仑波函数 TemplateBox[{l, eta, r}, CoulombF].

更多信息

  • 数学函数，适宜于符号和数值运算.
  • CoulombF[l,η,r] 是常微分方程 的解.
  • CoulombF[l,η,r] 在 附近与 成正比.
  • 对于较大的 和一些相移 ，CoulombF[l,η,r] 趋近于 .
  • CoulombF 在复平面 上有从 到 的分支切割线.
  • 对于某些特殊参数，CoulombF 会自动运算出精确值.
  • CoulombF 可以运算至任意数值精度.
  • CoulombF 自动逐项作用于列表的各个元素.
  • CoulombF 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值运算：

Wolfram Language code: CoulombF[3, 0.12, 7.]

运算至任意数值精度：

Wolfram Language code: N[CoulombF[3, 2, 5], 50]

绘制排斥 () 和吸引 () 相互作用的库仑波函数：

Wolfram Language code: Plot[{CoulombF[0, 0.3, r], CoulombF[0, -0.3, r]}, {r, 0, 10}]

复数图：

Wolfram Language code: ComplexPlot[CoulombF[3 / 2, 1 / 4, z], {z, -3 - 3I, 3 + 3I}]

在原点处级数展开：

Wolfram Language code: Series[CoulombF[0, 2, r], {r, 0, 2}]

大半径的渐近行为：

Wolfram Language code: Asymptotic[CoulombF[ℓ, η, r], r -> ∞]

范围  (20)

数值运算  (5)

数值运算：

Wolfram Language code: N[CoulombF[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombF[1 / 2, -7, 1]]

运算至高精度：

Wolfram Language code: N[CoulombF[1 / 2, 7, 1], 50]

输出的精度与输入的精度一致：

Wolfram Language code: CoulombF[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombF[-2 / 5, -3, 1.2345678910111213141516171819202122]

复数输入：

Wolfram Language code: CoulombF[2 / 3, 0.7 + 0.1 I, 3.2]

以高精度进行高效运算：

Wolfram Language code: CoulombF[11, -3, 70`100]//N//Timing
Wolfram Language code: CoulombF[11, -3, 70`1000]//N//Timing

CoulombF 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: CoulombF[Interval[{0.234, 0.235}], Interval[{0.345, 0.346}], Interval[{0.456, 0.457}]]
Wolfram Language code: CoulombF[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

特定值  (3)

在原点处的极限值：

Wolfram Language code: Limit[CoulombF[0, 2, r], r -> 0]

对于 η 的零值，CoulombF 简化为球贝塞尔函数：

Wolfram Language code: CoulombF[n, 0, r]

求 CoulombF 的第一个正零点：

Wolfram Language code: rzero = r /. FindRoot[CoulombF[0, 3, r], {r, 9}]
Wolfram Language code: Plot[CoulombF[0, 3, r], {r, 0, 20}, Epilog -> Style[Point[{rzero, CoulombF[0, 3, rzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 CoulombF 函数：

Wolfram Language code: Plot[CoulombF[2, 0, x], {x, 0, 4π}]

绘制 TemplateBox[{2, 0, z}, CoulombF] 的实部：

Wolfram Language code: ComplexContourPlot[Re[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{2, 0, z}, CoulombF] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[CoulombF[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

r=TemplateBox[{2, 0, {k, , phi}}, CoulombF] 时的极坐标图：

Wolfram Language code: Table[PolarPlot[...], {k, 1, 8}]

函数的属性  (7)

CoulombF 的定义域：

Wolfram Language code: FunctionDomain[CoulombF[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombF[n, η, z], z, Complexes]

CoulombF 是 η 的解析函数：

Wolfram Language code: FunctionAnalytic[CoulombF[n, η, x], η]

CoulombF[2,0,x] 不是单射的：

Wolfram Language code: FunctionInjective[CoulombF[2, 0, x], x]
Wolfram Language code: Plot[{CoulombF[2, 0, x], 1 / 2}, {x, -4π, 4π}]

CoulombF[2,0,x] 既不是非负也不是非正：

Wolfram Language code: FunctionSign[CoulombF[2, 0, x], x]

CoulombF[2,0,x] 在零点处同时具有奇点和断点：

Wolfram Language code: FunctionSingularities[CoulombF[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombF[2, 0, x], x]

CoulombF 既不凸也不凹：

Wolfram Language code: FunctionConvexity[CoulombF[2, 0, x], x]

TraditionalForm 格式：

Wolfram Language code: CoulombF[n, η, z]//TraditionalForm

级数展开  (1)

用 Series 在零点和无穷大处求泰勒展开式：

Wolfram Language code: Series[CoulombF[1, 2, x], {x, 0, 3}]//FullSimplify
Wolfram Language code: Series[CoulombF[1, 2, x], {x, ∞, 3}]//FullSimplify

绘制 CoulombF 在 附近的前 3 个近似式：

Wolfram Language code: terms = Normal@Table[Series[CoulombF[1, 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{CoulombF[1, 2, x], terms}, {x, -2π, 2π}, PlotRange -> {-1.5, 1.5}]

函数表示  (1)

通过其他库仑函数表示：

Wolfram Language code: (CoulombH2[ℓ, η, r] - CoulombH1[ℓ, η, r]) / (2I)//FullSimplify

应用  (3)

求解库仑波方程：

Wolfram Language code: DSolve[{y''[r] + (1 - (2η/r) - (ℓ(ℓ + 1)/r^2))y[r] == 0}, y[r], r]

间距为 、相对运动能量为 、带有电荷 和 、之间具有库仑势的两个点粒子的径向薛定谔方程的波函数：

Wolfram Language code: w[𝓈_] := CoulombF[ℓ, 𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "SpeedOfLight"]Sqrt[(Quantity[1, "ElectronMass"]/2ℰ)], (𝓈/Quantity[1, "ReducedPlanckConstant"])Sqrt[2Quantity[1, "ElectronMass"]ℰ]]

对于特定的能量值和间距，验证波函数满足薛定谔方程：

Wolfram Language code: -(Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])w''[𝓈] + ((Quantity[1, "ReducedPlanckConstant"]^2/2Quantity[1, "ElectronMass"])(ℓ(ℓ + 1)/𝓈^2) + (𝒵 𝒵 Quantity[1, "FineStructureConstant"]Quantity[1, "ReducedPlanckConstant"]Quantity[1, "SpeedOfLight"]/𝓈))w[𝓈] == ℰ w[𝓈] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}

绘制波函数图：

Wolfram Language code: Plot[w[Quantity[s, "Angstroms"]] /. {ℓ -> 2, 𝒵 -> -1, 𝒵 -> 1, ℰ -> Quantity[0.44, "Electronvolts"], 𝓈 -> 2.1ElementData["Hydrogen", "AtomicRadius"]}, {s, 0, 50}]

构造 CoulombF 的 WKB 近似：

Wolfram Language code: wkbCoulombF[el_, eta_, r_ ? NumberQ] := Module[{rhoT = eta + √(eta^2 + el(el + 1)), a, phi}, CompoundExpression[...] ]

将 WKB 近似值与实际函数进行比较：

Wolfram Language code: Plot[{CoulombF[3, 17, r], wkbCoulombF[3, 17, r]}, {r, 0, 50}, PlotStyle -> {Thick, Dashed}]

属性和关系  (2)

CoulombF 是 CoulombH1 和 CoulombH2 的线性组合：

Wolfram Language code: (CoulombH1[ℓ, η, r] - CoulombH2[ℓ, η, r]) / (2I)//FullSimplify

CoulombF 与在复平面的某些区域中的 Hypergeometric1F1Regularized 有关：

Wolfram Language code: coulombF[el_, eta_, r_] := With[{z = -2I r, w = 1 + el + I eta}, Exp[(LogGamma[el + 1 + I eta] + LogGamma[el + 1 - I eta]) / 2 + I Pi / 2 w]z ^ (el + 1)Exp[-z / 2]Hypergeometric1F1Regularized[w, 2 el + 2, z] / 2 ]
Wolfram Language code: Plot[{CoulombF[3, 1, r], coulombF[3, 1, r]}, {r, 0, 16}, PlotStyle -> {Thick, Dashed}, PlotLegends -> {"built-in", "alternative"}]

然而，所述定义在 处有分支，而内置 CoulombF 在 有分支:

Wolfram Language code: {Labeled[ComplexPlot[CoulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "built-in"], Labeled[ComplexPlot[coulombF[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "alternative"]}

巧妙范例  (1)

绘制 TemplateBox[{{3, /, 5}, {{-, 1}, /, 2}, rho}, CoulombF] 的黎曼曲面：

Wolfram Language code: With[{ℓ = 3 / 5, η = -1 / 2, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[2π I k ℓ]CoulombF[ℓ, η, r Exp[I φ]]]}, {k, -1, 1}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.85], Opacity[0.6]]]]
Wolfram Research (2021)，CoulombF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoulombF.html （更新于 2023 年）.

文本

Wolfram Research (2021)，CoulombF，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoulombF.html （更新于 2023 年）.

CMS

Wolfram 语言. 2021. "CoulombF." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/CoulombF.html.

APA

Wolfram 语言. (2021). CoulombF. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoulombF.html 年

BibTeX

@misc{reference.wolfram_2026_coulombf, author="Wolfram Research", title="{CoulombF}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombF.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombf, organization={Wolfram Research}, title={CoulombF}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombF.html}, note=[Accessed: 13-September-2026]}