Wolfram 语言与系统参考资料中心

Csch

Csch[z]

给出 z 的双曲余割.

背景

Csch 是双曲余割函数，是三角学中普遍使用的 Csc 圆函数的双曲类比. 它被定义为双曲正弦函数的倒数 . 对于实数变量它的定义如下：设是三条线轴、从原点出发的射线以及单位双曲线围成的封闭区域面积的两倍，则 Csch[α] 表示射线与双曲线交点的纵坐标的倒数. Csch 也可以定义为，其中是自然对数 Log 的底数.
当变量是有理数的（自然）对数时，Csch 会自动计算出精确值. 当给出精确数值表达式作为变量时，Csch 可以算出任意精度的数值结果. TrigFactorList 可将包含 Csch 的表达式因式分解为包含 Sinh、Cosh、Sin 和 Cos 的单项式. 对包含 Csch 的符号表达式，其他适用的操作运算有 TrigToExp、TrigExpand、Simplify 和 FullSimplify.
Csch 自动逐项作用于列表和矩阵. 相比之下，MatrixFunction 则可用于给出整个方阵的双曲余割值（即用矩阵幂次代替普通幂次的双曲余割函数的幂级数）而不是单个矩阵元素的双曲余割值.
当 x 趋向于时，Csch[x] 呈指数级递减. Csch 和 Csc 类似，也满足勾股恒等式，即 . 双曲余割函数的定义可由等式扩展到复数域上. Csch 在且是整数的这些点处取得极值 ComplexInfinity. Csch[z] 在原点处的级数展开为 $sum_(k=0)^infty(2(2^(2 k-1)-1) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ ，可由伯努利数 BernoulliB 构成的项表示.
Csch 的反函数是 ArcCsch. 其他相关的数学函数有 Sinh 和 Sech.

范例

打开所有单元关闭所有单元

基本范例 (5)

数值运算：

Wolfram Language code: Csch[1.8]

在实数子集上绘图：

Wolfram Language code: Plot[Csch[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Csch[z], {z, -2 - 2I π, 2 + 2I π}, PlotLegends -> Automatic]

在原点处的级数展开式：

Wolfram Language code: Series[Csch[x], {x, 0, 10}]

在奇点处的渐近展开式：

Wolfram Language code: Series[Csch[x], {x, 2 I π, 3}]//Normal

范围 (47)

数值计算 (6)

数值计算：

Wolfram Language code: Csch[1.8]

高精度求值：

Wolfram Language code: N[Csch[18 / 10], 50]

输出精度与输入精度一致：

Wolfram Language code: Csch[1.80000000000000000000000000000000000000000000]

对复变量求值：

Wolfram Language code: Csch[2.5 + I]

在高精度条件下高效计算 Csch：

Wolfram Language code: Csch[1.8`500]//Timing

Wolfram Language code: Csch[1.8`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Csch[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

或用 MatrixFunction 计算矩阵形式的 Csch 函数：

Wolfram Language code: MatrixFunction[Csch[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Csch[Interval[{0, Log[3]}]]

Wolfram Language code: Csch[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Csch[CenteredInterval[2 + 3I, (1 + I) / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Csch[Around[(2/Sqrt[3]), 0.1]]

特殊值 (5)

Csch 在纯虚数点上的值：

Wolfram Language code: Table[Csch[I(π/6)n], {n, -3, 3}]

无穷处的值：

Wolfram Language code: Csch[Infinity]

Wolfram Language code: Csch[ComplexInfinity]

Csch 的奇点：

Wolfram Language code: Csch[0]

求满足方程的值：

Wolfram Language code: f[x_] := Csch[x] - 1;

Wolfram Language code: sol = Solve[f[x] == 0 && 0 < x, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 4}, Epilog -> {Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]}]

自动生成简单精确值：

Wolfram Language code: Csch[I Pi / 3]

更复杂的情况则需使用 FunctionExpand：

Wolfram Language code: Csch[I Pi / 24]

Wolfram Language code: FunctionExpand[%]

可视化 (3)

绘制 Csch 函数：

Wolfram Language code: Plot[Csch[x], {x, -2.5, 2.5}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Csch[z]], {z, -2 - 3I, 2 + 3I}, Contours -> 24]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Csch[z]], {z, -2 - 3I, 2 + 3I}, Contours -> 24]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[Csch[k ϕ], {ϕ, -2π, 2π}, Sequence[Frame -> True, Axes -> False, Exclusions -> All, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-1, 1}, {-0.6, 1}}, FrameTicks -> {{{-1, 1}, None}, {{-1, 0, 1}, None}}]], {k, 1, 6}]

函数属性 (12)

Csch 的实定义域：

Wolfram Language code: FunctionDomain[Csch[x], x]

复定义域：

Wolfram Language code: FunctionDomain[Csch[z], z, Complexes]

Csch 的值域是除 0 以外的所有实数：

Wolfram Language code: FunctionRange[Csch[x], x, y]

Csch 是一个奇函数：

Wolfram Language code: Csch[-x]

Csch 具有镜像属性：

Wolfram Language code: FullSimplify[Csch[Conjugate[z]] == Conjugate[Csch[z]]]

Csch 不是解析函数：

Wolfram Language code: FunctionAnalytic[Csch[x], x]

但是，它是亚纯函数：

Wolfram Language code: FunctionMeromorphic[Csch[x], x]

Csch 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[Csch[x], x]

Csch 是单射函数：

Wolfram Language code: FunctionInjective[Csch[x], x]

Wolfram Language code: Plot[{Csch[x], .3}, {x, -5, 5}]

Csch 不是满射函数：

Wolfram Language code: FunctionSurjective[Csch[x], x]

Wolfram Language code: Plot[{Csch[x], 0}, {x, -5, 5}]

Csch 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Csch[x], x]

