WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DropShadowing[]

グラフィックスオブジェクトを追加的なぼかしのオフセット画像で描画するように指定する二次元の指示子である．

DropShadowing[{dx,dy}]

絶対オフセット{dx,dy}を使う．

DropShadowing[{dx,dy},r]

変形 r のぼかし効果を適用する．

DropShadowing[{dx,dy},r,col]

ぼかしたオフセット画像に指定の色 col を使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
指定  
アプリケーション  
基本的なアプリケーション  
シャドー効果  
グラフィックス  
可視化  
特性と関係  
考えられる問題  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DropShadowing

DropShadowing[]

グラフィックスオブジェクトを追加的なぼかしのオフセット画像で描画するように指定する二次元の指示子である．

DropShadowing[{dx,dy}]

絶対オフセット{dx,dy}を使う．

DropShadowing[{dx,dy},r]

変形 r のぼかし効果を適用する．

DropShadowing[{dx,dy},r,col]

ぼかしたオフセット画像に指定の色 col を使う．

詳細

例題

すべて開く すべて閉じる

例  (3)

テキストにドロップシャドウ効果を適用する：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 32]]}]

曲線に影を付けてプロットする：

Wolfram Language code: Plot[{2 Sin[x] + x, 2 Cos[x] + x}, {x, 0, 15}, PlotStyle -> DropShadowing[]]

アメリカ合衆国の地図をドロップシャドウでプロットする：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", DropShadowing[{-3, -3}, 6], RGBColor[0.7411765055418048, 0.8549020847953749, 0.6705883350216774]], Polygon[["US"]]}]

スコープ  (16)

基本的な用法  (7)

ドロップシャドウをグラフィックスプリミティブに適用する：

Wolfram Language code: Graphics[{DropShadowing[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

ドロップシャドウをTextに適用する：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 24]]}]

ドロップシャドウをプロットに適用する：

Wolfram Language code: Plot[{3Sin[x] + x, 3Cos[x] + x}, {x, 0, 15}, PlotStyle -> DropShadowing[]]

ドロップシャドウをグラフに適用する：

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> DropShadowing[]]

幾何学領域にスタイル付けする：

Wolfram Language code: Region[Style[ImplicitRegion[y ^ 2 < x (-1 + x ^ 3), {x, y}], DropShadowing[]]]

白地図を表示する：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", DropShadowing[{-3, -3}, 6], RGBColor[0.7411765055418048, 0.8549020847953749, 0.6705883350216774]], Polygon[["austria"]]}]

要約ボックス：

Wolfram Language code: DropShadowing[]

指定  (9)

DropShadowEffectを引数なしで使うと透明な影がオブジェクトの左下に描画される：

Wolfram Language code: Graphics[{DropShadowing[], Annulus[]}, PlotRangePadding -> 0.2]

影のオフセットをもとのオブジェクトと相対的に指定する：

