WOLFRAM

Wolfram 语言与系统参考资料中心

CoulombG[l,η,r]

给出不规则的库仑波函数 TemplateBox[{l, eta, r}, CoulombG].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特定值  
可视化  
函数的属性  
级数展开  
函数表示  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CoulombG

CoulombG[l,η,r]

给出不规则的库仑波函数 TemplateBox[{l, eta, r}, CoulombG].

更多信息

  • 数学函数，适用于符号和数值运算.
  • CoulombG[l,η,r] 是常微分方程 的解.
  • CoulombG[l,η,r] 对于较大的 和一些相移 ，趋于 .
  • CoulombG[l,η,r] 在 处有一个不规则奇点.
  • CoulombG 在从 到 的 复平面上有分支切割不连续性.
  • 对于某些特殊参数，CoulombG 会自动运算为精确值.
  • CoulombG 可以运算至任意数值精度.
  • CoulombG 自动遍历列表.
  • CoulombG 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

数值运算：

Wolfram Language code: CoulombG[3, 0.12, 7.]
Wolfram Language code: CoulombG[3, 0.12`50, 3`50]

绘制排斥 () 和吸引 () 相互作用的库仑波函数：

Wolfram Language code: Plot[{CoulombG[0, 0.3, r], CoulombG[0, -0.3, r]}, {r, 0, 10}]

复数图：

Wolfram Language code: ComplexPlot[CoulombG[0, 2, z], {z, -3 - 3I, 3 + 3I}]

在原点处级数展开：

Wolfram Language code: Series[CoulombG[0, 2, r], {r, 0, 1}]//TraditionalForm

大半径的渐近行为：

Wolfram Language code: Asymptotic[CoulombG[ℓ, η, r], r -> ∞]

范围  (18)

数值运算  (5)

数值运算：

Wolfram Language code: N[CoulombG[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombG[1 / 2, -7, 1]]

运算至高精度：

Wolfram Language code: N[CoulombG[1 / 2, 7, 1], 50]

输出的精度与输入的精度一致：

Wolfram Language code: CoulombG[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombG[-2 / 5, -3, 1.2345678910111213141516171819202122]

复数输入：

Wolfram Language code: CoulombG[2 / 3, 0.7 + 0.1 I, 3.2]

以高精度进行高效运算：

Wolfram Language code: CoulombG[11, -3, 70`100]//NumberForm[#, 20]&//Timing
Wolfram Language code: CoulombG[11, -3, 70`1000]//NumberForm[#, 20]&//Timing

CoulombG 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: CoulombG[Interval[{0.234, 0.235}], Interval[{0.345, 0.346}], Interval[{0.456, 0.457}]]
Wolfram Language code: CoulombG[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

特定值  (2)

对于 η 的零值，CoulombG 简化为球面贝塞尔函数：

Wolfram Language code: CoulombG[n, 0, r]

求 CoulombG 的第一个正零：

Wolfram Language code: rzero = r /. FindRoot[CoulombG[0, 3, r], {r, 9}]
Wolfram Language code: Plot[CoulombG[0, 3, r], {r, 0, 20}, Epilog -> Style[Point[{rzero, CoulombG[0, 3, rzero]}], PointSize[Large], Red]]

可视化  (2)

绘制 CoulombG 函数：

Wolfram Language code: Plot[CoulombG[2, 0, x], {x, 0, 4π}]

绘制 TemplateBox[{2, 0, z}, CoulombG] 的实部：

Wolfram Language code: ComplexContourPlot[Re[CoulombG[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{2, 0, z}, CoulombG] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[CoulombG[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

函数的属性  (7)

CoulombG 的函数域：

Wolfram Language code: FunctionDomain[CoulombG[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombG[n, η, z], z, Complexes]

CoulombG 是 η 的解析函数：

Wolfram Language code: FunctionAnalytic[CoulombG[n, η, x], η]

CoulombG[2,0,x] 不是单射的：

Wolfram Language code: FunctionInjective[CoulombG[2, 0, x], x]
Wolfram Language code: Plot[{CoulombG[2, 0, x], 1 / 2}, {x, -4π, 4π}]

CoulombG[2,0,x] 既不是非负也不是非正：

Wolfram Language code: FunctionSign[CoulombG[2, 0, x], x]

CoulombG[2,0,x] 在零点处同时具有奇点和不连续点：

Wolfram Language code: FunctionSingularities[CoulombG[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombG[2, 0, x], x]

CoulombG 既不凸也不凹：

Wolfram Language code: FunctionConvexity[CoulombG[2, 0, x], x]

TraditionalForm 格式化：

Wolfram Language code: CoulombG[n, η, z]//TraditionalForm

级数展开  (1)

使用 Series 在零点和无穷大处求泰勒展开式：

Wolfram Language code: Series[CoulombG[1, 2, x], {x, 0, 2}]//FullSimplify
Wolfram Language code: Series[CoulombG[1, 2, x], {x, ∞, 3}]//FullSimplify

在 附近 CoulombG 的前三个近似的图形：

Wolfram Language code: terms = Normal@Table[Series[CoulombG[1, 0, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{CoulombG[1, 0, x], terms}, {x, -2π, 2π}, PlotRange -> {-10, 10}]

函数表示  (1)

通过其他库仑函数表示：

Wolfram Language code: (CoulombH2[ℓ, η, r] + CoulombH1[ℓ, η, r]) / 2//FullSimplify

应用  (2)

求解库仑波方程：

Wolfram Language code: DSolve[{y''[r] + (1 - (2η/r) - (ℓ(ℓ + 1)/r^2))y[r] == 0}, y[r], r]

构造 CoulombG 的 WKB 近似：

Wolfram Language code: wkbCoulombG[el_, eta_, r_ ? NumberQ] := Module[{rhoT = eta + √(eta^2 + el(el + 1)), a, phi}, CompoundExpression[...] ]

将 WKB 近似值与实际函数进行比较：

Wolfram Language code: Plot[{CoulombG[3, 17, r], wkbCoulombG[3, 17, r]}, {r, 20, 100}, PlotStyle -> {Thick, Dashed}]

属性和关系  (1)

CoulombG 是 CoulombH1 和 CoulombH2 的线性组合：

Wolfram Language code: (CoulombH1[ℓ, η, r] + CoulombH2[ℓ, η, r]) / 2//FullSimplify
Wolfram Research (2021)，CoulombG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoulombG.html （更新于 2023 年）.

文本

Wolfram Research (2021)，CoulombG，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoulombG.html （更新于 2023 年）.

CMS

Wolfram 语言. 2021. "CoulombG." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/CoulombG.html.

APA

Wolfram 语言. (2021). CoulombG. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoulombG.html 年

BibTeX

@misc{reference.wolfram_2026_coulombg, author="Wolfram Research", title="{CoulombG}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombG.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombg, organization={Wolfram Research}, title={CoulombG}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombG.html}, note=[Accessed: 07-September-2026]}