WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DirectionalLight[col,pt]

3D曲面の彩色に使用する，色が col の点 pt から境界ボックスの中心までの平行光源を指定する三次元グラフィックス指示子である．

DirectionalLight[col,{pt1,pt2}]

pt1から pt2までのベクトルに沿って平行光源を使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
照明指定  
照明位置  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

DirectionalLight

DirectionalLight[col,pt]

3D曲面の彩色に使用する，色が col の点 pt から境界ボックスの中心までの平行光源を指定する三次元グラフィックス指示子である．

DirectionalLight[col,{pt1,pt2}]

pt1から pt2までのベクトルに沿って平行光源を使う．

詳細

  • DirectionalLightはフリー平行光源としても知られている．
  • DirectionalLightは，通常，特定の方向から均等に光線を照射することで，オブジェクトにより明るいハイライトを当てたりより暗い陰影を付けたりするのに使われる．
  • DirectionalLight[col,{pt1,pt2}]は，{pt1,pt2}で定義される方向ベクトルで色 col の平行のシミュレーション光として与えられる．
  • 光源 col の色は，RGBColor，Hue，他の任意の色指定で定義できる．
  • DirectionalLightの設定は3D曲面の拡散反射と鏡面反射に関連する色にしか影響しない．
  • {dcol,Specularity[scol]}の形式の色指定 col がある光源は，事実上，拡散反射の目的では色 dcol を，鏡面反射の目的では色 scol を持つとみなされる．
  • 拡散反射はランベルト(Lambert)の法則に従い，光が事実上曲面から全方向に均等に散乱しているものとする．
  • 鏡面反射は，Specularityの関数ページで指定されているように，光が鏡面反射方向の近くだけで効果的に散乱しているとする．
  • 光源の位置と照準点 ptiは以下のように指定できる．
  • {x,y,z}グラフィックスとともに動く明示的な座標
    Scaled[{x,y,z}]グラフィックスとともに動くスケールされた座標
    ImageScaled[{x,y,z}]最終的な描画画像と相対的に固定された座標
  • ImageScaled[{x,y,z}]の と は最終的な表示画像の境界ボックスの幅と高さの0から1までである． 座標はディスプレイの平面と直交し，3D領域の後ろでは0で前では1になる．
  • ScaledおよびImageScaledで指定された座標は，0から1までではないことがしばしばある．

例題

すべて開く すべて閉じる

例  (3)

曲面の平行光源：

Wolfram Language code: Graphics3D[{DirectionalLight[Orange, {1, 1, 1}], Sphere[], Cuboid[{1, 2, -1}, {2, 3, 1}], Cylinder[{{3, -1, 0}, {3, -1, 1}}]}, Lighting -> None]

プロット中の曲面にスタイルを付ける：

Wolfram Language code: Plot3D[Sin[x + y ^ 2], {x, -3, 3}, {y, -2, 2}, PlotStyle -> DirectionalLight[RGBColor[1, 0.7, 0.1], {{5, 5, 4}, {5, 5, 0}}]]

鏡面の天辺からの平行光源：

Wolfram Language code: ListPlot3D[RandomReal[1, {9, 9}], InterpolationOrder -> 2, Mesh -> None, PlotStyle -> {Specularity[50], DirectionalLight[RGBColor[1, 0.7, 0.1], {{5, 5, 4}, {5, 5, 0}}]}]

スコープ  (5)

照明指定  (4)

平行光源は色と2つの点によって定義されたベクトルによって指定される：

Wolfram Language code: Graphics3D[{DirectionalLight[Green, {{0, 0, 1}, {0, 0, 0}}], White, Sphere[]}, Lighting -> None]

さまざまな色の平行光源：

Wolfram Language code: Table[Graphics3D[{DirectionalLight[c, {{0, 0, 1}, {0, 0, 0}}], White, Sphere[]}, Lighting -> None], {c, {Red, Yellow, Blue}}]

さまざまな方向の平行光源：

Wolfram Language code: Table[Graphics3D[{DirectionalLight[Orange, {p, {0, 0, 0}}], Sphere[]}, Lighting -> None], {p, {{1, 0, 0}, {0, -1, 0}, {1, -1, 0}, {0, 0, 1}}}]

鏡面上の平行光源：

Wolfram Language code: Table[Graphics3D[{DirectionalLight[Orange, {p, {0, 0, 0}}], Specularity[White, 50], Sphere[]}, Lighting -> None], {p, {{1, 0, 0}, {0, -1, 0}, {1, -1, 0}, {0, 0, 1}}}]

照明位置  (1)

ImageScaledを使って視点座標系で照明の位置を指定する：

