WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CountRoots[f,x]

一変量関数 f の実根の数を x について与える．

CountRoots[f,{x,a,b}]

a と b の間にある根の数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
実初等関数  
正則関数  
有理型関数  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CountRoots

CountRoots[f,x]

一変量関数 f の実根の数を x について与える．

CountRoots[f,{x,a,b}]

a と b の間にある根の数を与える．

詳細

  • CountRootsは多重度も含めて根を数える．
  • 関数 f は，多項式関数，正則関数，有理型関数等でよい．
  • 厳密に xa あるいは xb にある根は数えられる．
  • 極限 a および b は複素数でもよい．その場合，範囲は閉じた長方形Re[a]≤Re[x]≤Re[b]∧Im[a]≤Im[x]≤Im[b]であると解釈される．

例題

すべて開く すべて閉じる

例  (4)

0から5までにある多項式の根を数える：

Wolfram Language code: CountRoots[(x - 1)(x - 2)(x - 3)(x - 4), {x, 0, 5}]

閉じた長方形内の多項式の根を数える：

Wolfram Language code: CountRoots[x ^ 17 - 1, {x, 0, 1 + I}]

実初等関数の根を実数区間で数える：

Wolfram Language code: CountRoots[Sin[z / 2]^5 + Tan[4z]^3, {z, 0, 10 ^ 10}]

正則関数の根を閉じた長方形内で数える：

Wolfram Language code: CountRoots[Cos[x ^ 3], {x, -2 - 2I, 2 + 2I}]
Wolfram Language code: Plot3D[With[{x = u + I v}, Log@Abs[Cos[x ^ 3]]], {u, -2, 2}, {v, -2, 2}, Mesh -> None]

スコープ  (20)

基本的な用法  (8)

実根の数を数える：

Wolfram Language code: CountRoots[(x ^ 2 - 2)(x ^ 2 - 5), x]

実数区間で根を数える：

Wolfram Language code: CountRoots[(x ^ 2 - 2)(x ^ 2 - 5), {x, -2, 2}]
Wolfram Language code: Plot[(x ^ 2 - 2)(x ^ 2 - 5), {x, -2, 2}]

閉じた長方形内で根を数える：

Wolfram Language code: CountRoots[(x ^ 4 - 2)(x ^ 4 - 20), {x, -2 - 2I, 2 + 2I}]
Wolfram Language code: Plot3D[With[{x = u + I v}, Log@Abs[(x ^ 4 - 2)(x ^ 4 - 20)]], {u, -2, 2}, {v, -2, 2}, Mesh -> None]

垂直の線分上の根を数える：

Wolfram Language code: CountRoots[1 + x ^ 2, {x, -2I, 2I}]

水平の線分上の根を数える：

Wolfram Language code: CountRoots[1 + x ^ 2, {x, -1 + I, 1 + I}]

多重根はその重複度も含めて数えられる：

Wolfram Language code: CountRoots[x ^ 3, {x, -1, 1}]

多重度 の根の場合は，についてのすべての導関数 もまた消失する：

Wolfram Language code: Plot[Evaluate@Table[D[x ^ 3, {x, n}], {n, 0, 2}], {x, -1, 1}, PlotLabels -> {"f", "f'", "f''"}]

区間の端点にある根は含まれる：

Wolfram Language code: CountRoots[(x - 1)(x - 2), {x, 0, 2}]

長方形の境界上の根は含まれる：

Wolfram Language code: CountRoots[x ^ 4 - 1, {x, 0, 1 + I}]

実初等関数  (6)

高次多項式の実根を数える：

Wolfram Language code: CountRoots[x ^ 1000000 - 2x ^ 777777 + 3x ^ 12345 + 9x ^ 67 - 10, x]

高次のベキ根を含む代数関数の非負の根を数える：

Wolfram Language code: CountRoots[2x ^ (123451 / 67890) - x ^ 2 + 4Sqrt[x] - 4x - 9 / 8, {x, 0, ∞}]

無理実数ベキを含む関数の非負の根を数える：

Wolfram Language code: CountRoots[x ^ Pi - x ^ Sqrt[2] - Sqrt[3]x + 2 ^ (1 / 3), {x, 0, ∞}]

実数指数対数関数の実根を数える：

Wolfram Language code: CountRoots[E ^ (2E ^ x) - Log[x ^ 2 + 1] - 20x - 11, x]

順実初等関数の実根を数える：

Wolfram Language code: CountRoots[Cos[1 / (x ^ 2 + 1)] - Sin[E ^ -x ^ 2], x]

次はこの関数のプロットを示している：

Wolfram Language code: Plot[Cos[1 / (x ^ 2 + 1)] - Sin[E ^ -x ^ 2], {x, -3, 3}]

有界区間における実初等関数の根を数える：

Wolfram Language code: CountRoots[2Sin[Exp[x]] - Cos[Pi x] - 1 / 2, {x, 0, 7}]

次はこの関数のプロットを示している：

Wolfram Language code: Plot[2Sin[Exp[x]] - Cos[Pi x] - 1 / 2, {x, 0, 7}]

