WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DistributeDefinitions[s1,s2,…]

シンボル siのすべての定義をすべての並列カーネルに配布する．

DistributeDefinitions["context`"]

指定のコンテキスト内のすべてのシンボルの定義を配布する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DistributeDefinitions

DistributeDefinitions[s1,s2,…]

シンボル siのすべての定義をすべての並列カーネルに配布する．

DistributeDefinitions["context`"]

指定のコンテキスト内のすべてのシンボルの定義を配布する．

詳細とオプション

  • DistributeDefinitionsは，事実上，自身の値だけでなく下向きの値，上向きの値，その他のタイプの値を含む記号 siの値と属性のすべての割当てにParallelEvaluateを適用する．
  • DistributeDefinitionsは記号 siの定義に現れる任意の記号に繰り返し適用される．
  • DistributeDefinitionsにはHoldAllという属性がある．
  • DistributeDefinitionsは，事実上，記号 siの定義を「登録」し，起動されたすべての新規並列カーネルに自動的に配布されるようにする．
  • 任意の式 expr についてのDistributeDefinitions[expr]は expr 中のすべての記号の定義を配布する．
  • 次は，使用可能なオプションである．
  • DistributedContexts$DistributedContexts配布が考慮されるシンボルのコンテキスト
    ProgressReporting$ProgressReporting計算の進捗状況を報告するかどうか
  • DistributedContextsオプションで与えられるコンテキストにコンテキストがリストされているシンボルだけが，定義の配布対象となる．
  • ProgressReportingオプションは，定義配布の進捗状況を報告するかどうかを指定する．
  • DistributeDefinitionsは，実際に配布されたシンボルのリストをHoldFormで包み込んで返す．定義が変わっていないシンボルは含まれない．

例題

すべて開く すべて閉じる

例  (2)

並列サブカーネルが起動されたことを確認する：

Wolfram Language code: LaunchKernels[];$KernelCount

サブカーネルで使われる値をまず配布する必要がある：

Wolfram Language code: ctx`y = 42;
Wolfram Language code: ParallelEvaluate[ToString[ctx`y]]
Wolfram Language code: $DistributedDefinitions
Wolfram Language code: DistributeDefinitions[ctx`y]
Wolfram Language code: ParallelEvaluate[ToString[ctx`y]]
Wolfram Language code: $DistributedDefinitions

デフォルトコンテキストのシンボルは自動的に配布される：

Wolfram Language code: y = 43;
Wolfram Language code: ParallelEvaluate[ToString[y]]
Wolfram Language code: $DistributedDefinitions

スコープ  (5)

変数の値：

Wolfram Language code: ni = 5;nd := $KernelID DistributeDefinitions[ni, nd]
Wolfram Language code: ParallelEvaluate[{ni, nd}]

関数：

Wolfram Language code: nfactors[n_] := Total[FactorInteger[(10 ^ n - 1/9)][[All, 2]]] DistributeDefinitions[nfactors]
Wolfram Language code: ParallelMap[nfactors, Range[50, 70]]

上向きの値：

Wolfram Language code: g/:f[g[x_]] := fg[x, $KernelID] DistributeDefinitions[g]
Wolfram Language code: ParallelMap[f, {g[1], h[2], g[3]}]

属性：

Wolfram Language code: np = 5;Protect[np] DistributeDefinitions[np]
Wolfram Language code: ParallelEvaluate[np = $KernelID, First[Kernels[]]]

現行コンテキストのすべての記号の定義を配布する：

Wolfram Language code: f[x_] := N[Pi ^ x, $prec];$prec = 50;
Wolfram Language code: DistributeDefinitions[Evaluate[Context[]]];
Wolfram Language code: ParallelEvaluate[f[$KernelID]]

一般化と拡張  (1)

配布された定義が依存する補助定義も自動的に配布される：

Wolfram Language code: prec = 18; mtest[n_] := Timing[Inverse[RandomReal[{-1, 1}, {n, n}, WorkingPrecision -> prec]]][[1]]
Wolfram Language code: DistributeDefinitions[mtest]
Wolfram Language code: ParallelTable[mtest[i], {i, 10, 100, 10}]

特性と関係  (7)

DistributeDefinitionsはそれまでの値や存在する属性をすべて上書きする：

Wolfram Language code: ParallelEvaluate[f[0] = "Zero";f[x_] := x ^ 2, DistributedContexts -> None];
Wolfram Language code: ParallelMap[f, {0, 1, 2, 3, 4}, DistributedContexts -> None]
Wolfram Language code: f[x_] := x ^ 2 DistributeDefinitions[f]
Wolfram Language code: ParallelMap[f, {0, 1, 2, 3, 4}, DistributedContexts -> None]

関数をクリアし，それを再配布することで，配布された定義を取り除く：

Wolfram Language code: f[x_] := Labeled[Framed[x ^ 2], $KernelID] DistributeDefinitions[f];
Wolfram Language code: ParallelMap[f, {1, 2, 3, 4}]
Wolfram Language code: ClearAll[f];DistributeDefinitions[f];
Wolfram Language code: ParallelMap[f, {1, 2, 3, 4}]

DistributeDefinitionsはParallelEvaluateを使ってすべてのカーネルに定義を送る：

Wolfram Language code: f[n_] := PrimeQ[2 ^ n - 1]
Wolfram Language code: DistributeDefinitions[f];

明示的なParallelEvaluateも同じことをする：

Wolfram Language code: ParallelEvaluate[g[n_] := PrimeQ[2 ^ n + 1]];
Wolfram Language code: ParallelEvaluate[Through[{Identity, f, g}[$KernelID]]]

配布された定義は新たなカーネルにも引き継がれるが，ParallelEvaluateの効果は引き継がれない：

Wolfram Language code: CloseKernels[];LaunchKernels[];
Wolfram Language code: ParallelEvaluate[Through[{Identity, f, g}[$KernelID]]]

より高レベルの並列コマンドに関しては，インタラクティブに定義された関数が自動的に配布される：

Wolfram Language code: ftest[n_] := Labeled[Framed[PrimeQ[2 ^ n - 1]], $KernelID]
Wolfram Language code: ParallelMap[ftest, Range[1275, 1285]]

手動で定義を配布し自動配布を無効にする：

Wolfram Language code: gtest[n_] := Labeled[Framed[PrimeQ[2 ^ n - 1]], $KernelID]
Wolfram Language code: DistributeDefinitions[gtest];
Wolfram Language code: ParallelMap[gtest, Range[1275, 1285], DistributedContexts -> None]

サブカーネルのみで値のある記号は配布されない：

Wolfram Language code: ParallelEvaluate[xr = 5]
Wolfram Language code: DistributeDefinitions[xr]

サブカーネル上の値はそのまま残される：

Wolfram Language code: ParallelTable[Sqrt[i] / xr, {i, 5}]

記号に局所的な値が与えられるやいなや，その値は次の並列計算で配布される：

Wolfram Language code: xr = 6;
Wolfram Language code: ParallelTable[Sqrt[i] / xr, {i, 5}]

ParallelNeedsを使ってすべての並列カーネルにパッケージを設定する：

Wolfram Language code: Needs["GraphUtilities`"] ParallelNeeds["GraphUtilities`"]
Wolfram Language code: ParallelEvaluate[HamiltonianCycles[CompleteGraph[3], All]]

DistributeDefinitionsを使ってユーザ自身の定義を設定する：

Wolfram Language code: hcg[n_] := HamiltonianCycles[CompleteGraph[n], All]
Wolfram Language code: DistributeDefinitions[hcg];
Wolfram Language code: ParallelMap[hcg, Range[4]]

$DistributedDefinitionsは，定義が配布されている全シンボルのリストを与える：

Wolfram Language code: a = 2;b = 3;
Wolfram Language code: DistributeDefinitions[a]
Wolfram Language code: $DistributedDefinitions

リストには自動的に配布されたシンボルも含まれる：

Wolfram Language code: ParallelEvaluate[b]
Wolfram Language code: $DistributedDefinitions

考えられる問題  (5)

並列カーネルにとって既知ではない関数が使われると評価が連続的に行われかねない：

Wolfram Language code: ftest[n_] := Labeled[Framed[PrimeQ[2 ^ n - 1]], $KernelID]
Wolfram Language code: ParallelEvaluate[ftest[$KernelID], DistributedContexts -> None]

すべての並列カーネルで関数を定義する：

Wolfram Language code: DistributeDefinitions[ftest];

