WOLFRAM

Wolfram 语言与系统参考资料中心

DiscreteInputOutputModel[{g0,g1,…,gn-1},u]

表示在采样时刻 i 输入为 u 和输出为 的离散时间模型.

DiscreteInputOutputModel[{g0,g1,…,gn-1},u,y]

可用于指定还依赖于输出变量 y 的输出 .

DiscreteInputOutputModel[…,{{u1,{…,u10}},…},{{y1,{…,y10}},…}]

指定每个信号在时刻 k<=0 时的输入和输出值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
TransferFunctionModel  
ModelPredictiveController  
属性  
选项  
MissingDataMethod  
ResamplingMethod  
SamplingPeriod  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

DiscreteInputOutputModel

DiscreteInputOutputModel[{g0,g1,…,gn-1},u]

表示在采样时刻 i 输入为 u 和输出为 的离散时间模型.

DiscreteInputOutputModel[{g0,g1,…,gn-1},u,y]

可用于指定还依赖于输出变量 y 的输出 .

DiscreteInputOutputModel[…,{{u1,{…,u10}},…},{{y1,{…,y10}},…}]

指定每个信号在时刻 k<=0 时的输入和输出值.

更多信息和选项

  • DiscreteInputOutputModel 表示一个系统，在定期采样时刻的输出是系统输入和先前输出的函数.
  • DiscreteInputOutputModel 可用于表示输入-输出形式的离散时间系统，包括离散时间 TransferFunctionModel 对象. 通常用于表示 ModelPredictiveController 中计算的 MPC 控制器.
  • 输入-输出模型表示过去的输入和输出组成的长度为 m 的移动窗口， ，其中 .
  • 对于 k=n,…，方程则被周期性地扩展为 ，p=TemplateBox[{k, n}, Mod].
  • 默认情况下， 时的输入 和输出 被视为 .
  • 对于模型预测控制，经常使用两种简单的情况：
  • 状态反馈控制器
    状态准反馈控制器
  • 默认情况下，假定采样实例之间的值是恒定的. 实际上是一个插值阶数为 0 的零阶保持 (ZOH).
  • 可用 DiscreteInputOutputModel[{{k0,g0},…,{kn-1,gn-1}},…] 明确指定整数采样实例 ki 和输出 .
  • 时间 ti 与采样时刻 ki 之间的关系为 ti=τ ki，其中 τ 是采样周期，用 DiscreteInputOutputModel[…, SamplingPeriodτ] 指定.
  • DiscreteInputOutputModel["prop"] 可用于计算属性.
  • 与输出规范 {ki,gi} 相关的属性：
  • "FirstInstant"第一时刻 Min[{k0,k1,…}]
    "FirstValue"第一时刻上的值
    "Instants"采样时刻 Sort[{k0,k1,…}]
    "LastInstant"最后时刻 Max[{k0,k1,…}]
    "LastValue"最后时刻上的值
    "Path"“时刻-值”数据对 {{k0,g0},…}
    "PathComponent"第一个路径分量
    "PathComponents"所有路径都拆分为单变量分量
    "PathFunction"插值路径函数
    "PathLength"路径的长度 ("Horizon")
    "Values"输出的值 {g0,g1,…}
  • 基本的模型属性：
  • "InputsCount"输入的数量
    "InputVariables"输入变量 u
    "OutputsCount"输出的数量
    "OutputVariables"输出变量 y
    "Type"输入-输出关系的类型
    "SamplingPeriod"采样周期 sp
  • 时间序列的属性：
  • "FirstTime"对应于第一时刻的时间
    "LastTime"对应于最后时刻的时间
    "TemporalData"多路径 TemporalData 对象
    "TimePath"“时刻-值”数据对 {{t0,g0},…}
    "Times"对应于采样时刻的时间
    "TimeSeries"TimeSeries 对象
    "TimeValues"采样时的输出值
  • DiscreteInputOutputModel 接受以下选项：
  • MissingDataMethod None处理缺失值的方法
    ResamplingMethod {"Interpolation", InterpolationOrder0}用于重采样路径的方法
    SamplingPeriod Automatic采样周期

范例

打开所有单元 关闭所有单元

基本范例  (3)

一个输出只依赖于输入的模型：

Wolfram Language code: DiscreteInputOutputModel[{u[0], (u[0] + u[1]) / 2, (u[0] + u[1] + u[2]) / 3}, u]

对随机输入序列的响应：

Wolfram Language code: ListStepPlot[OutputResponse[%, RandomInteger[{-5, 5}, 50]]]

