Csch

Csch[z]

z の双曲線余割を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
1/Sinh[z]は自動的にCsch[z]に変換される．分解するにはTrigFactorList[expr]を使う．
特別な引数の場合，Cschは自動的に厳密値を計算する．
Cschは任意の数値精度で評価できる
Cschは自動的にリストに縫い込まれる． »
CschはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

Cschは，双曲線余割関数である．これは，三角法で頻繁に使われる，Csc円関数の双曲線バージョンのようなものである．これは，双曲線正弦関数の逆数として，と定義される．これは，実数について，の面積が，単位双曲線と交わる原点からの放射線と軸との間の面積の2倍になるようにすることで定義される．そうすると，Csch[α]は交点の垂直座標の逆数を表す．Cschはとしても定義される．ただし，は自然対数Logの底である．
Cschは，その引数が有理数の（自然）対数であるときは，自動的に厳密値に評価される．引数として厳密な数式が与えられると，Cschは任意の数値精度に評価されることがある．TrigFactorListを使って，Cschを含む式をSinh，Cosh，Sin，Cosを含む項に因子分解することができる．Cschを含む記号式の操作に便利なその他の演算には，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
Cschは要素単位でリストおよび行列に縫い込まれる．対照的に，個々の行列要素の双曲線余割とは違って，MatrixFunctionは正方行列の双曲線余割（つまり，通常のベキが行列のベキで置き換えられた双曲線余割関数のベキ級数）を与えるのに使うことができる．
Csch[x]は，x がに近付くにつれて，指数的に減少する．Cschは，Cscによって満足されるような，ピタゴラス(Pythagorean)の恒等式に似た恒等式を満足する．双曲線余割関数の定義は，恒等式によって，複素引数にまで拡張される．Cschは整数について値において極を持ち，これらの点で評価するとComplexInfinityになる．Csch[z]は，原点付近で級数展開 $sum_(k=0)^infty(2(2^(2 k-1)-1) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ を持つ．これはベルヌーイ(Bernoulli)数BernoulliBによって表すことができる．
Cschの逆関数はArcCschである．他の関連する数学関数にはSinhおよびSechがある．

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: Csch[1.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Csch[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Csch[z], {z, -2 - 2I π, 2 + 2I π}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Csch[x], {x, 0, 10}]

特異点における漸近展開：

Wolfram Language code: Series[Csch[x], {x, 2 I π, 3}]//Normal

スコープ (47)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Csch[1.8]

高精度で評価する：

Wolfram Language code: N[Csch[18 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Csch[1.80000000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: Csch[2.5 + I]

Cschを高精度で効率よく評価する：

Wolfram Language code: Csch[1.8`500]//Timing

Wolfram Language code: Csch[1.8`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Csch[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

MatrixFunctionを使って行列のCsch関数を計算することもできる：

Wolfram Language code: MatrixFunction[Csch[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Csch[Interval[{0, Log[3]}]]

Wolfram Language code: Csch[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Csch[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Csch[Around[(2/Sqrt[3]), 0.1]]

特定の値 (5)

固定された純粋な虚点におけるCschの値：

Wolfram Language code: Table[Csch[I(π/6)n], {n, -3, 3}]

無限大における値：

Wolfram Language code: Csch[Infinity]

Wolfram Language code: Csch[ComplexInfinity]

Cschの特異点：

Wolfram Language code: Csch[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := Csch[x] - 1;

Wolfram Language code: sol = Solve[f[x] == 0 && 0 < x, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, 0, 4}, Epilog -> {Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]}]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Csch[I Pi / 3]

より複雑な場合には明示的にFunctionExpandを使用する必要がある：

Wolfram Language code: Csch[I Pi / 24]

Wolfram Language code: FunctionExpand[%]

可視化 (3)

Csch関数をプロットする：

Wolfram Language code: Plot[Csch[x], {x, -2.5, 2.5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Csch[z]], {z, -2 - 3I, 2 + 3I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Csch[z]], {z, -2 - 3I, 2 + 3I}, Contours -> 24]

の極プロット：

Wolfram Language code:

Table[PolarPlot[Csch[k ϕ], {ϕ, -2π, 2π}, Sequence[Frame -> True, Axes -> False, Exclusions -> All, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-1, 1}, {-0.6, 1}}, FrameTicks -> {{{-1, 1}, None}, {{-1, 0, 1}, None}}]], {k, 1, 6}]

関数の特性 (12)

実数上のCschの領域：

Wolfram Language code: FunctionDomain[Csch[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Csch[z], z, Complexes]

Cschは0以外のすべての実数値に達する：

Wolfram Language code: FunctionRange[Csch[x], x, y]

Cschは奇関数である：

Wolfram Language code: Csch[-x]

Cschは鏡特性を有する：

Wolfram Language code: FullSimplify[Csch[Conjugate[z]] == Conjugate[Csch[z]]]

Cschは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Csch[x], x]

しかし，有理型である：

Wolfram Language code: FunctionMeromorphic[Csch[x], x]

Cschは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[Csch[x], x]

Cschは単射である：

Wolfram Language code: FunctionInjective[Csch[x], x]

Wolfram Language code: Plot[{Csch[x], .3}, {x, -5, 5}]

Cschは全射ではない：

Wolfram Language code: FunctionSurjective[Csch[x], x]

Wolfram Language code: Plot[{Csch[x], 0}, {x, -5, 5}]

Cschは非負でも非正でもない：

Wolfram Language code: FunctionSign[Csch[x], x]

Cschは零点に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Csch[x], x]

Wolfram Language code: FunctionDiscontinuities[Csch[x], x]

Cschは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Csch[x], x]

TraditionalFormによる表示：

Wolfram Language code: Csch[z]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Csch[x], x]

高次導関数：

Wolfram Language code: Table[D[Csch[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Csch[x], {x, n}]

積分 (3)

Cschの不定積分：

Wolfram Language code: Integrate[Csch[x], x]

原点を中心とした区間上の奇関数の定積分は0である：

Wolfram Language code: Integrate[Csch[x], {x, -2, 2}, PrincipalValue -> True]

その他の積分例：

Wolfram Language code: Integrate[Csch[x]Sech[x], x]

Wolfram Language code: Integrate[x ^ 2Csch[x], x]//Simplify

級数展開 (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Csch[x], {x, Log[2], 7}]

の周りのCschの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Csch[x], {x, Log[2], m}], {m, 0, 5, 2}];
Plot[{Csch[x], terms}, {x, .5, 1.5}]

Cschの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Csch[x], {x, 0, n}]

Cschはベキ級数に適用できる：

Wolfram Language code: Csch[x + (x^2/2) + (x^3/9) + O[x]^4]

積分変換 (2)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[Csch[t], t, s]

FourierTransform：

Wolfram Language code: FourierTransform[Csch[ω], ω, t]

関数の恒等式と簡約 (6)

倍角のCsch：

Wolfram Language code: Expand[Csch[2x], Trig -> True]

総和のCsch：

Wolfram Language code: TrigExpand[Csch[x + y]]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Csch[4x]]

Wolfram Language code: TrigReduce[%]

双曲線関数の総和を積に変換する：

Wolfram Language code: TrigFactor[Csch[x] + Csch[y]]

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[Csch[x + I y]]

指数関数に変換する：

Wolfram Language code: TrigToExp[Csch[z]]

関数表現 (4)

Sinを介した表現：

Wolfram Language code: Simplify[I / Sin[I y]]

ベッセル(Bessel)関数を介した表現：

Wolfram Language code: Simplify[Sqrt[(2/Pi x)] / BesselI[(1/2), x], x > 0]

Wolfram Language code: Simplify[I Sqrt[(2/Pi I y)] / BesselY[-(1/2), I y], y > 0]

ヤコビ関数を介した表現：

Wolfram Language code: Simplify[JacobiCS[x, 1]]

Wolfram Language code: Simplify[I JacobiDS[I y, 0]]

MeijerGによる表現：

Wolfram Language code: (1/Sqrt[2]π^3 / 2MeijerG[{{}, {(3/4)}}, {{(1/2)}, {(3/4), 0}}, (x/2), (1/2)])//FullSimplify

アプリケーション (3)

複素平面上で絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[Csch[x + I y]], {x, -2, 2}, {y, -2Pi, 2Pi}]

ポアンソ(Poinsot)の渦巻きをプロットする：

Wolfram Language code: ParametricPlot[Table[Csch[n θ]{Cos[θ], Sin[θ]}, {n, -2, 2, 4 / 10}]//Evaluate, {θ, -Pi, Pi}]

微分方程式を解く：

Wolfram Language code: DSolve[y'[x] - y[x] - Csch[x] == 0, y, x]

特性と関係 (9)

Cschの基本的なパリティと周期性の特性は自動的に適用される：

Wolfram Language code: Csch[x + Pi I]

Wolfram Language code: Csch[-x]

Wolfram Language code: Csch[I x]

SimplifyとFullSimplifyを使ってCschを含む式を簡約する：

Wolfram Language code: Simplify[4Csch[2z] ^ 2(1 + Csch[z] ^ 2)]

Wolfram Language code: FullSimplify[Csch[Log[GoldenRatio]]]

FunctionExpandを使って累乗根における特別な値を表現する：

Wolfram Language code: FunctionExpand[Csch[I Pi / 16]]

逆関数を使って構成する：

Wolfram Language code: {Csch[ArcCsch[z]], Csch[2ArcCsch[z]], Csch[3ArcCsch[z]]}

Wolfram Language code: FunctionExpand[%]//Simplify

双曲型方程式を解く：

Wolfram Language code: Reduce[Csch[z]^2 + Csch[z + 1] == 1, z]

Wolfram Language code: Reduce[Csch[a x + b] == 1, x]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Csch[z]^3 - 3Csch[z + 1] + z == 3, {z, 1}]

総和，積，微分方程式からCschを得る：

Wolfram Language code: Sum[(-1) ^ k / (z ^ 2 + Pi ^ 2k ^ 2), {k, 1, Infinity}]//Simplify

Wolfram Language code: Product[(Pi ^ 2k ^ 2) / (z ^ 2 + Pi ^ 2k ^ 2), {k, 1, Infinity}]

Cschは特殊関数の特殊なケースに見られる：

Wolfram Language code: {1 / HypergeometricPFQ[{}, {3 / 2}, z ^ 2 / 4], JacobiCN[Pi I / 2 - z, 1]}

Cschは数値関数である：

Wolfram Language code: Attributes[Csch]

Wolfram Language code: NumericQ[Csch[2 + E]]

考えられる問題 (5)

機械精度の入力は正しい答を出すのには不十分である：

Wolfram Language code: Csch[10. ^ 30 I]

代りに任意精度で評価する：

Wolfram Language code: N[Csch[10 ^ 30I], 10]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Csch[10 ^ 65I], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 70}, N[Csch[10 ^ 65I], 20]]

Cschの逆関数を評価するとSinhになる：

Wolfram Language code: 1 / Csch[x]

Cschが真性特異点を持つ無限大にはベキ級数は存在しない：

Wolfram Language code: Series[Csch[x], {x, Infinity, 2}]

TraditionalFormでは引数の前後に丸カッコが必要である：

Wolfram Language code: csch x

Wolfram Language code: csch(x)

おもしろい例題 (1)

無限大でCschをプロットする：

Wolfram Language code: ContourPlot[Arg[Csch[1 / (x + I y)]], {x, -1 / 4, 1 / 4}, {y, -1 / 2, 1 / 2}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Csch

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (5)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (3)

特性と関係 (9)

考えられる問題 (5)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Csch

詳細

予備知識

例題

例 (5)

スコープ (47)

数値評価 (6)

特定の値 (5)

可視化 (3)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (2)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (3)

特性と関係 (9)

考えられる問題 (5)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX