WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoulombH1[l,η,r]

非正則出クーロン(Coulomb)波動関数 TemplateBox[{l, eta, r}, CoulombH1]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特別な値  
可視化  
関数の特性  
級数展開  
関数表現  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CoulombH1

CoulombH1[l,η,r]

非正則出クーロン(Coulomb)波動関数 TemplateBox[{l, eta, r}, CoulombH1]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • CoulombH1[ℓ,η,r]は常微分方程式 の解である．
  • CoulombH1[l,η,r]は，大きい についてに比例する．
  • CoulombH1[l,η,r]は に確定特異点を持つ．
  • CoulombH1はからまでの複素 平面に不連続な分枝切断線を持つ．
  • CoulombH1を特定の特別な引数について評価すると自動的に厳密値になる．
  • CoulombH1は任意の数値精度で評価できる．
  • CoulombH1は自動的にリストに縫い込まれる．
  • CoulombH1はCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: CoulombH1[2, 0.2, 3.]

任意精度で評価する：

Wolfram Language code: N[CoulombH1[3, 2, 5], 25]

CoulombH1はCoulombG関数とCoulombF関数の線形結合である：

Wolfram Language code: CoulombH1[1, 0.8, 5]
Wolfram Language code: CoulombG[1, 0.8, 5] + I CoulombF[1, 0.8, 5]

複素数プロット：

Wolfram Language code: ComplexPlot[CoulombH1[3 / 2, -1, z], {z, -2 - 2I, 2 + 2I}]

大きい半径での漸近動作：

Wolfram Language code: Asymptotic[CoulombH1[ℓ, η, r], r -> ∞]//TrigToExp

スコープ  (19)

数値評価  (5)

数値的に評価する：

Wolfram Language code: N[CoulombH1[1 / 2, 7, 1]]
Wolfram Language code: N[CoulombH1[1 / 2, -7, 1]]

高精度で評価する：

Wolfram Language code: N[CoulombH1[1, 7, 1], 50]

出力精度は入力精度に従う：

Wolfram Language code: CoulombH1[-2 / 5, -3, 1.23456789101112131415]
Wolfram Language code: CoulombH1[-2 / 5, -3, 1.2345678910111213141516171819202122]

複素数入力：

Wolfram Language code: CoulombH1[2 / 3, 0.7 + 0.1 I, 3.2]

高精度で効率的に評価する：

Wolfram Language code: CoulombH1[11, -3, 70`100]//NumberForm[#, 20]&//Timing
Wolfram Language code: CoulombH1[11, -3, 70`1000]//NumberForm[#, 20]&//Timing

CoulombH1はCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: CoulombH1[CenteredInterval[3 / 4, 10 ^ -6], CenteredInterval[5 / 6, 10 ^ -6], CenteredInterval[7 / 8, 10 ^ -6]]

特別な値  (4)

原点における極限値：

Wolfram Language code: Limit[CoulombH1[1, 1, r], r -> 0]//FullSimplify

特別なパラメータについての記号評価：

Wolfram Language code: CoulombH1[0, 0, r]

CoulombH1は，パラメータ η の値が0のときは球ハンケル(Hankel)関数に簡約される：

Wolfram Language code: CoulombH1[n, 0, r]

CoulombH1の実部の最初の正の零点を求める：

Wolfram Language code: rzero = r /. FindRoot[Re[CoulombH1[0, 3, r]], {r, 9}]//Quiet
Wolfram Language code: Plot[Re[CoulombH1[0, 3, r]], {r, 0, 20}, Epilog -> Style[Point[{rzero, Re[CoulombH1[0, 3, rzero]]}], PointSize[Large], Red]]

可視化  (2)

CoulombH1の実部と虚部をプロットする：

Wolfram Language code: ReImPlot[CoulombH1[2, 0, x], {x, 0, 4π}]

TemplateBox[{2, 0, z}, CoulombH1]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[CoulombH1[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

TemplateBox[{2, 0, z}, CoulombH1]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[CoulombH1[2, 0, z]], {z, -2π - π I, 2π + π I}, IconizedObject[«PlotOptions»]]

関数の特性  (6)

CoulombH1の定義域：

Wolfram Language code: FunctionDomain[CoulombH1[n, η, x], x]
Wolfram Language code: FunctionDomain[CoulombH1[n, η, z], z, Complexes]

CoulombH1[2,0,x]は複素数上で単射ではない：

Wolfram Language code: FunctionInjective[CoulombH1[2, 0, x], x, Complexes]
Wolfram Language code: Plot[{Im[CoulombH1[2, 0, x]], 1 / 2}, {x, -4π, 4π}]

CoulombH1[2,0,x]は非負でも非正でもない：

Wolfram Language code: FunctionSign[CoulombH1[2, 0, x], x]

CoulombH1[2,0,x]は特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[CoulombH1[2, 0, x], x]
Wolfram Language code: FunctionDiscontinuities[CoulombH1[2, 0, x], x]

CoulombH1は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[CoulombH1[2, 0, x], x]

TraditionalFormによる表示：

Wolfram Language code: CoulombH1[n, η, z]//TraditionalForm

級数展開  (1)

零点と無限大でSeriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[CoulombH1[1, 2, x], {x, 0, 2}]//FullSimplify
Wolfram Language code: Series[CoulombH1[1, 2, x], {x, ∞, 3}]//FullSimplify

CoulombH1についてのの周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[CoulombH1[1, 0, x], {x, 0, m}], {m, 1, 5, 2}]; ReImPlot[{CoulombH1[1, 0, x], terms}, {x, -2π, 2π}, PlotRange -> {0, 20}]

関数表現  (1)

他のクーロン関数との関係：

Wolfram Language code: (CoulombH2[``l``, η, ``r``] - CoulombH1[``l``, η, ``r``]) / 2 I//FullSimplify
Wolfram Language code: (CoulombH2[``l``, η, ``r``] + CoulombH1[``l``, η, ``r``]) / 2 //FullSimplify

特性と関係  (1)

CoulombH1は複素平面の一部の領域ではWhittakerWに比例する：

Wolfram Language code: coulombH1[el_, eta_, r_] := Exp[(LogGamma[el + 1 + I eta] - LogGamma[el + 1 - I eta]) / 2 + (eta - I el) Pi / 2] WhittakerW[-I eta, el + 1 / 2, -2I r]
Wolfram Language code: With[{r = 3`20}, {CoulombH1[3, 1, r], coulombH1[3, 1, r]}]

しかし，標準的な定義ではに分枝切断線を持つのに対し，組込みのCoulombH1はに分枝切断線を持つ：

Wolfram Language code: {Labeled[ComplexPlot[CoulombH1[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "built-in"], Labeled[ComplexPlot[coulombH1[4 / 3, 1, r], {r, -3 - 3I, 3 + 3I}], "alternative"]}
Wolfram Research (2021), CoulombH1, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoulombH1.html （2023年に更新）.

テキスト

Wolfram Research (2021), CoulombH1, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoulombH1.html （2023年に更新）.

CMS

Wolfram Language. 2021. "CoulombH1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CoulombH1.html.

APA

Wolfram Language. (2021). CoulombH1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoulombH1.html

BibTeX

@misc{reference.wolfram_2026_coulombh1, author="Wolfram Research", title="{CoulombH1}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CoulombH1.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coulombh1, organization={Wolfram Research}, title={CoulombH1}, year={2023}, url={https://reference.wolfram.com/language/ref/CoulombH1.html}, note=[Accessed: 13-September-2026]}