WOLFRAM

Wolfram 语言与系统参考资料中心

Dashing[{r1,r2,…}]

是一个二维图形命令，指定用长度为 r1、r2 … （反复循环）的虚线绘制后面的线. 以占图形总宽度的比例给出 ri.

Dashing[r]

等同于 Dashing[{r,r}].

Dashing[{r1,r2,…},offset]

在每个短线前添加 offset.

Dashing[{r1,r2,…},offset,capform]

将每个短线的 CapForm 设置为 capform.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
虚线规范  
影响的基元  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

Dashing

Dashing[{r1,r2,…}]

是一个二维图形命令，指定用长度为 r1、r2 … （反复循环）的虚线绘制后面的线. 以占图形总宽度的比例给出 ri.

Dashing[r]

等同于 Dashing[{r,r}].

Dashing[{r1,r2,…},offset]

在每个短线前添加 offset.

Dashing[{r1,r2,…},offset,capform]

将每个短线的 CapForm 设置为 capform.

更多信息

  • Dashing 可用于二维和三维图形，还可用在 Style 的规范说明中.
  • Dashing[{}] 指定线为实线. »
  • r 可以使用下面的符号形式：Tiny、Small、Medium 和 Large. 这些符号指定了线段的绝对长度，和图形的总宽度无关. »
  • 如果一个线段的长度 ri 被定为 0，画出来的是一个点，直径和线的粗细一致. »
  • 以占图形总宽度的比例给出 offset，可以为正，也可以为负. 如果没有指定 offset，则其值为 0.
  • capform 可接受 CapForm[form] 形式的任何正常的 form 值. 如果没有指定，将以 "Butt" 端点格式绘制所有短线.

范例

打开所有单元 关闭所有单元

基本范例  (4)

指定虚线的样式，其线段长度依次成比例变化：

Wolfram Language code: Table[Graphics[{Dashing[{r, 0.1 - r}], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]
Wolfram Language code: Table[Graphics3D[{Dashing[{r, 0.1 - r}], Line[{{0, 0, 0}, {2, 1, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]

改变多边形边的虚线样式：

Wolfram Language code: p2 = Polygon[{{-1, 0}, {0, Sqrt[3]}, {1, 0}}];
Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], p2}], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: p3 = Polygon[{{1, 0, 0}, {0, 0, 1}, {1, 1, 1}}];
Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[{Dashing[r]}], p3}], {r, {0.01, 0.05, 0.1}}]

用 PlotStyle 在图形中设置虚线的样式：

Wolfram Language code: Plot[{Sin[x], Cos[x]}, {x, 0, 2 π}, PlotStyle -> {Dashing[Tiny], Dashing[Large]}]

设置虚线边框：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> All, FrameStyle -> Dashing[Tiny]]

范围  (8)

虚线规范  (5)

无虚线：

Wolfram Language code: Graphics[{Dashing[{}], Line[{{0, 0}, {2, 1}}]}]

Dashing[r] 等同于 Dashing[{r,r}]：

Wolfram Language code: Table[Graphics[{Dashing[r], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05, 0.08}}]

使用预定义的绝对虚线的符号值：

Wolfram Language code: Table[Graphics[{Dashing[r], Line[{{0, 0}, {2, 1}}]}], {r, {Tiny, Small, Medium, Large}}]

指定多重循环线段：

Wolfram Language code: Graphics[{Dashing[{0.1, 0.02, 0.05}], Line[{{0, 0}, {2, 1}}]}]

指定短线的偏移量：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], Dashing[{.1, .05}, o], Red, Opacity[.5], Thickness[.05], Line[{{0, 0}, {2, 1}}]}], {o, {-0.05, 0, 0.05}}]

指定短线端点的格式：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], Dashing[{.1, .1}, 0, CapForm[c]], Red, Opacity[.5], Thickness[.05], Line[{{0, 0}, {2, 1}}]}], {c, {"Round", "Butt", "Square"}}]

影响的基元  (3)

指定箭杆的虚线样式：

Wolfram Language code: Graphics[{Dashing[0.02], Arrow[{{0, 0}, {2, 1}}]}]