Csch 在零处有奇点和断点：

Wolfram Language code: FunctionSingularities[Csch[x], x]

Wolfram Language code: FunctionDiscontinuities[Csch[x], x]

Csch 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Csch[x], x]

TraditionalForm 格式：

Wolfram Language code: Csch[z]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[Csch[x], x]

高阶导数：

Wolfram Language code: Table[D[Csch[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[Csch[x], {x, n}]

积分 (3)

Csch 的不定积分：

Wolfram Language code: Integrate[Csch[x], x]

奇函数在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[Csch[x], {x, -2, 2}, PrincipalValue -> True]

更多积分：

Wolfram Language code: Integrate[Csch[x]Sech[x], x]

Wolfram Language code: Integrate[x ^ 2Csch[x], x]//Simplify

级数展开式 (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[Csch[x], {x, Log[2], 7}]

绘制 Csch 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[Csch[x], {x, Log[2], m}], {m, 0, 5, 2}];
Plot[{Csch[x], terms}, {x, .5, 1.5}]

Csch 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Csch[x], {x, 0, n}]

Csch 可被应用于幂级数：

Wolfram Language code: Csch[x + (x^2/2) + (x^3/9) + O[x]^4]

积分变换 (2)

使用 LaplaceTransform 计算拉普拉斯变换：

Wolfram Language code: LaplaceTransform[Csch[t], t, s]

FourierTransform:

Wolfram Language code: FourierTransform[Csch[ω], ω, t]

函数属性和化简 (6)

倍角的 Csch：

Wolfram Language code: Expand[Csch[2x], Trig -> True]

和的 Csch：

Wolfram Language code: TrigExpand[Csch[x + y]]

转换多倍角表达式：

Wolfram Language code: TrigExpand[Csch[4x]]

Wolfram Language code: TrigReduce[%]

将双曲线函数的和形式转换为积形式：

Wolfram Language code: TrigFactor[Csch[x] + Csch[y]]

假定为实变量和进行展开：

Wolfram Language code: ComplexExpand[Csch[x + I y]]

转换为指数形式：

Wolfram Language code: TrigToExp[Csch[z]]

函数表示 (4)

用 Sin 表示：

Wolfram Language code: Simplify[I / Sin[I y]]

用贝塞尔函数来表示：

Wolfram Language code: Simplify[Sqrt[(2/Pi x)] / BesselI[(1/2), x], x > 0]

Wolfram Language code: Simplify[I Sqrt[(2/Pi I y)] / BesselY[-(1/2), I y], y > 0]

用 Jacobi 函数来表示：

Wolfram Language code: Simplify[JacobiCS[x, 1]]

Wolfram Language code: Simplify[I JacobiDS[I y, 0]]

用 MeijerG 表示：

Wolfram Language code: (1/Sqrt[2]π^3 / 2MeijerG[{{}, {(3/4)}}, {{(1/2)}, {(3/4), 0}}, (x/2), (1/2)])//FullSimplify

应用 (3)

绘制复平面上的绝对值：

Wolfram Language code: Plot3D[Abs[Csch[x + I y]], {x, -2, 2}, {y, -2Pi, 2Pi}]

绘制 Poinsot 螺旋图线：

Wolfram Language code: ParametricPlot[Table[Csch[n θ]{Cos[θ], Sin[θ]}, {n, -2, 2, 4 / 10}]//Evaluate, {θ, -Pi, Pi}]

解微分方程：

Wolfram Language code: DSolve[y'[x] - y[x] - Csch[x] == 0, y, x]

属性和关系 (9)

Csch 自动应用的奇偶性和周期性：

Wolfram Language code: Csch[x + Pi I]

Wolfram Language code: Csch[-x]

Wolfram Language code: Csch[I x]

用 Simplify 和 FullSimplify 来化简包含 Csch 的表达式：

Wolfram Language code: Simplify[4Csch[2z] ^ 2(1 + Csch[z] ^ 2)]

Wolfram Language code: FullSimplify[Csch[Log[GoldenRatio]]]

用 FunctionExpand 表示根式中的特殊值：

Wolfram Language code: FunctionExpand[Csch[I Pi / 16]]

由反函数组成：

Wolfram Language code: {Csch[ArcCsch[z]], Csch[2ArcCsch[z]], Csch[3ArcCsch[z]]}

Wolfram Language code: FunctionExpand[%]//Simplify

求双曲线方程：

Wolfram Language code: Reduce[Csch[z]^2 + Csch[z + 1] == 1, z]

Wolfram Language code: Reduce[Csch[a x + b] == 1, x]

求超越方程的数值根：

Wolfram Language code: FindRoot[Csch[z]^3 - 3Csch[z + 1] + z == 3, {z, 1}]

从求和、积和微分方程获得 Csch ：

Wolfram Language code: Sum[(-1) ^ k / (z ^ 2 + Pi ^ 2k ^ 2), {k, 1, Infinity}]//Simplify

Wolfram Language code: Product[(Pi ^ 2k ^ 2) / (z ^ 2 + Pi ^ 2k ^ 2), {k, 1, Infinity}]

在许多数学函数的特例中出现 Csch：

Wolfram Language code: {1 / HypergeometricPFQ[{}, {3 / 2}, z ^ 2 / 4], JacobiCN[Pi I / 2 - z, 1]}

Csch 是一个数值方程：

Wolfram Language code: Attributes[Csch]

Wolfram Language code: NumericQ[Csch[2 + E]]

可能存在的问题 (5)

机器精度输入不足以获得正确结果：

Wolfram Language code: Csch[10. ^ 30 I]

使用精确输入，得到正确结果：

Wolfram Language code: N[Csch[10 ^ 30I], 10]

或许要增大 $MaxExtraPrecision 的值：

Wolfram Language code: N[Csch[10 ^ 65I], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 70}, N[Csch[10 ^ 65I], 20]]

Csch 的逆为 Sinh：

Wolfram Language code: 1 / Csch[x]

在无穷大处不存在幂级数，其中 Csch 有一个重要的奇点：

Wolfram Language code: Series[Csch[x], {x, Infinity, 2}]

在 TraditionalForm 中，需要在自变量外加上圆括号：

Wolfram Language code: csch x

Wolfram Language code: csch(x)

巧妙范例 (1)

绘制无穷大处 Csch：

Wolfram Language code: ContourPlot[Arg[Csch[1 / (x + I y)]], {x, -1 / 4, 1 / 4}, {y, -1 / 2, 1 / 2}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Csch

更多信息

背景

范例

基本范例 (5)

范围 (47)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数属性和化简 (6)

函数表示 (4)

应用 (3)

属性和关系 (9)

可能存在的问题 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Csch

更多信息

背景

范例

基本范例 (5)

范围 (47)

数值计算 (6)

特殊值 (5)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (3)

积分变换 (2)

函数属性和化简 (6)

函数表示 (4)

应用 (3)

属性和关系 (9)

可能存在的问题 (5)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX