WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CrossingPolygon[{p1,p2,…,pn}]

ある点から平面内の任意の方向に向けて出た半直線が，半直線{p1,p2},…,{pn-1,pn},{pn,p1}と偶数回交差するすべての点を表すPolygonを与える．

CrossingPolygon[{{p11,p12,…},{p21,p22,…},…}]

線分{p11,p12},…,{p21,p22},…からのPolygonを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
自己交差する輪郭線  
複数の輪郭線  
オプション  
VertexColors  
VertexNormals  
VertexTextureCoordinates  
アプリケーション  
基本的なアプリケーション  
コンピュータグラフィックス  
計算幾何学  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CrossingPolygon

CrossingPolygon[{p1,p2,…,pn}]

ある点から平面内の任意の方向に向けて出た半直線が，半直線{p1,p2},…,{pn-1,pn},{pn,p1}と偶数回交差するすべての点を表すPolygonを与える．

CrossingPolygon[{{p11,p12,…},{p21,p22,…},…}]

線分{p11,p12},…,{p21,p22},…からのPolygonを与える．

詳細とオプション

  • CrossingPolygonは偶奇充填規則としても知られている．
  • ある点から出て無限大の任意の方向に向かう半直線が境界曲線と偶数回交差するなら，その点はCrossingPolygon内にある．半直線の交差回数はCrossingCountで与えられる．
  • 下の各領域についての半直線の交差回数
  • CrossingPolygonは，例えば自己交差のある曲線からの多角形の定義に使われる．
  • CrossingPolygon[{p1,p2,…,pn}]は，事実上，Polygon[{p1,p2,…,pn}]に等しい．
  • CrossingPolygon[{{p11,p12,…},{p21,p22,…},…}]は，一般に，Polygon[{{p11,p12,…},{p21,p22,…},…}]とは異なる．前者がすべての閉曲線{pi1,pi2,…}に対して半直線交差規則を使うのに対し，後者は多角形Polygon[{pi1,pi2,…}]の和集合であるからである．
  • 点 piは任意の長さでよいが，すべてが平面上になければならない．
  • CrossingPolygonはPolygonと同じオプションを取る．

    • 全オプションのリスト

例題

すべて開く すべて閉じる

例  (2)

多角形を定義する：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

自己交差する輪郭線から多角形を構築する：

Wolfram Language code: CrossingPolygon[{{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}}]

その面積を計算する：

Wolfram Language code: Area[%]

スコープ  (11)

基本的な用法  (5)

二次元の多角形を定義する：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

三次元の多角形：

Wolfram Language code: CrossingPolygon[{{1, 0, 0}, {1, (2/Sqrt[5]), (1/Sqrt[5])}, {1 - Sqrt[(5/6)], (2/Sqrt[5]) - (1/Sqrt[30]), Sqrt[(2/15)] + (1/Sqrt[5])}}]
Wolfram Language code: Graphics3D[%]

次元の多角形：

Wolfram Language code: CrossingPolygon[{{1, 0, 0, 3}, {1, 1, 1, 3}, {(2/3), (1/3), (2/3), 3}, {0, 0, 1, 3}}]

自己交差する輪郭線から多角形を構築する：

Wolfram Language code: CrossingPolygon[{{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}}]
Wolfram Language code: Graphics[%]

複数の輪郭線：

Wolfram Language code: CrossingPolygon[{{{0.3, 0.}, {-0.8, 0.6}, {-0.8, -0.6}, {0.3, 0.}}, {{1.5, 0.}, {0.4, 0.6}, {0.4, -0.6}, {1.5, 0.}}}]
Wolfram Language code: Graphics[%]

自己交差する輪郭線  (3)

CrossingPolygonは自己交差する輪郭線に使うことができる：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

