WOLFRAM

Wolfram 语言与系统参考资料中心

DiscreteHilbertTransform[list]

求实数列表 list 的离散希尔伯特变换.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
通讯  
心电图频率分析  
风速预测  
地震数据分析  
属性和关系  
参见
历史
按以下格式引用：

DiscreteHilbertTransform

DiscreteHilbertTransform[list]

求实数列表 list 的离散希尔伯特变换.

更多信息

  • 离散希尔伯特变换在信号处理、通信、声学、数据压缩、地震环境数据、引力波等领域均有应用.
  • 该变换对原始序列中的正频率施加一个 的相位偏移，对负频率施加一个 的相位偏移.
  • 对于列表 ，DiscreteHilbertTransform 先计算其快速傅立叶变换（FFT），然后消除负频率分量，再对结果进行逆傅立叶变换，所得结果的虚部即为 . »
  • 在信号处理中，复数序列 被称为“解析信号”，其幅值为包络（envelope）：
  • 的长度可为任意正整数.
  • 若 的元素为精确数值，则 DiscreteHilbertTransform 会先对其应用 N 函数.
  • 也可以是 SparseArray 对象，生成的 也同样是 SparseArray 对象.

范例

打开所有单元 关闭所有单元

基本范例  (2)

求离散希尔伯特变换：

Wolfram Language code: DiscreteHilbertTransform[{1, 1, 2, 2, 1, 1, 0, 0}]

求实值信号的解析表示：

Wolfram Language code: {1, 2, 3, 4, 5, 6} + I DiscreteHilbertTransform[{1, 2, 3, 4, 5, 6}]

范围  (9)

x 是一个实值列表：

Wolfram Language code: x = {1, 0, 0, 1, 0, 0, 1};

使用机器运算计算离散希尔伯特变换：

Wolfram Language code: DiscreteHilbertTransform[x]

使用 24 位精度运算进行计算：

Wolfram Language code: DiscreteHilbertTransform[N[x, 24]]

计算二维离散希尔伯特变换：

Wolfram Language code: DiscreteHilbertTransform[RandomReal[{2, 4}, {3, 6}]]

x 是一个对角线非零的 3 阶张量：

Wolfram Language code: x = ConstantArray[0, {2, 3, 4}];x[[1, 1, 1]] = 1;x[[2, 2, 2]] = 1;

计算三维离散希尔伯特变换：

Wolfram Language code: DiscreteHilbertTransform[x]

x 是实值的 SparseArray：

Wolfram Language code: x = SparseArray[{{1, 2} -> -1, {2, 2} -> 2π, {3, 3} -> 1.3, {2, 3} -> 7}];

计算离散希尔伯特变换，并以 SparseArray 形式返回结果：

Wolfram Language code: DiscreteHilbertTransform[x]

x 是一个由实数值组成的大型稀疏矩阵：

Wolfram Language code: x = SparseArray[Table[3 ^ i -> 1, {i, 10}]];

计算离散希尔伯特变换，并以 SparseArray 形式返回结果：

Wolfram Language code: DiscreteHilbertTransform[x]

考虑一个离散余弦波：

Wolfram Language code: discreteCosine = Table[Cos[t], {t, -π, π, π / 25}];

DiscreteHilbertTransform 施加一个弧度为 的相位偏移：

Wolfram Language code: discreteHCosine = DiscreteHilbertTransform[discreteCosine];
Wolfram Language code: ListPlot[{discreteCosine, discreteHCosine}, ...]

以下是离散信号及其离散希尔伯特变换的前 10 个元素的值：

Wolfram Language code: Tabular[(Transpose[{N[discreteCosine], discreteHCosine}])[[ ;; 10]] , {...}]

生成一个随机实数序列：

Wolfram Language code: x = RandomReal[1, 200];

计算离散希尔伯特变换：

Wolfram Language code: dhtx = DiscreteHilbertTransform[x];

将原始数据及其变换一起绘制：

Wolfram Language code: ListLinePlot[{x, dhtx}, ...]

考虑一个带有噪声的正弦序列：

Wolfram Language code: x = Sin[17 * 2π * Range[0, 1, 0.001]] + RandomVariate[NormalDistribution[0, 0.05], 1001];

计算离散希尔伯特变换：

Wolfram Language code: dhtx = DiscreteHilbertTransform[x];

将原始数据及其变换一起绘制：

Wolfram Language code: ListLinePlot[{x, dhtx}, ...]

带有噪声的 Sinc 函数数据：

Wolfram Language code: n = 100; x = Table[Sinc[x - 10], {x, n}] + RandomReal[{-.05, .05}, {n}];
Wolfram Language code: ListPlot[x, PlotRange -> All]

其功率谱：

Wolfram Language code: p = Fourier[x, FourierParameters -> {1, 1}]; ListPlot[Abs[p] ^ 2]

它的离散希尔伯特变换：

Wolfram Language code: dHx = DiscreteHilbertTransform[x];

它提供了解析表示的虚部：

Wolfram Language code: a = x + I * dHx;

解析信号的功率谱：

Wolfram Language code: s = Fourier[a, FourierParameters -> {1, 1}]; ListPlot[Abs[s] ^ 2]

振荡信号的包络是勾勒其极值的曲线，它是解析表示的幅值：

Wolfram Language code: ListLinePlot[{x, dHx, Abs /@ a}, ...]

应用  (4)

通讯  (1)

考虑以下消息信号：