输出依赖于输入和输出的模型：

Wolfram Language code: DiscreteInputOutputModel[{u[0], u[1] - y[0], u[2] - y[1]}, u, y]

对正弦输入的响应：

Wolfram Language code: ListStepPlot[OutputResponse[%, Table[Sin[t], {t, 0, 4π, 0.1}]]]

具有非零初始条件的模型：

Wolfram Language code: DiscreteInputOutputModel[{u[0] + y[-1] + y[-2], u[1] + u[0] + u[-1]}, {{u, {-2, -1, 1}}}, {{y, {-1, -1, -1}}}]

对类似斜坡的输入序列的响应：

Wolfram Language code: or = OutputResponse[%, Range[-20, 20]]; ListStepPlot[or, DataRange -> {0, 40}]

对于零初始条件的响应是不同的：

Wolfram Language code: DiscreteInputOutputModel[{u[0] + y[-1] + y[-2], u[1] + u[0] + u[-1]}, u, y]; OutputResponse[%, Range[-20, 20]] == or

范围  (30)

基本用法  (8)

输出为当前输入值的系统：

Wolfram Language code: diom = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u]

它的输出与输入相同：

Wolfram Language code: OutputResponse[diom, {a, b, c}]

对于较长的输入序列，在假设周期性的情况下计算输出：

Wolfram Language code: OutputResponse[diom, {a, b, c, d, e}]

输出是之前和当前输入的平均值的系统：

Wolfram Language code: diom = DiscreteInputOutputModel[{(u[-1] + u[0]) / 2}, u]
Wolfram Language code: OutputResponse[diom, {a, b, c, d, e}]

输出是之前的输出和当前输入的平均值的系统：

Wolfram Language code: diom = DiscreteInputOutputModel[{(y[-1] + u[0]) / 2}, u, y]
Wolfram Language code: OutputResponse[diom, {a, b, c, d, e}]

计算移动最大值的系统：

Wolfram Language code: diom = DiscreteInputOutputModel[{Max[y[-1], u[0]]}, u, y]
Wolfram Language code: inp = RandomInteger[{-20, 20}, 20]; OutputResponse[diom, inp]

用 FoldList 获取同样的结果：

Wolfram Language code: Rest[FoldList[Max, 0, inp]]

计算移动最大值和最小值的多输出系统：

Wolfram Language code: diom = DiscreteInputOutputModel[{{Max[y1[-1], u[0]], Min[y2[-1], u[0]]}}, u, {y1, y2}]
Wolfram Language code: inp = RandomInteger[{-20, 20}, 20]; OutputResponse[diom, inp]

用 FoldList 获取同样的结果：

Wolfram Language code: {Rest[FoldList[Max, 0, inp]], Rest[FoldList[Min, 0, inp]]}

指定非零初始值：

Wolfram Language code: diom = DiscreteInputOutputModel[{{Max[y1[-1], u[0]], Min[y2[-1], u[0]]}}, u, {{y1, {-20, -20}}, {y2, {20, 20}}}]

对一组负输入的响应：

Wolfram Language code: inp1 = RandomInteger[{-20, -10}, 5]; OutputResponse[diom, inp1]

对一组正输入的响应：

Wolfram Language code: inp2 = RandomInteger[{10, 20}, 5]; OutputResponse[diom, inp2]

默认值为零的模型：

Wolfram Language code: diomD = DiscreteInputOutputModel[{{Max[y1[-1], u[0]], Min[y2[-1], u[0]]}}, u, {y1, y2}]

对于负输入，最大值错误地始终为 0：

Wolfram Language code: OutputResponse[diomD, inp1]

对于正输入，最小值总是错误地为 0：

Wolfram Language code: OutputResponse[diomD, inp2]

周期为 3 的双输出系统：

Wolfram Language code: DiscreteInputOutputModel[{{u[0], u[0]}, {u[0] - u[1], u[0] + u[1]}, {u[0] - u[1] - u[2], u[0] + u[1] + u[2]}}, u]

对斜坡输入的响应：

Wolfram Language code: ListLinePlot[OutputResponse[%, {Range[-50, 50]}], DataRange -> {-20, 20}]

具有一系列分段输出的系统：

Wolfram Language code: DiscreteInputOutputModel[{Piecewise[{{1, u[0] > 0}, {-1, u[0] <= 0}}], Piecewise[{{1, u[1] > 1}, {-1, u[1] <= 1}}], Piecewise[{{1, u[2] > 2}, {-1, u[2] <= 2}}], Piecewise[{{1, u[3] > 3}, {-1, u[3] <= 3}}]}, u]

