WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DivisorSum[n,form]

n を割るすべての i についての form[i]の総和を表す．

DivisorSum[n,form,cond]

cond[i]がTrueを与える除数だけを含む．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
記号演算  
アプリケーション  
基本的なアプリケーション  
整数論  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

DivisorSum

DivisorSum[n,form]

n を割るすべての i についての form[i]の総和を表す．

DivisorSum[n,form,cond]

cond[i]がTrueを与える除数だけを含む．

詳細

  • 記号操作・数値操作の両方に適した数学的整数関数である．
  • n は記号でも正の整数でもよい．
  • form と cond はFunctionオブジェクトでなければならない．
  • DivisorSum[n,form]は正の n についてSum[form[d],{d,Divisors[n]}]に等しい．
  • DivisorSum[n,form,cond]は，n が正の整数であるときは，自動的に簡約される．
  • DivisorSum[n,form]は，form が多項式関数であるときは，自動的に簡約される．

例題

すべて開く すべて閉じる

例  (2)

の約数の和を求める：

Wolfram Language code: DivisorSum[30, #&]

最初の50個の数の約数の和をプロットする：

Wolfram Language code: DiscretePlot[DivisorSum[n, #&], {n, 50}]

スコープ  (12)

数値評価  (5)

DivisorSumは形式的式に使うことができる：

Wolfram Language code: DivisorSum[20, f]

厳密値は正の整数に対して生成される：

Wolfram Language code: DivisorSum[20, #&]

約数についての条件を指定することができる：

Wolfram Language code: DivisorSum[20, #&, # < 5&]
Wolfram Language code: DivisorSum[20, f, PrimeQ]

大きい数について計算する：

Wolfram Language code: DivisorSum[10 ^ 50 + 1, #&]

DivisorSumは要素単位でリストに縫い込まれる：

Wolfram Language code: DivisorSum[{2, 5, 10}, # ^ 2&]

記号演算  (7)

TraditionalFormによる表示：

Wolfram Language code: DivisorSum[x, f]//TraditionalForm

DivisorSumは多項式関数を自動的に簡約する：

Wolfram Language code: DivisorSum[n, # ^ 2 + 2# + 5&]

式を簡約する：

Wolfram Language code: Reduce[DivisorSum[n, #&] == 2n - 4 && 0 < n < 40, n, Integers]

方程式を解く：

Wolfram Language code: Solve[DivisorSum[n, EulerPhi] < DivisorSum[n - 1, #&] && 1 < n < 10, n, Integers]

式を簡約する：

Wolfram Language code: FullSimplify[DivisorSum[2 ^ (p - 1)(2 ^ p - 1), #&], Element[2 ^ p - 1, Primes]]

和を記号的に計算する：

Wolfram Language code: DivisorSum[x, MangoldtLambda]
Wolfram Language code: DivisorSum[n, MoebiusMu]
Wolfram Language code: DivisorSum[n, MoebiusMu[n / #] Log[#] &]

母関数：

Wolfram Language code: GeneratingFunction[DivisorSum[n, Function[m, EulerPhi[m]]], n, x]

アプリケーション  (8)

基本的なアプリケーション  (3)

最初の100個の数について約数の和をプロットする：

Wolfram Language code: DiscretePlot[DivisorSum[n, #&], {n, 100}]

古典的な恒等式：

Wolfram Language code: 4DivisorSum[n, (-1)^(# - 1) / 2&, OddQ]
Wolfram Language code: 4DivisorSum[n, Sin[(π #/2)]&]
Wolfram Language code: 8DivisorSum[n, #&, Mod[#, 4] ≠ 0&]
Wolfram Language code: 16DivisorSum[n, (-1)^n + ##^3&]

ベキの和：

Wolfram Language code: DivisorSum[n, 1&]
Wolfram Language code: DivisorSum[n, # ^ k&]

整数論  (5)

オイラー(Euler)のトーシェント関数についてLambert級数を計算する：

Wolfram Language code: GeneratingFunction[DivisorSum[n, Function[m, EulerPhi[m]]], n, x]

ジョルダン(Jordan)のトーシェント関数を計算する [詳細]：

Wolfram Language code: jordanTotient[n_, k_] := DivisorSum[n, # ^ k MoebiusMu[n / #]&];

これは のときはオイラーのトーシェント関数に等しい：

Wolfram Language code: AllTrue[Range[100], jordanTotient[#, 1] == EulerPhi[#]&]
Wolfram Language code: jordanTotient[#, 2]& /@ Range[20]

ねじれ除数の和を計算する：

Wolfram Language code: twistedDivisorSum[s_, k_, j_, n_] := DivisorSum[n, DirichletCharacter[k, j, #] * # ^ s&];
Wolfram Language code: Table[twistedDivisorSum[s, 6, 2, m], {m, 1, 10}]

ユニタリたたみ込みを定義する：

Wolfram Language code: unitaryConvolution[f_, g_, n_, m_] := DivisorSum[m, Evaluate[(f /. n -> #)(g /. n -> (m / #))]&, CoprimeQ[#, m / #]&];
Wolfram Language code: Table[unitaryConvolution[n, 1 / n, n, m], {m, 1, 10}]

次数 n で既約であるの上で多項式の数を計算する：

Wolfram Language code: polynomialCount[p_, n_] := DivisorSum[n, MoebiusMu[n / #]p ^ #&] / n;

5を法とする既約多項式：

Wolfram Language code: Table[polynomialCount[5, n], {n, 1, 20}]

5を法とする既約多項式の分布：

Wolfram Language code: DiscretePlot[polynomialCount[5, n] / 5 ^ n, {n, 20}, PlotRange -> All]

についての数の対数プロット：

Wolfram Language code: DiscretePlot[{polynomialCount[2, n], polynomialCount[3, n], polynomialCount[5, n]}, {n, 20}, ScalingFunctions -> "Log", PlotLegends -> {"p=2", "p=3", "p=5"}]

特性と関係  (4)

Divisorsを使ってDivisorSumを計算する：

Wolfram Language code: Total[Divisors[1000] ^ 2]
Wolfram Language code: DivisorSum[1000, # ^ 2&]

DivisorSigmaは整数の約数のベキの和を与える：

Wolfram Language code: DivisorSigma[4, 15]
Wolfram Language code: DivisorSum[15, # ^ 4&]

DivisorSum[n,form]は，正の n についてはSum[form[d],{d,Divisors[n]}]に等しい：

Wolfram Language code: n = 28; form = # ^ 2 + 2#&;
Wolfram Language code: DivisorSum[n, form]
Wolfram Language code: Sum[form[d], {d, Divisors[n]}]

素数の素因数の和はもとの数を返す：

Wolfram Language code: PrimeQ[11]
Wolfram Language code: DivisorSum[11, #&, PrimeQ]

考えられる問題  (2)

DivisorSumの引数はNには影響されない：

Wolfram Language code: N[DivisorSum[n, 1 / (# + 1)&]]

評価の後では，結果がNに影響されることがある：

Wolfram Language code: N[DivisorSum[9, 1 / (# + 1)&]]

条件に対してTrueを与える約数だけが使われる：

Wolfram Language code: DivisorSum[10, f, g]
Wolfram Research (2008), DivisorSum, Wolfram言語関数， https://reference.wolfram.com/language/ref/DivisorSum.html.

テキスト

Wolfram Research (2008), DivisorSum, Wolfram言語関数， https://reference.wolfram.com/language/ref/DivisorSum.html.

CMS

Wolfram Language. 2008. "DivisorSum." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DivisorSum.html.

APA

Wolfram Language. (2008). DivisorSum. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DivisorSum.html

BibTeX

@misc{reference.wolfram_2026_divisorsum, author="Wolfram Research", title="{DivisorSum}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DivisorSum.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisorsum, organization={Wolfram Research}, title={DivisorSum}, year={2008}, url={https://reference.wolfram.com/language/ref/DivisorSum.html}, note=[Accessed: 13-September-2026]}