Wolfram Language code: m = Table[Sin[2Pi 5t] + 2Sin[2Pi 7t] + 1 / 2Sin[2Pi 9t], {t, -π / 2, π / 2, π / 100}]; ListLinePlot[m, DataRange -> {-π / 2, π / 2}, ...]

以 作为消息载波，获取上边带抑制载波 (USB-SC) 和下边带抑制载波 (LSB-SC)：

Wolfram Language code: c = Table[Cos[2Pi 55t], {t, -π / 2, π / 2, π / 100}]; s = Table[Sin[2Pi 55t], {t, -π / 2, π / 2, π / 100}]; USB = m * c - DiscreteHilbertTransform[m] * s; LSB = m * c + DiscreteHilbertTransform[m] * s; ListLinePlot[{USB, LSB}, ...]

心电图频率分析  (1)

心电图（ECG）的时频分析能够揭示重要的生理信息。以某患者的心电图数据为例，该数据记录了心脏电活动随时间变化的电压曲线：

Wolfram Language code: ECGData = {...}; ListLinePlot[ECGData, ...]

使用 KaiserWindow 对数据进行滤波处理：

Wolfram Language code: filteredECG = BandpassFilter[ECGData, {(4π/25), (2π/5)}, Length[ECGData], KaiserWindow];

在离散域（采样频率为100Hz）中计算其一阶差分：

Wolfram Language code: differentialECG = Differences[filteredECG] / (2 * .01);

离散希尔伯特变换为：

Wolfram Language code: dhDifferentialECG = DiscreteHilbertTransform[differentialECG];

比较离散希尔伯特变换的均方根值与其最大值的18%：

Wolfram Language code: {Max[dhDifferentialECG] * .18, RootMeanSquare[dhDifferentialECG]}

这将设定最大值的 39% 作为一个阈值；基于此信息，您可以通过一阶差分的希尔伯特变换定位 R 峰的位置：

Wolfram Language code: RpeaksLocation = First /@ FindPeaks[dhDifferentialECG, Automatic, Automatic, Max[dhDifferentialECG] * .39];

在心电图数据中可视化 R 波峰：

Wolfram Language code: RPeaks = Transpose@{RpeaksLocation, ECGData[[RpeaksLocation]]}; ListPlot[{ECGData, RPeaks}, ...]

风速预测  (1)

考虑哥伦比亚麦德林市未来七天的风速与风向天气预报：

Wolfram Language code: speedDateData = QuantityMagnitude[WeatherForecastData[...]]; directionDateData = (π/180)QuantityMagnitude[WeatherForecastData[...]]; DateListPlot[{speedDateData, directionDateData}, ...]

预测风速由公式 给出，其中 是风速数据的最大值， 和 分别是序列 和风向数据的平均值. 和 分别为这两个序列去除均值后的离散希尔伯特变换：

Wolfram Language code: {...}; DateListPlot[{...}, ...]

地震数据分析  (1)

考虑以下地震波形，它展示了由地震波引起的地面运动随时间被检测和记录的过程：

Wolfram Language code: trace = {...}; ListLinePlot[trace]

计算其希尔伯特变换：

Wolfram Language code: dhTrace = DiscreteHilbertTransform[trace];

获取复信号：

Wolfram Language code: complexTrace = trace + I * dhTrace;

及其包络：

Wolfram Language code: env = Abs[complexTrace];

绘制信号、其变换及包络：

Wolfram Language code: ListLinePlot[{trace, dhTrace, env, -env}, ...]

瞬时相位：

Wolfram Language code: phase = ArcTan[trace, dhTrace]; ListLinePlot[phase, PlotLabel -> "Instantaneous phase for the complex trace"]

属性和关系  (2)

对于列表 ：

Wolfram Language code: Subscript[f, k] = {1.1, -1.2, 5.5, -4.5};

计算其快速傅立叶变换：

Wolfram Language code: fFourier = Fourier[Subscript[f, k], FourierParameters -> {1, -1}]

消除负频率：

Wolfram Language code: anhilation = {1, 2, 1, 0} * fFourier

计算逆快速傅立叶变换：

Wolfram Language code: InverseFourier[anhilation, FourierParameters -> {1, -1}]

最后，将虚部与 DiscreteHilbertTransform 的结果进行比较：

Wolfram Language code: Im[%] == DiscreteHilbertTransform[Subscript[f, k]]

对于实值信号的解析表示：

Wolfram Language code: {-2.3, -3.14, 1.62, E, Pi} + I DiscreteHilbertTransform[{-2.3, -3.14, 1.62, E, Pi}]

直流分量（第一位置）和奈奎斯特分量（TemplateBox[{{n, /, 2}}, Ceiling] 位置）始终为实数：

Wolfram Language code: Fourier[%, FourierParameters -> {1, -1}]//Chop
Wolfram Research (2026)，DiscreteHilbertTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html.

文本

Wolfram Research (2026)，DiscreteHilbertTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html.

CMS

Wolfram 语言. 2026. "DiscreteHilbertTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html.

APA

Wolfram 语言. (2026). DiscreteHilbertTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html 年

BibTeX

@misc{reference.wolfram_2026_discretehilberttransform, author="Wolfram Research", title="{DiscreteHilbertTransform}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretehilberttransform, organization={Wolfram Research}, title={DiscreteHilbertTransform}, year={2026}, url={https://reference.wolfram.com/language/ref/DiscreteHilbertTransform.html}, note=[Accessed: 07-September-2026]}