WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Divisors[n]

n の約数となる整数をリスト形式で返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
GaussianIntegers  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Divisors

Divisors[n]

n の約数となる整数をリスト形式で返す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (1)

1729の約数：

Wolfram Language code: Divisors[1729]
Wolfram Language code: 1729 / %

スコープ  (2)

整数を入力すると約数が整数で返される：

Wolfram Language code: Divisors[6]

ガウスの整数を入力するとガウスの約数が返される：

Wolfram Language code: Divisors[6 + 4I]

Divisorsは要素単位でリストの引数に縫い込まれる：

Wolfram Language code: Divisors[{605, 871, 824}]

オプション  (3)

GaussianIntegers  (3)

次は整数の入力に対し，ガウスの約数を返す：

Wolfram Language code: Divisors[2, GaussianIntegers -> True]

素数の中にはガウスの素数もある：

Wolfram Language code: Divisors[3]
Wolfram Language code: Divisors[3, GaussianIntegers -> True]

整数の約数に対するガウスの約数の割合：

Wolfram Language code: ListPlot[Table[Length[Divisors[n, GaussianIntegers -> True]] / Length[Divisors[n]], {n, 200}], Filling -> Axis]

アプリケーション  (3)

10000より小さいすべての perfect numbers（完全数）を求める：

Wolfram Language code: Select[Range[10 ^ 4 - 1], Total[Divisors[#]] == 2#&]

25を二乗の和で表す：

Wolfram Language code: {Re[#], Im[#]}& /@ Select[Divisors[25, GaussianIntegers -> True], Abs[#]^2 == 25&]

PowersRepresentationsは順序付けた表示をする：

Wolfram Language code: PowersRepresentations[25, 2, 2]

ある数を4つの二乗の和として表す方法の数：

Wolfram Language code: 8 Total[Select[Divisors[20], !Divisible[#, 4]&]]

SquaresRによる計算：

Wolfram Language code: SquaresR[4, 20]

特性と関係  (4)

約数の数を数える：

Wolfram Language code: Sum[1, {k, Divisors[2 ^ 12 - 1]}]
Wolfram Language code: DivisorSigma[0, 2 ^ 12 - 1]

一般にはDivisorSigma[d,n]==∑k|nkdとなる：

Wolfram Language code: Table[{DivisorSigma[d, 2 ^ 12 - 1], Sum[k ^ d, {k, Divisors[2 ^ 12 - 1]}]}, {d, 0, 5}]//Grid

同様にEulerPhi[n]==n∏p|n(1-1/p)，ただし p は素数である：

Wolfram Language code: 100 Product[1 - 1 / k, {k, Select[Divisors[100], PrimeQ]}]
Wolfram Language code: EulerPhi[100]

EulerPhi[n]==n∑k|nMoebiusMu[k]/k もある：

Wolfram Language code: 35 Sum[MoebiusMu[k] / k, {k, Divisors[35]}]
Wolfram Language code: EulerPhi[35]

考えられる問題  (1)

Divisorsは，単位数による乗算，つまり第一象限におけるもの以外のすべての約数を与える：

Wolfram Language code: d = Divisors[2, GaussianIntegers -> True]

すべての約数を得る：

Wolfram Language code: Flatten[Outer[Times, {1, -1, I, -I}, d]]
Wolfram Language code: Divisible[2, %]
Wolfram Research (1988), Divisors, Wolfram言語関数， https://reference.wolfram.com/language/ref/Divisors.html.

テキスト

Wolfram Research (1988), Divisors, Wolfram言語関数， https://reference.wolfram.com/language/ref/Divisors.html.

CMS

Wolfram Language. 1988. "Divisors." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Divisors.html.

APA

Wolfram Language. (1988). Divisors. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Divisors.html

BibTeX

@misc{reference.wolfram_2026_divisors, author="Wolfram Research", title="{Divisors}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Divisors.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisors, organization={Wolfram Research}, title={Divisors}, year={1988}, url={https://reference.wolfram.com/language/ref/Divisors.html}, note=[Accessed: 07-October-2026]}