Wolfram Language code: Graphics3D[{DirectionalLight[Red, ImageScaled[{2, 2, 2}]], DirectionalLight[Green, ImageScaled[{-2, 2, 2}]], DirectionalLight[Blue, ImageScaled[{-2, -2, 2}]], Sphere[]}, Lighting -> None]

光源の位置は常に視点と相対的に固定されている：

Wolfram Language code: Table[Graphics3D[{DirectionalLight[Red, ImageScaled[{2, 2, 2}]], DirectionalLight[Green, ImageScaled[{-2, 2, 2}]], DirectionalLight[Blue, ImageScaled[{-2, -2, 2}]], Sphere[]}, Lighting -> None, ViewPoint -> v], {v, {{0, -2, 2}, {2, 0, 2}, {2, -2, 0}}}]

一般化と拡張  (8)

定義済みのカラー照明：

Wolfram Language code: Graphics3D[Sphere[], Lighting -> Automatic]

カラー照明は以下の明示的な設定と等価である：

Wolfram Language code: Graphics3D[{Sphere[], AmbientLight[RGBColor[{0.4, 0.2, 0.2}]], DirectionalLight[RGBColor[{0., 0.18, 0.5}], ImageScaled[{2, 0, 2}]], DirectionalLight[RGBColor[{0.18, 0.5, 0.18}], ImageScaled[{2, 2, 3}]], DirectionalLight[RGBColor[{0.5, 0.18, 0.}], ImageScaled[{0, 2, 2}]], DirectionalLight[RGBColor[{0., 0., 0.18}], ImageScaled[{0, 0, 2}]]}]

定義済みのアクセント照明：

Wolfram Language code: Graphics3D[{Sphere[]}, Lighting -> "Accent"]

アクセント照明は以下の明示的な設定と等価である：

Wolfram Language code: Graphics3D[{DirectionalLight[RGBColor[{1, 1, 1}], ImageScaled[{1, 1, 4}]], Sphere[]}, Lighting -> None]

定義済みのニュートラル照明：

Wolfram Language code: Graphics3D[{Sphere[]}, Lighting -> "Neutral"]

ニュートラル照明は以下の明示的な設定と等価である：

Wolfram Language code: Graphics3D[{AmbientLight[RGBColor[{.35, .35, .35}]], DirectionalLight[RGBColor[{.37, .37, .37}], ImageScaled[{2, 0, 2}]], DirectionalLight[RGBColor[{.37, .37, .37}], ImageScaled[{2, 2, 2}]], DirectionalLight[RGBColor[{.37, .37, .37}], ImageScaled[{0, 2, 2}]], Sphere[]}, Lighting -> None]

定義済みの3点照明：

Wolfram Language code: Graphics3D[{Sphere[]}, Lighting -> "ThreePoint"]

3点照明は以下の明示的な設定と等価である：

Wolfram Language code: Graphics3D[{DirectionalLight[GrayLevel[.85], ImageScaled[{1, 1, 2}]], DirectionalLight[GrayLevel[.4], ImageScaled[{-1, -2, 2}]], DirectionalLight[GrayLevel[.1], ImageScaled[{.5, 2, -2}]], Sphere[]}, Lighting -> None]

各オブジェクトの照明を指定する：

Wolfram Language code: o1 = Style[{PointLight[Red, {0, 0, 2}], Sphere[]}]; o2 = Style[{SpotLight[Yellow, {{3, 0, 2}, {3, 0, 0}}, Pi / 8], Sphere[{3, 0, 0}]}]; o3 = Style[{DirectionalLight[Blue, {{0, 3, 2}, {0, 3, 0}}], Sphere[{0, 3, 0}]}]; o4 = Style[{PointLight[White, {3, 3, 2}], Sphere[{3, 3, 0}]}];
Wolfram Language code: Graphics3D[{o1, o2, o3, o4}, Lighting -> None]

グラフィックス内の照明を指定する：

Wolfram Language code: Graphics3D[{{PointLight[Red, {0, 0, 2}], Sphere[]}, {SpotLight[Yellow, {{3, 0, 2}, {3, 0, 0}}, Pi / 8], Sphere[{3, 0, 0}]}, {DirectionalLight[Blue, {{0, 3, 2}, {0, 3, 0}}], Sphere[{0, 3, 0}]}, {PointLight[White, {3, 3, 2}], Sphere[{3, 3, 0}]}}, Lighting -> None]

ターゲットの方向は，指定されていなければオブジェクトの中心に向かって与えられる：

Wolfram Language code: Graphics3D[{DirectionalLight[LightRed, {0, 0, 4}], Specularity[White, 50], Sphere[], Sphere[{3, 0, 0}], Sphere[{0, 3, 0}], Sphere[{3, 3, 0}]}, Lighting -> None]

