WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Dashing[{r1,r2,…}]

2Dグラフィックス指示子で，これに続く線は，長さr1，r2，…（周期的に繰り返される）の連続する線分からなる破線として描かれることを指定する．riは，グラフの全幅との比で与えられる．

Dashing[r]

Dashing[{r,r}]と等価である．

Dashing[{r1,r2,…},offset]

破線にオフセット offset を加える．

Dashing[{r1,r2,…},offset,capform]

個々の破線にCapForm capform を設定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
破線指定  
影響されるプリミティブ  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Dashing

Dashing[{r1,r2,…}]

2Dグラフィックス指示子で，これに続く線は，長さr1，r2，…（周期的に繰り返される）の連続する線分からなる破線として描かれることを指定する．riは，グラフの全幅との比で与えられる．

Dashing[r]

Dashing[{r,r}]と等価である．

Dashing[{r1,r2,…},offset]

破線にオフセット offset を加える．

Dashing[{r1,r2,…},offset,capform]

個々の破線にCapForm capform を設定する．

詳細

  • Dashingは，2D，3DのグラフィックスおよびStyle指定に使用することができる．
  • Dashing[{}]は，この線が破線ではない通常の線であることを指定する． »
  • r には，Tiny，Small，Medium，Largeの記号形式を使うことができる．これらで，グラフィックスの全体幅に依存しない絶対的な線分の長さを指定する． »
  • 線分の長さriが0に指定されている場合，この線分は直径が線の太さである点として描画される． »
  • offset はグラフの幅との正または負の割合で指定される．offset は，指定されていない場合は0である．
  • capform はCapForm[form]の任意の正当な form の値を取ることができる．これが指定されていない場合は，すべての線分が"Butt"キャップ形式で描画される．

例題

すべて開く すべて閉じる

例  (4)

破線をスケールされた長さの連続する線分として指定する：

Wolfram Language code: Table[Graphics[{Dashing[{r, 0.1 - r}], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]
Wolfram Language code: Table[Graphics3D[{Dashing[{r, 0.1 - r}], Line[{{0, 0, 0}, {2, 1, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]

多角形の辺の破線を指定する：

Wolfram Language code: p2 = Polygon[{{-1, 0}, {0, Sqrt[3]}, {1, 0}}];
Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], p2}], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: p3 = Polygon[{{1, 0, 0}, {0, 0, 1}, {1, 1, 1}}];
Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[{Dashing[r]}], p3}], {r, {0.01, 0.05, 0.1}}]

PlotStyleを使ってプロット中の破線を設定する：

Wolfram Language code: Plot[{Sin[x], Cos[x]}, {x, 0, 2 π}, PlotStyle -> {Dashing[Tiny], Dashing[Large]}]

枠のスタイルを破線に設定する：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> All, FrameStyle -> Dashing[Tiny]]

スコープ  (8)

破線指定  (5)

破線は使わない：

Wolfram Language code: Graphics[{Dashing[{}], Line[{{0, 0}, {2, 1}}]}]

Dashing[r]はDashing[{r,r}]と等しい：

Wolfram Language code: Table[Graphics[{Dashing[r], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]

定義済みの絶対破線の記号としての値：

Wolfram Language code: Table[Graphics[{Dashing[r], Line[{{0, 0}, {2, 1}}]}], {r, {Tiny, Small, Medium, Large}}]

複数の巡回する線分を指定する：

Wolfram Language code: Graphics[{Dashing[{0.1, 0.02, 0.05}], Line[{{0, 0}, {2, 1}}]}]

破線の線分のオフセットを指定する：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], Dashing[{.1, .05}, o], Red, Opacity[.5], Thickness[.05], Line[{{0, 0}, {2, 1}}]}], {o, {-0.05, 0, 0.05}}]

破線の線分のキャップを指定する：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], Dashing[{.1, .1}, 0, CapForm[c]], Red, Opacity[.5], Thickness[.05], Line[{{0, 0}, {2, 1}}]}], {c, {"Round", "Butt", "Square"}}]

影響されるプリミティブ  (3)

