WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiscreteDelta[n1,n2,…]

すべての niが零なら1，それ以外の場合は0であるような離散デルタ関数 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
微分と積分  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

DiscreteDelta

DiscreteDelta[n1,n2,…]

すべての niが零なら1，それ以外の場合は0であるような離散デルタ関数 を与える．

詳細

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: DiscreteDelta[1, 0]

総和で使う：

Wolfram Language code: Sum[DiscreteDelta[a - 5] f[a], {a, Infinity}]

整数の部分集合上でプロットする：

Wolfram Language code: DiscretePlot[DiscreteDelta[x], {x, -2, 2}, PlotMarkers -> {Automatic, 8}]

スコープ  (26)

数値評価  (6)

数値的に評価する：

Wolfram Language code: DiscreteDelta[0.]
Wolfram Language code: DiscreteDelta[2.5, 3.5]
Wolfram Language code: DiscreteDelta[E, Catalan, (1/2)]

複素数入力：

Wolfram Language code: DiscreteDelta[I]
Wolfram Language code: DiscreteDelta[2 - I, 2 - I]
Wolfram Language code: DiscreteDelta[2 - I, Pi - (1/4), 0.5I]

DiscreteDeltaは，入力精度とは無関係に，常に厳密な結果を返す：

Wolfram Language code: DiscreteDelta[0.12345]

高精度で効率的に評価する：