正則関数  (3)

閉じた長方形内の正則初等関数の根を数える：

Wolfram Language code: CountRoots[Cos[Sin[x] + 2] - Cos[2 x] - 1, {x, -3 - 3I, 3 + 3I}]

閉じた長方形内の正則特殊関数の根を数える：

Wolfram Language code: CountRoots[FresnelC[x] - x - 1, {x, -2 - 2I, 2 + 2I}]

有界の実数区間における解析関数の根の数を求める：

Wolfram Language code: CountRoots[BesselJ[2, x] - Sin[x ^ 2], {x, -3, 3}]

ゼロにおける重根は多重性をもって数えられる：

Wolfram Language code: Plot[BesselJ[2, x] - Sin[x ^ 2], {x, -3, 3}]

有理型関数  (3)

閉じた長方形内で有理型初等関数の根を数える：

Wolfram Language code: CountRoots[Tan[z] - Log[z + 3] - z ^ 2, {z, -2 - 2I, 2 + 2I}]

関数の根と極を可視化する：

Wolfram Language code: f = Tan[z] - Log[z + 3] - z ^ 2; g = f /. z -> x + I y; rts = {Re[z], Im[z]} /. Solve[f == 0 && -2 ≤ Re[z] ≤ 2 && -2 ≤ Im[z] ≤ 2, z]; Show[{ContourPlot[{Re[g] == 0, Im[g] == 0}, {x, -2, 2}, {y, -2, 2}, Contours -> 0], Graphics[{PointSize[Large], Green, Tooltip[Point[rts], "Root"], Red, Tooltip[Point[{{-Pi / 2, 0}, {Pi / 2, 0}}], "Pole"]}]}]

閉じた長方形内で有理型特殊関数の根を数える：

Wolfram Language code: CountRoots[Gamma[z] - z - 1, {z, -2 - 2I, 2 + 2I}]

関数の根と極を可視化する：

Wolfram Language code: f = Gamma[z] - z - 1; g = f /. z -> x + I y; rts = Quiet[{Re[z], Im[z]} /. Solve[f == 0 && -2 ≤ Re[z] ≤ 2 && -2 ≤ Im[z] ≤ 2, z]]; Show[{ContourPlot[{Re[g] == 0, Im[g] == 0}, {x, -2, 2}, {y, -2, 2}, Contours -> 0], Graphics[{PointSize[Large], Green, Tooltip[Point[rts], "Root"], Red, Tooltip[Point[{{-2, 0}, {-1, 0}, {0, 0}}], "Pole"]}]}]

有界の実数区間で有理型関数の根の数を求める：

Wolfram Language code: CountRoots[Gamma[x] + E ^ x - 7x, {x, -3, 3}]

この関数をプロットする：

Wolfram Language code: Plot[Gamma[x] + E ^ x - 7x, {x, -3, 3}]

アプリケーション  (4)

第1象限内の閉じた単位正方形内の1の17乗根の数：

Wolfram Language code: poly = x ^ 17 - 1; CountRoots[poly, {x, 0, 1 + I}]

境界線上の根を数える：

Wolfram Language code: Graphics[{{GrayLevel[0.7], Rectangle[{0, 0}, {1, 1}]}, {Red, PointSize[Medium], Point[{Re[x], Im[x]} /. NSolve[poly == 0, x]]}}]

関数が区間内で厳密に1つの根を持つことを確認する：

Wolfram Language code: f = Tan[x] - E ^ x + 7x ^ 2; CountRoots[f, {x, 8 / 5, 9 / 5}]

FindRootを使って根を近似する：

Wolfram Language code: FindRoot[f, {x, 8 / 5, 9 / 5}, Method -> "Brent", WorkingPrecision -> 30]

式 を使って関数の対数導関数の閉曲線積分を計算する．ただし， は正則関数 の根の数である：

Wolfram Language code: f = Sinh[5z] - z; ldf = D[f, z] / f; 2 Pi I CountRoots[f, {z, -1 - I, 1 + I}]

数値積分の結果と比較する：

Wolfram Language code: NIntegrate[ldf, {z, -1 - I, 1 - I, 1 + I, -1 + I, -1 - I}] - %//Chop

右半平面でCharacteristicPolynomial[m,x]の根を数えることで，動的な線形系 の0における平衡点の安定性をチェックする：

Wolfram Language code: m = {{0, 0, 0, 0, 0, 0, -78375471}, {1, 0, 0, 0, 0, 0, -34057401}, {0, 1, 0, 0, 0, 0, -5727428}, {0, 0, 1, 0, 0, 0, -639271}, {0, 0, 0, 1, 0, 0, -53497}, {0, 0, 0, 0, 1, 0, -2905}, {0, 0, 0, 0, 0, 1, -85}};
Wolfram Language code: f = CharacteristicPolynomial[m, x];

根の最大絶対値の境界を使う：

Wolfram Language code: rb = 1 + Max[Abs[Drop[#, -1] / Last[#]]]&[CoefficientList[f, x]]

右半平面の根を数える：

Wolfram Language code: CountRoots[f, {x, -rb I, rb + rb I}]

m のすべての固有値が負の実部を持つので，平衡点は漸近的に安定である：

Wolfram Language code: y = Table[x[i][t], {i, 7}]; sol = DSolveValue[{D[y, t] == m.y, (y /. t -> 0) == 1}, y, t]//N; Plot[sol, {t, 0, 30}]

別の行列を試してみる：

Wolfram Language code: m = {{0, 0, 0, 0, 0, 0, 78375471}, {1, 0, 0, 0, 0, 0, -34057401}, {0, 1, 0, 0, 0, 0, -5727428}, {0, 0, 1, 0, 0, 0, -639271}, {0, 0, 0, 1, 0, 0, -53497}, {0, 0, 0, 0, 1, 0, -2905}, {0, 0, 0, 0, 0, 1, -85}};

今回は，実部が負ではない根がある：

Wolfram Language code: f = CharacteristicPolynomial[m, x]; rb = 1 + Max[Abs[Drop[#, -1] / Last[#]]]&[CoefficientList[f, x]]; CountRoots[f, {x, -rb I, rb + rb I}]

平衡点は漸近的に安定ではない：

Wolfram Language code: y = Table[x[i][t], {i, 7}]; sol = DSolveValue[{D[y, t] == m.y, (y /. t -> 0) == 1}, y, t]//N; Plot[sol, {t, 0, 30}]

特性と関係  (5)

多項式の複素根の数はその次数に等しい：

Wolfram Language code: poly = x ^ 10 - 17x ^ 7 + 21x ^ 3 - 55x ^ 2 + 22x + 2;

これは，多項式の根の絶対値についての境界を返す：

Wolfram Language code: CauchyBound[f_, x_] := Module[{cfl, n}, cfl = CoefficientList[f, x]; n = Length[cfl] - 1; Max[Table[(n Abs[cfl[[n + 1 - k]] / cfl[[n + 1]]]) ^ (1 / k), {k, n}]]]
Wolfram Language code: b = Ceiling[CauchyBound[poly, x]]

この多項式は実際にコーシー(Cauchy)の有界範囲で10個の根を持つ：

Wolfram Language code: CountRoots[poly, {x, -b - b I, b + b I}]

個の非零の項を持つ多項式の実根の数は最高でである：

Wolfram Language code: poly = Expand[x(x ^ 4 - 1)(x ^ 4 - 2)(x ^ 4 - 3)]

この多項式は，可能な数としては最高の個の実根を持つ：

Wolfram Language code: CountRoots[poly, {x, -Infinity, Infinity}]

Reduceを使って多項式の根を求める：

Wolfram Language code: poly = (x ^ 2 - 2)(x ^ 3 - 5x + 1);

根を数える：

Wolfram Language code: CountRoots[poly, {x, 0, 3}]

根を求める：

Wolfram Language code: Reduce[poly == 0 && 0 ≤ x ≤ 3, x]

RootIntervalsを使って根の分離区間を求める：

Wolfram Language code: poly = (x ^ 4 - 2)(x ^ 8 - 3);

実根を数える：

Wolfram Language code: CountRoots[poly, {x, -Infinity, Infinity}]

実根を分離する：

Wolfram Language code: RootIntervals[poly]

NumberFieldSignatureを使って多項式の実根と複素根のペアを数える：

Wolfram Language code: poly = x ^ 8 - 2;
Wolfram Language code: NumberFieldSignature[poly, x]
Wolfram Language code: CountRoots[poly, {x, -Infinity, Infinity}]

考えられる問題  (1)

区間の端点にある根は数えられる：

Wolfram Language code: CountRoots[(x - 1)(x - 2), {x, 0, 2}]

おもしろい例題  (1)

有理型関数の根を数える：

Wolfram Language code: CountRoots[Tan[z ^ 3 + 1] - Exp[z], {z, -3 - 3I, 3 + 3I}]

根をスパイクとしてプロットする：

Wolfram Language code: Plot3D[With[{z = x + I y}, -Log[Abs[Tan[z ^ 3 + 1] - Exp[z]]]], {x, -3, 3}, {y, -3, 3}, PlotPoints -> 100, Mesh -> None]
Wolfram Research (2007), CountRoots, Wolfram言語関数， https://reference.wolfram.com/language/ref/CountRoots.html （2017年に更新）.

テキスト

Wolfram Research (2007), CountRoots, Wolfram言語関数， https://reference.wolfram.com/language/ref/CountRoots.html （2017年に更新）.

CMS

Wolfram Language. 2007. "CountRoots." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/CountRoots.html.

APA

Wolfram Language. (2007). CountRoots. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CountRoots.html

BibTeX

@misc{reference.wolfram_2026_countroots, author="Wolfram Research", title="{CountRoots}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/CountRoots.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_countroots, organization={Wolfram Research}, title={CountRoots}, year={2017}, url={https://reference.wolfram.com/language/ref/CountRoots.html}, note=[Accessed: 11-September-2026]}