WOLFRAM

Wolfram 语言与系统参考资料中心

CrossingPolygon[{p1,p2,…,pn}]

给出表示一些点的 Polygon，在平面上从这些点出发的射线从任意方向上穿过线段 {p1,p2},…,{pn-1,pn},{pn,p1} 奇数次.

CrossingPolygon[{{p11,p12,…},{p21,p22,…},…}]

根据线段 {p11,p12},…,{p21,p22},… 给出 Polygon.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
自相交轮廓线  
多个轮廓线  
选项  
VertexColors  
VertexNormals  
VertexTextureCoordinates  
应用  
基本应用  
计算机图形  
计算几何  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CrossingPolygon

CrossingPolygon[{p1,p2,…,pn}]

给出表示一些点的 Polygon，在平面上从这些点出发的射线从任意方向上穿过线段 {p1,p2},…,{pn-1,pn},{pn,p1} 奇数次.

CrossingPolygon[{{p11,p12,…},{p21,p22,…},…}]

根据线段 {p11,p12},…,{p21,p22},… 给出 Polygon.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

定义一个多边形：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

根据自相交轮廓线构建多边形：

Wolfram Language code: CrossingPolygon[{{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}}]

计算其面积：

Wolfram Language code: Area[%]

范围  (11)

基本用法  (5)

定义一个二维多边形：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

三维多边形：

Wolfram Language code: CrossingPolygon[{{1, 0, 0}, {1, (2/Sqrt[5]), (1/Sqrt[5])}, {1 - Sqrt[(5/6)], (2/Sqrt[5]) - (1/Sqrt[30]), Sqrt[(2/15)] + (1/Sqrt[5])}}]
Wolfram Language code: Graphics3D[%]

-维多边形：

Wolfram Language code: CrossingPolygon[{{1, 0, 0, 3}, {1, 1, 1, 3}, {(2/3), (1/3), (2/3), 3}, {0, 0, 1, 3}}]

根据自相交轮廓线构建多边形：

Wolfram Language code: CrossingPolygon[{{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}}]
Wolfram Language code: Graphics[%]

多个轮廓线：

Wolfram Language code: CrossingPolygon[{{{0.3, 0.}, {-0.8, 0.6}, {-0.8, -0.6}, {0.3, 0.}}, {{1.5, 0.}, {0.4, 0.6}, {0.4, -0.6}, {1.5, 0.}}}]
Wolfram Language code: Graphics[%]

自相交轮廓线  (3)

CrossingPolygon 适用于自相交轮廓线：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

重叠轮廓线：

Wolfram Language code: CrossingPolygon[{{0, 0}, {1, 0}, {1, 1}, {0, 0}, {1, 0}, {1, 1}}]
Wolfram Language code: Graphics[%]

多个轮廓线：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

多个轮廓线  (3)

CrossingPolygon 适用于多个轮廓线：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

相交轮廓线：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

自相交轮廓线：

Wolfram Language code: CrossingPolygon[IconizedObject[«[image]»]]
Wolfram Language code: Graphics[%]

选项  (6)

VertexColors  (2)

顶点着色的多边形：

Wolfram Language code: Graphics[CrossingPolygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]

指定三维多边形的顶点的颜色：

Wolfram Language code: Graphics3D[CrossingPolygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

VertexNormals  (1)

用边向量的叉积计算法向量：

Wolfram Language code: {p1, p2, p3} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};
Wolfram Language code: n = Cross[p2 - p1, p3 - p1]

法线指向 {1,-1,1} 的三角形：

Wolfram Language code: Graphics3D[{Yellow, CrossingPolygon[{p1, p2, p3}, VertexNormals -> {n, n, n}]}]

使用不同的法线将影响明暗：

Wolfram Language code: Graphics3D[{Yellow, CrossingPolygon[{p1, p2, p3}, VertexNormals -> {-n, n, n}]}]

VertexTextureCoordinates  (3)

对 2D 多边形进行纹理映射：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "Airplane2"}]], CrossingPolygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}]

对 3D 多边形进行纹理映射：

Wolfram Language code: Graphics3D[{Texture[ExampleData[{"TestImage", "Airplane2"}]], CrossingPolygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, Lighting -> "Neutral"]

使用非统一纹理坐标值重复纹理：

Wolfram Language code: {Graphics[{Texture[ExampleData[{"TestImage", "Mandrill"}]], CrossingPolygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "Mandrill"}]], CrossingPolygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}, Lighting -> "Neutral"]}

纹理映射没有 VertexColors 的优先级高：

Wolfram Language code: Graphics3D[{Texture[[image]], CrossingPolygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Purple}]}, Lighting -> "Neutral"]

应用  (3)

基本应用  (1)

根据轮廓线构建多边形：

Wolfram Language code: contours = {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]}; Grid[{{"self-intersecting", "overlay", "nested"}, Graphics[Line[#], ImageSize -> {80, 80}]& /@ contours, Graphics[CrossingPolygon[#], ImageSize -> {80, 80}]& /@ contours}, Spacings -> {Automatic, {0, 1.5, 1}}, Dividers -> {None, {2 -> GrayLevel[.5], -2 -> Directive[GrayLevel[.2], Dotted]}}]

计算机图形  (1)

乌龟绘图. 前进 20 步，始终向左转 110°：

Wolfram Language code: CrossingPolygon[AnglePath[ConstantArray[110°, 20]]]
Wolfram Language code: Graphics[%]

计算几何  (1)

生成随机多边形：

Wolfram Language code: CrossingPolygon[RandomReal[1, {20, 2}]]
Wolfram Language code: Graphics[%]

属性和关系  (3)

对于单轮廓线，CrossingPolygon 实际上等价于 Polygon：

Wolfram Language code: pts = {{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}};
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], Polygon[pts]}

一般情况下，对于多个相交轮廓线，CrossingPolygon 不同于 Polygon：

Wolfram Language code: pts = IconizedObject[«[image]»];
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], Polygon[pts]}

WindingPolygon 是另一个可用来构建多边形的函数：

Wolfram Language code: pts = {{0.35, 0.2}, {0.9, 0.75}, {0.1, 0.55}, {0.9, 0.35}, {0.42, 0.9}};
Wolfram Language code: Graphics /@ {CrossingPolygon[pts], WindingPolygon[pts]}

可能存在的问题  (1)

CrossingPolygon 中的点必须位于一个平面上：

Wolfram Language code: CrossingPolygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]

巧妙范例  (1)

数字花瓣：

Wolfram Language code: With[{d = 2Pi / 12}, Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], CrossingPolygon[{(8 - r){Cos[d(q - 1)], Sin[d(q - 1)]}, (8 - r){Cos[d(q + 1)], Sin[d(q + 1)]}, (10 - r){Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]]]
Wolfram Research (2019)，CrossingPolygon，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CrossingPolygon.html.

文本

Wolfram Research (2019)，CrossingPolygon，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CrossingPolygon.html.

CMS

Wolfram 语言. 2019. "CrossingPolygon." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CrossingPolygon.html.

APA

Wolfram 语言. (2019). CrossingPolygon. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CrossingPolygon.html 年

BibTeX

@misc{reference.wolfram_2026_crossingpolygon, author="Wolfram Research", title="{CrossingPolygon}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/CrossingPolygon.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_crossingpolygon, organization={Wolfram Research}, title={CrossingPolygon}, year={2019}, url={https://reference.wolfram.com/language/ref/CrossingPolygon.html}, note=[Accessed: 15-September-2026]}