Wolfram Language code: DiscreteDelta[2, 5, 10`100]//Timing
Wolfram Language code: DiscreteDelta[0``10000]//Timing

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: DiscreteDelta[ Around[2 / 3, 0.001]]

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: DiscreteDelta[{{1, 0}, {5, 1}}]//FullSimplify

　MatrixFunctionを使って行列のDiscreteDelta関数を計算することもできる：

Wolfram Language code: MatrixFunction[DiscreteDelta, {{1, 0}, {5, 1}}]//FullSimplify

特定の値  (4)

ゼロにおける値：

Wolfram Language code: DiscreteDelta[0]

入力が0のとき，引数が複数の形は1を返す：

Wolfram Language code: DiscreteDelta[0, 0]
Wolfram Language code: DiscreteDelta[0, 0, 0]
Wolfram Language code: DiscreteDelta[0, 0, 0, 0]

無限大における値：

Wolfram Language code: DiscreteDelta[Infinity]

記号的に評価する：

Wolfram Language code: Assuming[x < 0 && y > 0, Refine[DiscreteDelta[x, x, y]]]
Wolfram Language code: PiecewiseExpand[DiscreteDelta[ x, y], -2 < x < 2]

可視化  (3)

整数幅のビンを使って1引数のDiscreteDeltaをプロットする：

Wolfram Language code: DiscretePlot[DiscreteDelta[x], {x, -2, 2}, ExtentSize -> Full]

DiscreteDeltaを実数上で可視化する．におけるジャンプを除いてゼロ関数と区別できない：

Wolfram Language code: Plot[{DiscreteDelta[x], 0}, {x, -2, 2}, PlotStyle -> {StandardBlue, StandardRed}, AxesOrigin -> {-2, -1}, PlotLegends -> "Expressions", Epilog -> {StandardBlue, PointSize[Large], Point[{0, DiscreteDelta[0]}]}]

DiscreteDeltaを三次元でプロットする：

Wolfram Language code: DiscretePlot3D[DiscreteDelta[x, y], {x, -2, 2}, {y, -2, 2}, ExtentSize -> Full, ColorFunction -> "TemperatureMap"]

関数の特性  (9)

DiscreteDeltaは実数および複素数のすべての入力について定義される：

Wolfram Language code: FunctionDomain[DiscreteDelta[x1, x2, x3], {x1, x2, x3}]
Wolfram Language code: FunctionDomain[DiscreteDelta[x1, x2, x3], {x1, x2, x3}, Complexes]

DiscreteDelta関数の値域：

Wolfram Language code: FunctionRange[DiscreteDelta[x1, x2, x3], {x1, x2, x3}, y]

複素値についての関数の値域も同じである：

Wolfram Language code: FunctionRange[DiscreteDelta[x1, x2, x3], {x1, x2, x3}, y, Complexes]

DiscreteDeltaは解析関数ではない：

Wolfram Language code: FunctionAnalytic[DiscreteDelta[x, y], {x, y}]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[DiscreteDelta[x, y], {x, y}]
Wolfram Language code: FunctionDiscontinuities[DiscreteDelta[x, y], {x, y}]

DiscreteDeltaは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[DiscreteDelta[x], x]

DiscreteDeltaは単射ではない：

Wolfram Language code: FunctionInjective[DiscreteDelta[x, y], {x, y}]

DiscreteDeltaは全射ではない：

Wolfram Language code: FunctionSurjective[DiscreteDelta[x, y], {x, y}]

DiscreteDeltaは非負である：

Wolfram Language code: FunctionSign[DiscreteDelta[x], x]

DiscreteDeltaは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[DiscreteDelta[x], x]

TraditionalFormによる表示：

Wolfram Language code: DiscreteDelta[n, m] // TraditionalForm

微分と積分  (4)

x についての一次導関数：

Wolfram Language code: D[DiscreteDelta[x, y], x]

生成点における級数展開：

Wolfram Language code: Series[DiscreteDelta[x1, x2], {x1, x0, 2}]// FullSimplify

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[DiscreteDelta[x, y], x]

不定積分を確かめる：

Wolfram Language code: FullSimplify[D[%, x]]

その他の積分例：

Wolfram Language code: Integrate[DiscreteDelta[x, y], {x, 0, 5}]
Wolfram Language code: Integrate[DiscreteDelta[x, y]DiscreteDelta[x, z], x]

アプリケーション  (4)

項を抽出するために総和で使う：

Wolfram Language code: Sum[DiscreteDelta[k ^ 2 + j - 25]f[k, j], {k, 1, Infinity}, {j, 1, Infinity}]

要素を抽出する：

Wolfram Language code: ArrayPlot[Table[DiscreteDelta[Mod[Fibonacci[2m, 3n], 5]], {n, 1, 120, 2}, {m, 60}]]

区分定義関数の点別の値を継ぎ接ぎにする：

Wolfram Language code: {ListLinePlot[Table[{x, UnitStep[x] + UnitStep[-x]}, {x, -5, 5}]], ListLinePlot[Table[{x, UnitStep[x] + UnitStep[-x] - DiscreteDelta[x]}, {x, -5, 5}]]}

有限な継続信号を定義する：

Wolfram Language code: x1[n_] := DiscreteDelta[n] - 2DiscreteDelta[n - 1] + DiscreteDelta[n - 2] x2[n_] := Piecewise[{{1, 0 <= n <= 5}}]

時間領域でこの信号をプロットする：

Wolfram Language code: DiscretePlot[{x1[n], x2[n]}, {n, 0, 5}]

これらの信号のたたみ込みを求めるために，まず変換の積を計算する：

Wolfram Language code: BilateralZTransform[x1[n], n, z]BilateralZTransform[x2[n], n, z]

次に，時間領域に戻す反転を行う：

Wolfram Language code: InverseBilateralZTransform[%, z, n]

時間領域でたたみ込みをプロットする：

Wolfram Language code: DiscretePlot[%, {n, 0, 8}]

DiscreteConvolveを使ってたたみ込みを求めることもできる：

Wolfram Language code: DiscreteConvolve[x1[k], x2[k], k, n]//Simplify

特性と関係  (3)

DiscreteDeltaを含む方程式を簡約する：

Wolfram Language code: Reduce[a - DiscreteDelta[a ^ 2 + 4, 2a - 2] == 2 && -10 < a < 10, a, Integers]

DiscreteDeltaのサポートには測度ゼロがある：

Wolfram Language code: Integrate[DiscreteDelta[x], {x, -1, 1}]

DiscreteDeltaはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[DiscreteDelta[k], k]

考えられる問題  (2)

DiscreteDeltaは，数値引数のときは未評価で残されることがある：

Wolfram Language code: DiscreteDelta[Sqrt[2 - Sqrt[2 + Sqrt[2]]] / 2 - Sin[Pi / 16]]

$MaxExtraPrecisionに設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[%, 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 1000}, DiscreteDelta[1 - Sqrt[2 - Sqrt[2 + Sqrt[2]]] / 2 + Sin[Pi / 16] + 10 ^ -100]]

引数の等価性の検査では数値精度が考慮される：

Wolfram Language code: DiscreteDelta[1, 1.00000000000001]
Wolfram Research (1999), DiscreteDelta, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteDelta.html.

テキスト

Wolfram Research (1999), DiscreteDelta, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteDelta.html.

CMS

Wolfram Language. 1999. "DiscreteDelta." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteDelta.html.

APA

Wolfram Language. (1999). DiscreteDelta. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiscreteDelta.html

BibTeX

@misc{reference.wolfram_2026_discretedelta, author="Wolfram Research", title="{DiscreteDelta}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteDelta.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretedelta, organization={Wolfram Research}, title={DiscreteDelta}, year={1999}, url={https://reference.wolfram.com/language/ref/DiscreteDelta.html}, note=[Accessed: 10-September-2026]}