对随机输入的响应：

Wolfram Language code: ListStepPlot[OutputResponse[%, RandomReal[{-5, 5}, 50]]]

TransferFunctionModel  (4)

单入单出 (SISO) 系统的 TransferFunctionModel：

Wolfram Language code: tfm = TransferFunctionModel[(z^-1/0.1 z^-1 + 1), z^-1, SamplingPeriod -> 1]

等价的 DiscreteInputOutputModel：

Wolfram Language code: diom = DiscreteInputOutputModel[{ u[-1] - 0.1 y[-1]}, u, y ]

响应是一样的：

Wolfram Language code: inp = Table[Sin[t], {t, 0, 2 π, 0.1}]; GraphicsRow[Table[ListStepPlot[OutputResponse[sys, inp], DataRange -> {0, 2π}], {sys, {tfm, diom}}]]

多入单出 (MISO) 系统的 TransferFunctionModel：

Wolfram Language code: tfm = TransferFunctionModel[{{(z^-1/0.1 z^-1 + 1), (1/0.2 z^-1 + 1)}}, z^-1, SamplingPeriod -> 1]

等价的 DiscreteInputOutputModel：

Wolfram Language code: diom = DiscreteInputOutputModel[{0.2 Subscript[u, 1][-2] + Subscript[u, 1][-1] + 0.1 Subscript[u, 2][-1] + Subscript[u, 2][0] - 0.02 y[-2] - 0.3 y[-1]}, {Subscript[u, 1], Subscript[u, 2]}, y]

响应是一样的：

Wolfram Language code: inp = Table[{Sin[t], Cos[t]}, {t, 0, 2 π, 0.1}]; GraphicsRow[Table[ListStepPlot[OutputResponse[sys, inp], DataRange -> {0, 2π}], {sys, {tfm, diom}}]]

单入多出 (SIMO) 系统的 TransferFunctionModel：

Wolfram Language code: tfm = TransferFunctionModel[{{(z^-1/0.1 z^-1 + 1)}, {(1/0.2 z^-1 + 1)}}, z^-1, SamplingPeriod -> 1]

等价的 DiscreteInputOutputModel：

Wolfram Language code: diom = DiscreteInputOutputModel[{{ u[-1] - 0.1 Subscript[y, 1][-1], u[0] - 0.2 Subscript[y, 2][-1]}}, u, {Subscript[y, 1], Subscript[y, 2]}]

响应是一样的：

Wolfram Language code: inp = Table[Sin[t], {t, 0, 2 π, 0.1}]; GraphicsRow[Table[ListStepPlot[OutputResponse[sys, inp], DataRange -> {0, 2π}], {sys, {tfm, diom}}]]

多入多出 (MIMO) 系统的 TransferFunctionModel：

Wolfram Language code: tfm = TransferFunctionModel[{{(z^-1/0.1 z^-1 + 1), (2 z^-1/0.1 z^-1 + 1)}, {(1/0.2 z^-1 + 1), (z^-1/0.2 z^-1 + 1)}}, z^-1, SamplingPeriod -> 1]

等价的 DiscreteInputOutputModel：

Wolfram Language code: diom = DiscreteInputOutputModel[{{Subscript[u, 1][-1] + 2 Subscript[u, 2][-1] - 0.1 Subscript[y, 1][-1], Subscript[u, 1][0] + Subscript[u, 2][-1] - 0.2 Subscript[y, 2][-1]}}, {Subscript[u, 1], Subscript[u, 2]}, {Subscript[y, 1], Subscript[y, 2]}]

响应是一样的：

Wolfram Language code: inp = Table[{Sin[t], Cos[t]}, {t, 0, 2 π, 0.1}];GraphicsRow[Table[ListStepPlot[OutputResponse[sys, inp], DataRange -> {0, 2π}], {sys, {tfm, diom}}]]

ModelPredictiveController  (2)

ModelPredictiveController 的反馈增益模型：

Wolfram Language code: ssm = StateSpaceModel[{{{1, 1}, {0, 1}}, {{0}, {1}}}, {x1, x2}, u, SamplingPeriod -> 1];
Wolfram Language code: cost = <|"Horizon" -> 3, "StateWeight" -> {{1, 0}, {0, 1}}, "InputWeight" -> {{0.1}}|>;
Wolfram Language code: cons = {-1 ≤ x1 ≤ 1, -3 ≤ x2 ≤ 3, -1 ≤ u ≤ 1};
Wolfram Language code: fgm = ModelPredictiveController[ssm, cost, cons, "FeedbackGainsModel"]