オブジェクトと照明の両方に，拡散反射光と鏡面反射光の色を別々に指定する：

Wolfram Language code: Graphics3D[{DirectionalLight[{Red, Specularity[Yellow]}, {0, 0, 3}], Specularity[White, 20], Sphere[]}, Lighting -> None]

アプリケーション  (3)

平面上に4つの白い球を設定する：

Wolfram Language code: obj = Graphics3D[{Specularity[White, 50], Sphere[], Sphere[{4, 0, 0}], Sphere[{0, 4, 0}], Sphere[{4, 4, 0}]}, Lighting -> None]; plane = ParametricPlot3D[{u, v, -1}, {u, -2, 6}, {v, -2, 6}, PlotPoints -> 40, MaxRecursion -> 0, Mesh -> None, PlotRange -> 1, Axes -> False];

平行光源：

Wolfram Language code: light = Graphics3D[{DirectionalLight[Yellow, {2, 2, 10}], Glow[Yellow], EdgeForm[Gray], Opacity[.2], Cuboid[{-2, -2, -1}, {6, 6, 3}]}];
Wolfram Language code: Show[light, obj, plane, Boxed -> False]

端点の異なる照明器具：

Wolfram Language code: lights = {PointSize[Large], Yellow, Point[Tuples[{-1, 1}, 3]]};
Wolfram Language code: Graphics3D[{DirectionalLight[Hue[RandomReal[]], #]& /@ Tuples[{-1, 1}, 3], lights, Sphere[]}]

複数のオブジェクトと光源があるシーンを構築する：

Wolfram Language code: col = {Red, Green, Blue}; objs = Graphics3D[{Specularity[White, 2], EdgeForm[], Cylinder[{{2, 2, 0}, {2, 2, 4}}], Cylinder[{{6, 2, 0}, {6, 2, 4}}], Cylinder[{{10, 2, 0}, {10, 2, 4}}]}]; walls = ParametricPlot3D[{{u, v - 2, 0}, {u, 4, 2v}}, {u, -2, 14}, {v, 0, 6}, PlotPoints -> 15, MaxRecursion -> 0, PlotStyle -> Specularity[White, 2], Mesh -> None, Axes -> False]; srcs[pos_] := Graphics3D[MapThread[{DirectionalLight[#1, {{0, -1, 0}, {0, 0, 0}}], Sphere[{#2, 0, 8}, .3]}&, {col, pos}]]; lights[pos_] := Join[{AmbientLight[GrayLevel[.1]]}, Sequence@@MapThread[{SpotLight[#1, {{#2, 0, 8}, {#2, 3, 0}}, {Pi / 2, 20}], {PointLight[#1, {#2, 0, 8}, {0, 8, 0}]}}&, {col, pos}]];

スポットライトを動画にする：

Wolfram Language code: Animate[With[{rx = -6Cos[t] + 6, gx = 6Sin[t] + 6, bx = 6Cos[t] + 6}, Show[objs, walls, srcs[{rx, gx, bx}], Lighting -> lights[{rx, gx, bx}], Background -> Black, Boxed -> False, ImageSize -> 300]], {t, 0, 2Pi}, SaveDefinitions -> True, AnimationRunning -> False]

特性と関係  (1)

平行光源は指定された方向と平行の光線を与える：

Wolfram Language code: Graphics3D[Table[{DirectionalLight[White, {{0, 5, 4}, {0, 0, 0}}], Sphere[{3i, 0, 0}]}, {i, 0, 4}], Lighting -> None, ViewPoint -> Top]

考えられる問題  (1)

デフォルトの照明スキームは複数のカラー光源を使う：

Wolfram Language code: Graphics3D[{DirectionalLight[Orange, {1, 1, 1}], Sphere[]}]

LightingをNoneに指定してデフォルトの照明を消す：

Wolfram Language code: Graphics3D[{DirectionalLight[Orange, {1, 1, 1}], Sphere[]}, Lighting -> None]
Wolfram Research (2021), DirectionalLight, Wolfram言語関数， https://reference.wolfram.com/language/ref/DirectionalLight.html.

テキスト

Wolfram Research (2021), DirectionalLight, Wolfram言語関数， https://reference.wolfram.com/language/ref/DirectionalLight.html.

CMS

Wolfram Language. 2021. "DirectionalLight." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DirectionalLight.html.

APA

Wolfram Language. (2021). DirectionalLight. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DirectionalLight.html

BibTeX

@misc{reference.wolfram_2026_directionallight, author="Wolfram Research", title="{DirectionalLight}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/DirectionalLight.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_directionallight, organization={Wolfram Research}, title={DirectionalLight}, year={2021}, url={https://reference.wolfram.com/language/ref/DirectionalLight.html}, note=[Accessed: 12-August-2026]}