用 EdgeForm 指定图形基元边的虚线样式：

Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], Disk[]}], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: Table[Graphics[{Pink, EdgeForm[Dashing[r]], Rectangle[]}], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[Dashing[r]], Cylinder[]}, Boxed -> False], {r, {0.01, 0.05, 0.1}}]
Wolfram Language code: Table[Graphics3D[{Pink, EdgeForm[Dashing[r]], Cuboid[]}, Boxed -> False], {r, {0.01, 0.05, 0.1}}]

属性和关系  (6)

用 Dashed、Dotted 和 DotDashed 指定预定义的绝对虚线：

Wolfram Language code: {Graphics[{Dashed, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Line[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Line[{{0, 0}, {2, 1}}]}]}

Dashing 用图形总宽度的比例定义线段的长度.：

Wolfram Language code: Graphics[{Thick, Dashing[{0.05, 0.1}], Line[{{-1, 0}, {1, 0}}]}, Frame -> True]

Dashing 依赖于图形尺寸：

Wolfram Language code: Table[Graphics[{Dashing[.05], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

AbsoluteDashing 按打印机的点来定义线段的长度：

Wolfram Language code: Graphics[{Thickness[.02], AbsoluteDashing[{15}], Line[{{0, 0}, {1, 0}}], Text[Style["15 points", Black, FontSize -> 15], {0.5, 0.1}]}]

AbsoluteDashing 和图像尺寸无关：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[10], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

可以通过 Thickness 来指定线段的粗细：

Wolfram Language code: Table[Graphics[{Thickness[r], Dashing[Medium], Line[{{0, 0}, {2, 1}}]}], {r, {0.01, 0.03, 0.05}}]

长度为 0 的线段给出一个点，点的尺寸由 Thickness 定义：

Wolfram Language code: Graphics[{Thickness[.05], Dashing[{0, 0.1}], Line[{{0, 0}, {2, 1}}]}]

Dashing 将覆盖 CapForm 指令：

Wolfram Language code: Graphics[{Dashing[{.2, .15}], CapForm["Round"], Thickness[.1], Line[{{0, 0}, {1, 1}}]}]

指定 Dashing 的第三个参数来设置所有短线的端点格式：

Wolfram Language code: Graphics[{Dashing[{.2, .15}, 0, "Round"], Thickness[.1], Line[{{0, 0}, {1, 1}}]}]

可能存在的问题  (1)

短线端点处的不同格式会增加短线的长度，可能使得间隔较小的短线重叠在一起：

Wolfram Language code: Table[Graphics[{Dashing[{.2, .08}, 0, cap], Thickness[.1], Line[{{1, 0}, {0, 1}}]}], {cap, {None, "Round"}}]

巧妙范例  (3)

随意排列的虚线圆：

Wolfram Language code: Graphics[Table[{Hue[RandomReal[]], Dashing[RandomReal[{0, 0.07}]], Circle[RandomReal[1, {2}], RandomReal[]]}, {20}]]

用随机虚线样式画出的曲线：

Wolfram Language code: ParametricPlot[t{Cos[t], Sin[t]}, {t, 0, 50}, PlotStyle -> Directive[Thick, Dashing[RandomReal[{0, 0.05}, 100]]]]

改变从原点发出的虚射线的偏移量：

Wolfram Language code: Animate[Graphics[{Dashing[{.04, .04}, a], Table[Line[{{0, 0}, {Cos[b], Sin[b]}}], {b, 0, 2 π, π / 20}]}], {a, 0.64, 0}]
Wolfram Research (1988)，Dashing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dashing.html （更新于 2021 年）.

文本

Wolfram Research (1988)，Dashing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Dashing.html （更新于 2021 年）.

CMS

Wolfram 语言. 1988. "Dashing." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/Dashing.html.

APA

Wolfram 语言. (1988). Dashing. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Dashing.html 年

BibTeX

@misc{reference.wolfram_2026_dashing, author="Wolfram Research", title="{Dashing}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Dashing.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dashing, organization={Wolfram Research}, title={Dashing}, year={2021}, url={https://reference.wolfram.com/language/ref/Dashing.html}, note=[Accessed: 15-September-2026]}