反馈增益是状态的一系列分段函数：

Wolfram Language code: TabView[Table[i -> fgm[i], {i, 0, 2}]]

准反馈增益模型也是一个 DiscreteInputOutputModel：

Wolfram Language code: olgm = ModelPredictiveController[ssm, cost, cons, "QuasiFeedbackGainsModel"]

它是时间 0 处状态的一系列分段函数：

Wolfram Language code: TabView[Table[i -> olgm[i], {i, 0, 2}]]

多输入 ModelPredictiveController 的反馈增益模型：

Wolfram Language code: ssm = StateSpaceModel[{{{1, 1}, {0, 1}}, {{0, 1}, {1, 1}}}, {x1, x2}, {u1, u2}, SamplingPeriod -> 1];
Wolfram Language code: cost = <|"Horizon" -> 3, "StateWeight" -> DiagonalMatrix[{1, 1}], "InputWeight" -> DiagonalMatrix[{0.1, 0.2}]|>;
Wolfram Language code: cons = {-2 ≤ x1 ≤ 2, -4 ≤ x2 ≤ 4, -1 ≤ u1 ≤ 1, -1 ≤ u2 ≤ 1};
Wolfram Language code: fgm = ModelPredictiveController[ssm, cost, cons, "FeedbackGainsModel"]

分段函数的值的长度为 2，对应于两个输入：

Wolfram Language code: TabView[Table[i -> Pane[fgm[i], {500, 500}, Scrollbars -> {False, True}], {i, 0, 2}]]

属性  (16)

获取模型中的所有值：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["Values"]

第一个值：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["FirstValue"]

最后一个值：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["LastValue"]

特定时刻的值：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][1]

所有时刻：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["Instants"]

第一时刻：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["FirstInstant"]

最后时刻：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["LastInstant"]

“时刻-值”数据对列表：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["Path"]

将多变量路径拆分为单变量分量：

Wolfram Language code: pc = DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["PathComponents"]

第一个分量的路径：

Wolfram Language code: pc[[1]]["Path"]

第二个分量的路径：

Wolfram Language code: pc[[2]]["Path"]

"PathComponent" 给出第一个分量：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["PathComponent"] %["Path"]

获取第二个分量：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][{"PathComponent", 2}] %["Path"]

获取几个分量：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][{"PathComponent", {1, 2}}] %["Path"]

插值路径函数：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["PathFunction"]

路径的长度：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["PathLength"]

基本的模型属性：

Wolfram Language code: props = {"InputVariables", "InputsCount", "OutputVariables", "OutputsCount", "Type", "StatesCount", "SamplingPeriod"};
Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][props]; Dataset[Thread[{props, %}], Alignment -> Left]

用时间指定的属性：

Wolfram Language code: props = {"TimeValues", "Times", "FirstTime", "LastTime", "TimePath", "TimeSeries", "TemporalData"};
Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][props]; Grid[Thread[{props, %}], IconizedObject[«gridOpts»]]

以列表的形式获取多个属性：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}][{"Values", "TimeValues"}]

以 Association 的形式获取所有属性：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["PropertyAssociation"]

以 Dataset 的形式获取所有属性：

Wolfram Language code: DiscreteInputOutputModel[Association["SampledSeries" -> TemporalData[TimeSeries, {{{{u[-1] + u[0] + Subscript[y, 1][-1], u[-2] + Subscript[y, 2][-2]}, {u[1] + Subscript[y, 1][-2], u[0] + u[1] + Subscript[y, 2][0]}, {u[2], u[2] ... "LastValue", "OutputsCount", "OutputVariables", "Path", "PathComponent", "PathComponents", "PathFunction", "PathLength", "SamplingPeriod", "StatesCount", "TemporalData", "TimePath", "Times", "TimeSeries", "TimeValues", "Type", "Values"}]["Dataset"]

选项  (3)

MissingDataMethod  (1)

指定如何处理缺失值：

Wolfram Language code: diom = DiscreteInputOutputModel[{u[0], u[1] + u[0], Missing[], u[3] + u[2]}, u, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}]
Wolfram Language code: diom[2]//Simplify

ResamplingMethod  (1)

默认重采样方法的插值阶数为 0：

Wolfram Language code: diom1 = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u]
Wolfram Language code: {diom1[1], diom1[1.5]}

指定插值阶数为 1：

Wolfram Language code: diom2 = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}]

插值阶数为 1 时的值：

Wolfram Language code: {diom2[1], diom2[1.5]}//Simplify

SamplingPeriod  (1)

默认采样周期为 1：

Wolfram Language code: diom1 = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u]