Wolfram Language code: Graphics[{DropShadowing[#], Annulus[]}, PlotRangePadding -> 0.3]& /@ {{-8, 0}, {0, -8}, {8, 0}}

カスタムの影のぼかし半径を使う：

Wolfram Language code: Graphics[{DropShadowing[{-6, -6}, #], Annulus[{0, 0}, {8, 9}]}, PlotRangePadding -> 4]& /@ {0, 2, 6}

デフォルトで，影の色はGrayLevel[0,1/3]に設定される：

Wolfram Language code: Graphics[{DropShadowing[], RGBColor[0., 2/3, 1.], Annulus[]}, PlotRangePadding -> 0.2]

影の色を明示的に設定する：

Wolfram Language code: Graphics[{DropShadowing[{-3, -3}, 2, RGBColor[1., 1/3, 0.]], RGBColor[0., 2/3, 1.], Annulus[]}, PlotRangePadding -> 0.2]

色をInheritedに設定してもとのオブジェクトのFaceFormの色を不透明度を半分にして使う：

Wolfram Language code: Graphics[{DropShadowing[{-3, -3}, 2, Inherited], #, Annulus[]}, PlotRangePadding -> 0.2]& /@ {RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.], RGBColor[1., 1/3, 0.]}

DropShadowEffectは不透明度がある影の色に使うことができる：

Wolfram Language code: Graphics[{DropShadowing[{-6, -6}, 2, Opacity[#, RGBColor[1, 3/4, 0]]], Annulus[]}, PlotRangePadding -> 0.2]& /@ {1 / 10, 1 / 2, 1}

もとのオブジェクトのFaceForm色をカスタムの不透明度で使う：

Wolfram Language code: Graphics[{RGBColor[0, 2/3, 1], DropShadowing[{-6, -6}, 2, Opacity[#]], Annulus[]}, PlotRangePadding -> 0.2]& /@ {1 / 10, 1 / 2, 9 / 10}

LightDarkSwitchedを使ってライトモードとダークモードに異なる色を指定する：

Wolfram Language code: graphic = Graphics[{DropShadowing[{-6, -6}, 2, LightDarkSwitched[RGBColor[1., 3/4, 0.], RGBColor[0., 2/3, 1.]]], Annulus[]}, PlotRangePadding -> 0.2];
Wolfram Language code: {LightModePane[graphic], DarkModePane[graphic]}

オフセットと色にデフォルト値を使ってぼかし半径を設定する：

Wolfram Language code: Graphics[{DropShadowing[Automatic, 0], Annulus[]}]

これはぼかし半径だけを与えることに等しい：

Wolfram Language code: Graphics[{DropShadowing[0], Annulus[]}]

オフセットとぼかしにデフォルト値を使って影の色を設定する：

Wolfram Language code: Graphics[{DropShadowing[Automatic, Automatic, RGBColor[1., 1/3, 0.]], Annulus[]}]

これは色だけを与えることに等しい：

Wolfram Language code: Graphics[{DropShadowing[RGBColor[1., 1/3, 0.]], Annulus[]}]

影のオフセットとぼかし半径は，デフォルトで，印刷用のプリンタポイントで指定される：

Wolfram Language code: Graphics[{DropShadowing[{-25, -20}, 1], Disk[]}, PlotRange -> {{-4, 1}, {-3, 1.2}}, ImageSize -> #]& /@ {50, 100, 150}

ImageScaledのオフセットと半径を使う：

Wolfram Language code: Graphics[{DropShadowing[ImageScaled[{-0.5, -0.4}], ImageScaled[0.01]], Disk[]}, PlotRange -> {{-4, 1}, {-3, 1.2}}, ImageSize -> #]& /@ {50, 100, 150}

アプリケーション  (11)

基本的なアプリケーション  (1)

影のオフセットとぼかし半径を示す：

Wolfram Language code: offsetblur[offset_, blur_ : 0] := Graphics[{{RGBColor[0., 2/3, 1.], Thick, Circle[Offset[offset], Offset[30]], Dashed, Circle[Offset[offset], Offset[30 + blur]]}, {DropShadowing[offset, blur], RGBColor[1., 3/4, 0.], EdgeForm[Black], Disk[{0, 0}, Offset[30]]}, Point[{{0, 0}, Offset[offset]}], Dashing[None], Line[{{0, 0}, Offset[offset]}]}]

影を右にずらす：

Wolfram Language code: Table[offsetblur[{dx, 0}], {dx, {10, 20, 30}}]

さまざまな半径を使って影をぼかす：

Wolfram Language code: Table[offsetblur[{0, 0}, r], {r, {0, 10, 16}}]

大きいぼかし半径で左下にずらす：

Wolfram Language code: offsetblur[{-60, -30}, 20]

シャドー効果  (3)

3Dの深さのシミュレーションを2Dグラフィックスで行う：

Wolfram Language code: Graphics[{LightGray, Disk[], DropShadowing[], Disk[{2, 0}]}]

オフセットの値とぼかし半径が大きいほど深くなる：

Wolfram Language code: Graphics[{LightGray, Table[{DropShadowing[{-2x, -x}, x], Disk[{x, 0}, 3 / 4]}, {x, 4}]}]

オフセットは使わずにぼかし半径を大きくしてグロー効果を作成する：

Wolfram Language code: Graphics[{DropShadowing[{0, 0}, 16, Magenta], Text[Style["Glow", 64, FontFamily -> "Brush Script MT", White]]}, Background -> Black, AspectRatio -> 1 / 2]

複数のドロップシャドウを使うことで細い輪郭を近似する：

Wolfram Language code: Graphics[{Table[{DropShadowing[o, 1, Blue], Text[Style["Outline", 32, White]]}, {o, {{1, 0}, {-1, 0}, {0, 1}, {0, -1}}}]}, AspectRatio -> 1 / 2]

グラフィックス  (3)

ドロップシャドーをグラフィックスプリミティブに適用する：

Wolfram Language code: Graphics[{DropShadowing[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

ドロップシャドーをTextに適用する：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 52, FontFamily -> "Brush Script MT"]]}]

ドロップシャドーをGraphicsComplexに適用する：

Wolfram Language code: gc = GraphicsComplex[{...}, Polygon[...]]; Graphics[{DropShadowing[4], gc}, PlotRangePadding -> 30]

可視化  (4)

曲線をドロップシャドーをでプロットする：

Wolfram Language code: Plot[Sin[Sqrt[2] x] + Sin[x], {x, 0, 10}, PlotStyle -> DropShadowing[]]

棒グラフにスタイル付けする：

Wolfram Language code: BarChart[{1, 2, 3, 4, 5}, ChartStyle -> DropShadowing[]]

ベクトルプロットにスタイル付けする：

Wolfram Language code: VectorPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, VectorStyle -> DropShadowing[]]

パラメトリックプロットにスタイル付けする：

Wolfram Language code: ParametricPlot[r ^ 2 {Sqrt[t] Cos[t], Sin[t]}, {t, 0, 3 Pi / 2}, {r, 1, 2}, PlotStyle -> Directive[DropShadowing[], LightBlue, Opacity[1]]]

特性と関係  (2)

ドロップシャドウ効果は画像処理関数を使って出すこともできる：

Wolfram Language code: {offset, radius, img} = {{-6, -6}, 6, [image]};
Wolfram Language code: ImageCompose[SetAlphaChannel[GaussianFilter[img, radius], 1 / 3], img, {0, 0}, offset]

DropShadowingを使った同等の効果：

Wolfram Language code: Graphics[{DropShadowing[offset, radius], ImageMesh[ColorNegate[RemoveAlphaChannel[img]], Method -> "MarchingSquares"]}, PlotRangePadding -> Scaled[.08]]

グラフィックスプリミティブはOffsetを使って厳密な影のシミュレーションを行うことで複製してずらすことができる：

Wolfram Language code: Graphics[{Disk[], Opacity[1 / 3], Disk[Offset[{-8, -5}]]}, PlotRange -> 1.2]
Wolfram Language code: Graphics[{DropShadowing[{-8, -5}, 0], Disk[]}, PlotRange -> 1.2]

考えられる問題  (1)

ドロップシャドウは対応するオブジェクトがGraphics内で定義された順に描かれる：

Wolfram Language code: regs = {Disk[], Disk[{1, 0}]}; Graphics[{DropShadowing[{-3, -3}, 2, Gray], LightGray, regs}]

インタラクティブな例題  (1)

プロットのドロップシャドウオフセット，ぼかし半径，色を調整する：

Wolfram Language code: Manipulate[Plot[{Sin[x], Cos[x]}, {x, 0, 2 π}, PlotStyle -> DropShadowing[{dx, dy}, r, color]], {{dx, -3}, -10, 10}, {{dy, -3}, -10, 10}, {{r, 2}, 0, 10}, {color, {Automatic, Inherited, Red}}]

おもしろい例題  (2)

重なり合う多角形に深さを加える：

Wolfram Language code: With[{d = 2 Pi / 12}, Graphics[{DropShadowing[{0, 0}, 4, Black], Table[{Hue[(-11 + q + 10 r) / 72], Polygon[{(8 - r) {Cos[d (q - 1)], Sin[d (q - 1)]}, (8 - r) {Cos[d (q + 1)], Sin[d (q + 1)]}, (10 - r) {Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]}]]

ページから浮かんでくるテキストのアニメーションを作成する：

Wolfram Language code: Animate[ DynamicModule[{t, chars}, chars = Characters["Drop Shadow"]; Graphics[{Table[t = Max[0, 1 - Abs[i - Length[chars] * x] ^ 2];{DropShadowing[{0, -8t}, (2t) ^ 2], Text[Style[chars[[i]], 42, Bold], {i, 0.2t}]}, {i, Length[chars]}]}, ImageSize -> Medium, PlotRange -> {{0, Length[chars] + 1}, {-1, 1}}] ], {x, 0, 1} ]
Wolfram Research (2022), DropShadowing, Wolfram言語関数， https://reference.wolfram.com/language/ref/DropShadowing.html.

テキスト

Wolfram Research (2022), DropShadowing, Wolfram言語関数， https://reference.wolfram.com/language/ref/DropShadowing.html.

CMS

Wolfram Language. 2022. "DropShadowing." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DropShadowing.html.

APA

Wolfram Language. (2022). DropShadowing. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DropShadowing.html

BibTeX

@misc{reference.wolfram_2026_dropshadowing, author="Wolfram Research", title="{DropShadowing}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/DropShadowing.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dropshadowing, organization={Wolfram Research}, title={DropShadowing}, year={2022}, url={https://reference.wolfram.com/language/ref/DropShadowing.html}, note=[Accessed: 14-September-2026]}