重なり合う輪郭線の線分：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}, {0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

複数の輪郭線：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

複数の輪郭線  (3)

CrossingPolygonは複数の輪郭線に使うことができる：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

自己交差する輪郭線：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

自己交差する輪郭線：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

オプション  (6)

VertexColors  (2)

頂点が着色された多角形：

Wolfram Language code: Graphics[CrossingPolygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]

3D多角形の頂点の色を指定する：

Wolfram Language code: Graphics3D[CrossingPolygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

VertexNormals  (1)

辺ベクトルの外積を使って法線ベクトルを計算する：

Wolfram Language code: {p1, p2, p3} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};
Wolfram Language code: n = Cross[p2 - p1, p3 - p1]

法線が{1,-1,1}を指している三角形：

Wolfram Language code: Graphics3D[{Yellow, CrossingPolygon[{p1, p2, p3}, VertexNormals -> {n, n, n}]}]

異なる法線を使うと陰影に影響がある：

Wolfram Language code: Graphics3D[{Yellow, CrossingPolygon[{p1, p2, p3}, VertexNormals -> {-n, n, n}]}]

VertexTextureCoordinates  (3)

2D多角形のテクスチャマッピング：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "Airplane2"}]], CrossingPolygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}]

3D多角形のテクスチャマッピング：

Wolfram Language code: Graphics3D[{Texture[ExampleData[{"TestImage", "Airplane2"}]], CrossingPolygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, Lighting -> "Neutral"]

非統一テクスチャ座標値を使ってテクスチャを繰り返す：

Wolfram Language code: {Graphics[{Texture[ExampleData[{"TestImage", "Mandrill"}]], CrossingPolygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "Mandrill"}]], CrossingPolygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}, Lighting -> "Neutral"]}

VertexColorsはテクスチャマッピングに先立つ：

Wolfram Language code: Graphics3D[{Texture[[image]], CrossingPolygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Purple}]}, Lighting -> "Neutral"]

アプリケーション  (3)

基本的なアプリケーション  (1)

輪郭線からの多角形の構築：

Wolfram Language code: contours = {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]}; Grid[{{"self-intersecting", "overlay", "nested"}, Graphics[Line[#], ImageSize -> {80, 80}]& /@ contours, Graphics[CrossingPolygon[#], ImageSize -> {80, 80}]& /@ contours}, Spacings -> {Automatic, {0, 1.5, 1}}, Dividers -> {None, {2 -> GrayLevel[.5], -2 -> Directive[GrayLevel[.2], Dotted]}}]

コンピュータグラフィックス  (1)

タートル描画多角形．20ステップ進む．常に左に110°曲がる：

Wolfram Language code: CrossingPolygon[AnglePath[ConstantArray[110°, 20]]]
Wolfram Language code: Graphics[%]

計算幾何学  (1)

ランダムな多角形を生成する：

Wolfram Language code: CrossingPolygon[RandomReal[1, {20, 2}]]
Wolfram Language code: Graphics[%]

特性と関係  (3)

CrossingPolygonは，事実上，単一の輪郭線に関しては評価するとPolygonになる：

Wolfram Language code: pts = {{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}};
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], Polygon[pts]}

CrossingPolygonは，一般に，複数の交差がある輪郭線についてはPolygonとは異なる：

Wolfram Language code: pts = IconizedObject[«[image]»];
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], Polygon[pts]}

WindingPolygonは，別の多角形の輪郭線である：

Wolfram Language code: pts = {{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}};
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], WindingPolygon[pts]}

考えられる問題  (1)

CrossingPolygon中の点はすべて平面上になければならない：

Wolfram Language code: CrossingPolygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]

おもしろい例題  (1)

デジタル花弁：

Wolfram Language code: With[{d = 2Pi / 12}, Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], CrossingPolygon[{(8 - r){Cos[d(q - 1)], Sin[d(q - 1)]}, (8 - r){Cos[d(q + 1)], Sin[d(q + 1)]}, (10 - r){Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]]]
Wolfram Research (2019), CrossingPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/CrossingPolygon.html.

テキスト

Wolfram Research (2019), CrossingPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/CrossingPolygon.html.

CMS

Wolfram Language. 2019. "CrossingPolygon." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CrossingPolygon.html.

APA

Wolfram Language. (2019). CrossingPolygon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CrossingPolygon.html

BibTeX

@misc{reference.wolfram_2026_crossingpolygon, author="Wolfram Research", title="{CrossingPolygon}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/CrossingPolygon.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_crossingpolygon, organization={Wolfram Research}, title={CrossingPolygon}, year={2019}, url={https://reference.wolfram.com/language/ref/CrossingPolygon.html}, note=[Accessed: 13-September-2026]}