由于采样时刻和时间重合，"Path" 和 "TimePath" 给出相同的结果：

Wolfram Language code: diom1["Path"]
Wolfram Language code: diom1["TimePath"]

"TimePath" 也可以从 "TimeSeries" 的 "Path" 中获得：

Wolfram Language code: diom1["TimeSeries"]["Path"]

采样周期为 2 的系统：

Wolfram Language code: diom2 = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u, SamplingPeriod -> 2]

"Path" 是用采样时刻表示的，而 "TimePath" 是用时间值表示的：

Wolfram Language code: diom2["Path"]
Wolfram Language code: diom2["TimePath"] diom2["TimeSeries"]["Path"]

应用  (3)

计算一个低通 FIR 内核：

Wolfram Language code: ker = LeastSquaresFilterKernel[{"Lowpass", 1}, 10]

将其组合为 DiscreteInputOutputModel：

Wolfram Language code: diom = DiscreteInputOutputModel[{ker.Table[u[i], {i, -9, 0}]}, u]

计算它对有噪声的正弦曲线的响应：

Wolfram Language code: inp = Table[Sin[t] + Sin [15t], {t, 0, 2 π, 0.1}]; or1 = OutputResponse[diom, inp][[1]];
Wolfram Language code: ListStepPlot[{inp, or1}, DataRange -> {0, 2π}]

可用 ListConvolve 获得相同的结果：

Wolfram Language code: or2 = ListConvolve[ker, inp, 1, 0]; ListStepPlot[{inp, or2}, DataRange -> {0, 2π}]

这两个响应其实是一样的：

Wolfram Language code: AllTrue[Chop[or1 - or2], # == 0.&]

计算 IIR 滤波器的离散近似：

Wolfram Language code: bfm = ButterworthFilterModel[2]; ToDiscreteTimeModel[%, 0.1]//TransferFunctionExpand

将其组合为 DiscreteInputOutputModel:

Wolfram Language code: diom = DiscreteInputOutputModel[{0.01 u[0] + 0.02 u[-1] + 0.01 u[-2] + 7.978 y[-1] - 3.72716 y[-2]} / 4.2928, u, y]

计算它对有噪声的正弦曲线的响应：

Wolfram Language code: inp = Sin[0.5 t] + Sin[10 t];p1 = ListStepPlot[OutputResponse[diom, Table[inp, {t, 0, 25, 0.1}]], DataRange -> {0, 25}, PlotStyle -> RGBColor[0.880722, 0.611041, 0.142051]];Legended[Show[Plot[inp, {t, 0, 25}, PlotStyle -> RGBColor[0.368417, 0.506779, 0.709798]], p1], LineLegend[{RGBColor[0.368417, 0.506779, 0.709798], RGBColor[0.880722, 0.611041, 0.142051]}, {"noisy input", "diom response"}]]

类似的 TransferFunctionModel 表示给出几乎相同的响应：

Wolfram Language code: Legended[Show[p1, Plot[OutputResponse[bfm, inp, {t, 0, 25}], {t, 0, 25}, PlotStyle -> RGBColor[0.560181, 0.691569, 0.194885]]], LineLegend[{RGBColor[0.880722, 0.611041, 0.142051], RGBColor[0.560181, 0.691569, 0.194885]}, {"diom response", "bfm response"}]]

计算 MPC 设计的反馈增益模型和闭环系统：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1.}, {-5., -4.5}}, {{0}, {1.}}, {{0., 5.}}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, {u}, SamplingPeriod -> 1, SystemsModelLabels -> None];
Wolfram Language code: cost = <|"Horizon" -> 3, "StateWeight" -> IdentityMatrix[2], "InputWeight" -> {{1}}|>;
Wolfram Language code: cons = -2{Subscript[x, 1], Subscript[x, 2], u}2;
Wolfram Language code: {fgm, csys} = ModelPredictiveController[ssm, cost, cons, {"FeedbackGainsModel", "ClosedLoopSystem"}]

反馈增益模型是离散输入-输出模型，是闭环系统的一部分：

Wolfram Language code: csys[[1]]

对闭环系统进行仿真：

Wolfram Language code: or = OutputResponse[csys, PadRight[{0, 0.05, -0.05}, 30]]; ListStepPlot[or, PlotRange -> All]

属性和关系  (4)

形成一个卷积：

Wolfram Language code: OutputResponse[DiscreteInputOutputModel[{Subscript[c, -1] u[-1] + Subscript[c, 1] u[0]}, u], Array[a, 5]][[1]]

ListConvolve 给出相同的结果：

Wolfram Language code: ListConvolve[{Subscript[c, 1], Subscript[c, -1]}, Array[a, 5], 1, 0]
Wolfram Language code: % == %%

一个线性递归方程：

Wolfram Language code: Array[α, 3].Reverse[Array[y, 3, -2]] == Array[β, 3].Reverse[Array[u, 3, -2]]

用 DiscreteInputOutputModel 表示：

Wolfram Language code: y[0] /. Solve[%, y[0]] diom = DiscreteInputOutputModel[%, u, y]

对输入序列的响应：

Wolfram Language code: or = OutputResponse[%, Array[γ, 4]][[1]]//Simplify

RecurrenceFilter 给出同样的响应：

Wolfram Language code: RecurrenceFilter[{Array[α, 3], Array[β, 3]}, Array[γ, 4]] == or//Simplify

带有离散 TransferFunctionModel 表示的过程：

Wolfram Language code: tfm = TransferFunctionModel[MAProcess[{a, b, c}, σ^2], z]

还有一个 DiscreteInputOutputModel 表示：

Wolfram Language code: diom = DiscreteInputOutputModel[{{1, a, b, c}.Table[u[i], {i, 0, -3, -1}]}, u]

响应是相同的：

Wolfram Language code: OutputResponse[tfm, Array[r, 4]] OutputResponse[diom, Array[r, 4]] % == %%

如果没有输入和输出变量，DiscreteInputOutputModel 实际上是一个 TimeSeries：

Wolfram Language code: diom = DiscreteInputOutputModel[Range[0, 4], {}, {}] %["Path"]

等价的 TimeSeries 对象：

Wolfram Language code: TimeSeries[Table[{i, {i}}, {i, 0, 4}]]

路径：

Wolfram Language code: %["Path"]

用属性获取时间序列：

Wolfram Language code: diom["TimeSeries"]

具有相同的路径：

Wolfram Language code: %["Path"]

也可以直接获取时间路径：

Wolfram Language code: diom["TimePath"]

可能存在的问题  (2)

获取时间序列有可能会将规范从采样时刻改为时间戳：

Wolfram Language code: diom = DiscreteInputOutputModel[{u[0], u[1], u[2]}, u, SamplingPeriod -> 0.1]

采样时刻 1 的值：

Wolfram Language code: diom[1]

计算等价的时间序列：

Wolfram Language code: ts = diom["TimeSeries"]

时间序列不是以采样时刻给出的：

Wolfram Language code: ts[1]

使用等价的时间戳：

Wolfram Language code: ts[1 0.1]

时间序列路径：

Wolfram Language code: ts["Path"]

原始模型的时间序列路径是相同的：

Wolfram Language code: diom["TimePath"]

但是，原始模型的路径是是以采样时刻给出的：

Wolfram Language code: diom["Path"]

不将初始值 和 用于计算系统的响应：

Wolfram Language code: DiscreteInputOutputModel[{u[0] + y[-2], u[1] + y[0] + u[-1]}, {{u, {-2, -1, 1}}}, {{y, {-1, -1, -1}}}]; OutputResponse[%, Range[7]]
Wolfram Language code: DiscreteInputOutputModel[{u[0] + y[-2], u[1] + y[0] + u[-1]}, {{u, {-2, -1, Missing[]}}}, {{y, {-1, -1, Missing[]}}}]; OutputResponse[%, Range[7]]
Wolfram Research (2022)，DiscreteInputOutputModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html.

文本

Wolfram Research (2022)，DiscreteInputOutputModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html.

CMS

Wolfram 语言. 2022. "DiscreteInputOutputModel." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html.

APA

Wolfram 语言. (2022). DiscreteInputOutputModel. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html 年

BibTeX

@misc{reference.wolfram_2026_discreteinputoutputmodel, author="Wolfram Research", title="{DiscreteInputOutputModel}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discreteinputoutputmodel, organization={Wolfram Research}, title={DiscreteInputOutputModel}, year={2022}, url={https://reference.wolfram.com/language/ref/DiscreteInputOutputModel.html}, note=[Accessed: 14-September-2026]}