矢印の矢柄を破線に指定する：

Wolfram Language code: Graphics[{Dashing[0.02], Arrow[{{0, 0}, {2, 1}}]}]

EdgeFormを使ってプリミティブの辺の破線を指定する：

Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], Disk[]}], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], Rectangle[]}], {r, {0.01, 0.05, 0.1}}]

EdgeFormを使って3Dプリミティブの辺の破線を指定する：

Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[Dashing[r]], Cylinder[]}, Boxed -> False], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[Dashing[r]], Cuboid[]}, Boxed -> False], {r, {0.01, 0.05, 0.1}}]

特性と関係  (6)

Dashed，Dotted，DotDashedを使って定義済みの絶対破線を指定する：

Wolfram Language code: {Graphics[{Dashed, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Line[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Line[{{0, 0}, {2, 1}}]}]}

Dashingは線分の長さをグラフィクスの全体幅の比として定義する：

Wolfram Language code: Graphics[{Thick, Dashing[{0.05, 0.1}], Line[{{-1, 0}, {1, 0}}]}, Frame -> True]

Dashingは画像サイズに依存する：

Wolfram Language code: Table[Graphics[{Dashing[.05], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

AbsoluteDashingは線分の長さを印刷用ポイント数を単位として定義する：

Wolfram Language code: Graphics[{Thickness[.02], AbsoluteDashing[{15}], Line[{{0, 0}, {1, 0}}], Text[Style["15 points", FontSize -> 15], {0.5, 0.1}]}]

AbsoluteDashingは画像サイズに依存しない：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[10], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

線分の太さはThicknessで指定できる：

Wolfram Language code: Table[Graphics[{Thickness[r], Dashing[Medium], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05}}]

長さ0の線分はThicknessで大きさが定義される点を指定する：

Wolfram Language code: Graphics[{Thickness[.05], Dashing[{0, 0.1}], Line[{{0, 0}, {2, 1}}]}]

DashingはCapForm指示子よりも優先順位が高い：

Wolfram Language code: Graphics[{Dashing[{.2, .15}], CapForm["Round"], Thickness[.1], Line[{{0, 0}, {1, 1}}]}]

Dashingの第3引数を指定してすべての破線にキャップ形式を指定する：

Wolfram Language code: Graphics[{Dashing[{.2, .15}, 0, "Round"], Thickness[.1], Line[{{0, 0}, {1, 1}}]}]

考えられる問題  (1)

線にキャップを付けると個々の破線の長さが増すので，間隔が狭い破線の場合は重なってしまうかもしれない：

Wolfram Language code: Table[Graphics[{Dashing[{.2, .08}, 0, cap], Thickness[.1], Line[{{1, 0}, {0, 1}}]}], {cap, {None, "Round"}}]

おもしろい例題  (3)

ランダムな破線で描かれた円：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Dashing[RandomReal[{0, 0.07}]], Circle[RandomReal[1, {2}], RandomReal[]]}, {20}]]

ランダムな破線で描かれた曲線：

Wolfram Language code: ParametricPlot[t{Cos[t], Sin[t]}, {t, 0, 50}, PlotStyle -> Directive[Thick, Dashing[RandomReal[{0, 0.05}, 100]]]]

原点から出る破線の放射線のオフセットを変える：

Wolfram Language code: Animate[Graphics[{Dashing[{.04, .04}, a], Table[Line[{{0, 0}, {Cos[b], Sin[b]}}], {b, 0, 2 π, π / 20}]}], {a, 0.64, 0}]
Wolfram Research (1988), Dashing, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dashing.html （2021年に更新）.

テキスト

Wolfram Research (1988), Dashing, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dashing.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Dashing." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Dashing.html.

APA

Wolfram Language. (1988). Dashing. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Dashing.html

BibTeX

@misc{reference.wolfram_2026_dashing, author="Wolfram Research", title="{Dashing}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Dashing.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dashing, organization={Wolfram Research}, title={Dashing}, year={2021}, url={https://reference.wolfram.com/language/ref/Dashing.html}, note=[Accessed: 12-September-2026]}