これで，この関数が並列カーネルで評価されるようになった：

Wolfram Language code: ParallelEvaluate[ftest[$KernelID], DistributedContexts -> None]

DistributeDefinitionsを使っても定義の自動配布は抑えられない：

Wolfram Language code: f[i_] := {i, $KernelID} DistributeDefinitions[f];

定義を変更する：

Wolfram Language code: Clear[f]

変更された定義は自動的に配布される：

Wolfram Language code: Parallelize[Map[f, Range[8]]]

定義の自動配布を抑える：

Wolfram Language code: g[i_] := {i, $KernelID} DistributeDefinitions[g];
Wolfram Language code: Clear[g]
Wolfram Language code: Parallelize[Map[g, Range[8]], DistributedContexts -> None]

サブカーネル上だけで定義された記号は自動的には配布されない：

Wolfram Language code: ParallelEvaluate[h[i_] := {i, $KernelID}];
Wolfram Language code: Parallelize[Map[h, Range[8]]]

内部状態を有するある種のオブジェクトは配布されると効率的に働かないことがある：

Wolfram Language code: data = RandomReal[{-1, 1}, 1000]; fdata = ListInterpolation[data]
Wolfram Language code: Timing[Table[fdata[r], {r, 1.0, 1000, 0.1}];]
Wolfram Language code: DistributeDefinitions[fdata];
Wolfram Language code: ParallelEvaluate[Timing[Table[fdata[r], {r, 1.0, 1000, 0.1}];], First[Kernels[]]]

よりよいパフォーマンスのためにそのようなオブジェクトをすべてのサブカーネルで再計算する：

Wolfram Language code: DistributeDefinitions[data, fdata]
Wolfram Language code: ParallelEvaluate[fdata = ListInterpolation[data];];
Wolfram Language code: ParallelEvaluate[Timing[Table[fdata[r], {r, 1.0, 1000, 0.1}];], First[Kernels[]]]

代りに，サブカーネル上のすべてのデータを再評価する：

Wolfram Language code: fdata1 = fdata; DistributeDefinitions[fdata1]
Wolfram Language code: ParallelEvaluate[fdata1 = fdata1];
Wolfram Language code: ParallelEvaluate[Timing[Table[fdata1[r], {r, 1.0, 1000, 0.1}];], Last[Kernels[]]]

ReadProtected属性があるシンボルの定義は配布できない：

Wolfram Language code: ftest[n_] := Labeled[Framed[PrimeQ[2 ^ n - 1]], $KernelID]; SetAttributes[ftest, ReadProtected]
Wolfram Language code: DistributeDefinitions[ftest]
Wolfram Language code: ParallelMap[ftest, Range[$KernelCount]]

定義は必要に応じてのみ配布される．定義が変更されていなければ，再度配布されることはない：

Wolfram Language code: a = 2;b = 3;
Wolfram Language code: DistributeDefinitions[a, b]
Wolfram Language code: b = 4;
Wolfram Language code: DistributeDefinitions[a, b]

どちらのシンボルもまだ配布された状態である：

Wolfram Language code: $DistributedDefinitions

おもしろい例題  (1)

ガウス素数を素早く可視化する：

Wolfram Language code: test[x_] := Boole[PrimeQ[x, GaussianIntegers -> True]]
Wolfram Language code: data = With[{n = 100}, ParallelTable[test[x + y I], {x, -n, n}, {y, -n, n}]]; ArrayPlot[data]
Wolfram Research (2008), DistributeDefinitions, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistributeDefinitions.html （2025年に更新）.

テキスト

Wolfram Research (2008), DistributeDefinitions, Wolfram言語関数， https://reference.wolfram.com/language/ref/DistributeDefinitions.html （2025年に更新）.

CMS

Wolfram Language. 2008. "DistributeDefinitions." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DistributeDefinitions.html.

APA

Wolfram Language. (2008). DistributeDefinitions. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DistributeDefinitions.html

BibTeX

@misc{reference.wolfram_2026_distributedefinitions, author="Wolfram Research", title="{DistributeDefinitions}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DistributeDefinitions.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distributedefinitions, organization={Wolfram Research}, title={DistributeDefinitions}, year={2025}, url={https://reference.wolfram.com/language/ref/DistributeDefinitions.html}, note=[Accessed: 15-September-2026]}