WOLFRAM

Wolfram 语言与系统参考资料中心

DropShadowing[]

是一个二维指令，指定使用附加的模糊偏移图像绘制图形对象.

DropShadowing[{dx,dy}]

使用绝对偏移量 {dx,dy}.

DropShadowing[{dx,dy},r]

应用半径为 r 的模糊效果.

DropShadowing[{dx,dy},r,col]

对模糊的偏移图像使用指定的颜色 col.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
规范  
应用  
基本应用  
阴影效果  
图形  
可视化  
属性和关系  
可能存在的问题  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DropShadowing

DropShadowing[]

是一个二维指令，指定使用附加的模糊偏移图像绘制图形对象.

DropShadowing[{dx,dy}]

使用绝对偏移量 {dx,dy}.

DropShadowing[{dx,dy},r]

应用半径为 r 的模糊效果.

DropShadowing[{dx,dy},r,col]

对模糊的偏移图像使用指定的颜色 col.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

将阴影效果应用于文本：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 32]]}]

绘制带阴影的曲线：

Wolfram Language code: Plot[{2 Sin[x] + x, 2 Cos[x] + x}, {x, 0, 15}, PlotStyle -> DropShadowing[]]

显示带有阴影的美国地图：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", DropShadowing[{-3, -3}, 6], RGBColor[0.7411765055418048, 0.8549020847953749, 0.6705883350216774]], Polygon[["US"]]}]

范围  (16)

基本用法  (7)

对图形基元应用阴影：

Wolfram Language code: Graphics[{DropShadowing[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

对 Text 应用阴影：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 24]]}]

对图线应用阴影：

Wolfram Language code: Plot[{3Sin[x] + x, 3Cos[x] + x}, {x, 0, 15}, PlotStyle -> DropShadowing[]]

对图表应用阴影：

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> DropShadowing[]]

设置几何区域的样式：

Wolfram Language code: Region[Style[ImplicitRegion[y ^ 2 < x (-1 + x ^ 3), {x, y}], DropShadowing[]]]

显示示意轮廓图：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", DropShadowing[{-3, -3}, 6], RGBColor[0.7411765055418048, 0.8549020847953749, 0.6705883350216774]], Polygon[["austria"]]}]

摘要框：

Wolfram Language code: DropShadowing[]

规范  (9)

不带参数的 DropShadowEffect 在对象的左下角绘制半透明阴影：

Wolfram Language code: Graphics[{DropShadowing[], Annulus[]}, PlotRangePadding -> 0.2]

指定阴影相对于原始对象的偏移量：

Wolfram Language code: Graphics[{DropShadowing[#], Annulus[]}, PlotRangePadding -> 0.3]& /@ {{-8, 0}, {0, -8}, {8, 0}}

使用自定义阴影模糊半径：

Wolfram Language code: Graphics[{DropShadowing[{-6, -6}, #], Annulus[{0, 0}, {8, 9}]}, PlotRangePadding -> 4]& /@ {0, 2, 6}

阴影颜色默认设置为 GrayLevel[0,1/3]：

Wolfram Language code: Graphics[{DropShadowing[], RGBColor[0., 2/3, 1.], Annulus[]}, PlotRangePadding -> 0.2]

显式设置阴影颜色：

Wolfram Language code: Graphics[{DropShadowing[{-3, -3}, 2, RGBColor[1., 1/3, 0.]], RGBColor[0., 2/3, 1.], Annulus[]}, PlotRangePadding -> 0.2]

将颜色设置为 Inherited 以使用具有一半不透明度的原始对象的 FaceForm 颜色：

Wolfram Language code: Graphics[{DropShadowing[{-3, -3}, 2, Inherited], #, Annulus[]}, PlotRangePadding -> 0.2]& /@ {RGBColor[0., 2/3, 1.], RGBColor[1., 3/4, 0.], RGBColor[1., 1/3, 0.]}

DropShadowEffect 适用于具有不透明度的阴影颜色：

Wolfram Language code: Graphics[{DropShadowing[{-6, -6}, 2, Opacity[#, RGBColor[1, 3/4, 0]]], Annulus[]}, PlotRangePadding -> 0.2]& /@ {1 / 10, 1 / 2, 1}

使用具有自定义不透明度的原始对象的 FaceForm 颜色：

Wolfram Language code: Graphics[{RGBColor[0, 2/3, 1], DropShadowing[{-6, -6}, 2, Opacity[#]], Annulus[]}, PlotRangePadding -> 0.2]& /@ {1 / 10, 1 / 2, 9 / 10}

用 LightDarkSwitched 为浅色和深色模式指定不同的颜色：

Wolfram Language code: graphic = Graphics[{DropShadowing[{-6, -6}, 2, LightDarkSwitched[RGBColor[1., 3/4, 0.], RGBColor[0., 2/3, 1.]]], Annulus[]}, PlotRangePadding -> 0.2];
Wolfram Language code: {LightModePane[graphic], DarkModePane[graphic]}

在使用偏移和颜色的默认值时设置模糊半径：

Wolfram Language code: Graphics[{DropShadowing[Automatic, 0], Annulus[]}]

这相当于只给出模糊半径：

Wolfram Language code: Graphics[{DropShadowing[0], Annulus[]}]

在使用偏移和模糊的默认值时设置阴影颜色：

Wolfram Language code: Graphics[{DropShadowing[Automatic, Automatic, RGBColor[1., 1/3, 0.]], Annulus[]}]

这相当于只给出颜色：

Wolfram Language code: Graphics[{DropShadowing[RGBColor[1., 1/3, 0.]], Annulus[]}]

默认情况下，以打印机点数指定阴影偏移和模糊半径：

Wolfram Language code: Graphics[{DropShadowing[{-25, -20}, 1], Disk[]}, PlotRange -> {{-4, 1}, {-3, 1.2}}, ImageSize -> #]& /@ {50, 100, 150}

使用 ImageScaled 偏移和半径：

Wolfram Language code: Graphics[{DropShadowing[ImageScaled[{-0.5, -0.4}], ImageScaled[0.01]], Disk[]}, PlotRange -> {{-4, 1}, {-3, 1.2}}, ImageSize -> #]& /@ {50, 100, 150}

应用  (11)

基本应用  (1)

显示阴影偏移和模糊半径：

Wolfram Language code: offsetblur[offset_, blur_ : 0] := Graphics[{{RGBColor[0., 2/3, 1.], Thick, Circle[Offset[offset], Offset[30]], Dashed, Circle[Offset[offset], Offset[30 + blur]]}, {DropShadowing[offset, blur], RGBColor[1., 3/4, 0.], EdgeForm[Black], Disk[{0, 0}, Offset[30]]}, Point[{{0, 0}, Offset[offset]}], Dashing[None], Line[{{0, 0}, Offset[offset]}]}]

将阴影向右偏移：

Wolfram Language code: Table[offsetblur[{dx, 0}], {dx, {10, 20, 30}}]

使用各种半径模糊阴影：

Wolfram Language code: Table[offsetblur[{0, 0}, r], {r, {0, 10, 16}}]

以大模糊半径向左下方偏移：

Wolfram Language code: offsetblur[{-60, -30}, 20]

阴影效果  (3)

在二维图形中模拟三维深度：

Wolfram Language code: Graphics[{LightGray, Disk[], DropShadowing[], Disk[{2, 0}]}]

较大的偏移和模糊半径值对应于较大的深度：

Wolfram Language code: Graphics[{LightGray, Table[{DropShadowing[{-2x, -x}, x], Disk[{x, 0}, 3 / 4]}, {x, 4}]}]

通过使用大模糊半径的无偏移来创建发光效果：

Wolfram Language code: Graphics[{DropShadowing[{0, 0}, 16, Magenta], Text[Style["Glow", 64, FontFamily -> "Brush Script MT", White]]}, Background -> Black, AspectRatio -> 1 / 2]

通过使用多个阴影来近似细轮廓：

Wolfram Language code: Graphics[{Table[{DropShadowing[o, 1, Blue], Text[Style["Outline", 32, White]]}, {o, {{1, 0}, {-1, 0}, {0, 1}, {0, -1}}}]}, AspectRatio -> 1 / 2]

图形  (3)

对图形基元应用阴影：

Wolfram Language code: Graphics[{DropShadowing[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

对 Text 应用阴影：

Wolfram Language code: Graphics[{DropShadowing[], Text[Style["Shadow", 52, FontFamily -> "Brush Script MT"]]}]

对 GraphicsComplex 应用阴影：

Wolfram Language code: gc = GraphicsComplex[{...}, Polygon[...]]; Graphics[{DropShadowing[4], gc}, PlotRangePadding -> 30]

可视化  (4)

绘制带有阴影的曲线：

Wolfram Language code: Plot[Sin[Sqrt[2] x] + Sin[x], {x, 0, 10}, PlotStyle -> DropShadowing[]]

设置条形图的样式：

Wolfram Language code: BarChart[{1, 2, 3, 4, 5}, ChartStyle -> DropShadowing[]]

设置矢量图的样式：

Wolfram Language code: VectorPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, VectorStyle -> DropShadowing[]]

设置参数图的样式：

Wolfram Language code: ParametricPlot[r ^ 2 {Sqrt[t] Cos[t], Sin[t]}, {t, 0, 3 Pi / 2}, {r, 1, 2}, PlotStyle -> Directive[DropShadowing[], LightBlue, Opacity[1]]]

属性和关系  (2)

阴影效果也可以使用图像处理函数产生：

Wolfram Language code: {offset, radius, img} = {{-6, -6}, 6, [image]};
Wolfram Language code: ImageCompose[SetAlphaChannel[GaussianFilter[img, radius], 1 / 3], img, {0, 0}, offset]

使用 DropShadowing 的等价效果：

Wolfram Language code: Graphics[{DropShadowing[offset, radius], ImageMesh[ColorNegate[RemoveAlphaChannel[img]], Method -> "MarchingSquares"]}, PlotRangePadding -> Scaled[.08]]

图形基元可以使用 Offset 复制和偏移，以模拟精确的阴影：

Wolfram Language code: Graphics[{Disk[], Opacity[1 / 3], Disk[Offset[{-8, -5}]]}, PlotRange -> 1.2]
Wolfram Language code: Graphics[{DropShadowing[{-8, -5}, 0], Disk[]}, PlotRange -> 1.2]

可能存在的问题  (1)

阴影按照其对应对象在 Graphics 中定义的顺序绘制：

Wolfram Language code: regs = {Disk[], Disk[{1, 0}]}; Graphics[{DropShadowing[{-3, -3}, 2, Gray], LightGray, regs}]

互动范例  (1)

调整绘图的阴影偏移、模糊半径和颜色：

Wolfram Language code: Manipulate[Plot[{Sin[x], Cos[x]}, {x, 0, 2 π}, PlotStyle -> DropShadowing[{dx, dy}, r, color]], {{dx, -3}, -10, 10}, {{dy, -3}, -10, 10}, {{r, 2}, 0, 10}, {color, {Automatic, Inherited, Red}}]

巧妙范例  (2)

为重叠的多边形添加深度：

Wolfram Language code: With[{d = 2 Pi / 12}, Graphics[{DropShadowing[{0, 0}, 4, Black], Table[{Hue[(-11 + q + 10 r) / 72], Polygon[{(8 - r) {Cos[d (q - 1)], Sin[d (q - 1)]}, (8 - r) {Cos[d (q + 1)], Sin[d (q + 1)]}, (10 - r) {Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]}]]

创建悬停在页面外的文本动画：

Wolfram Language code: Animate[ DynamicModule[{t, chars}, chars = Characters["Drop Shadow"]; Graphics[{Table[t = Max[0, 1 - Abs[i - Length[chars] * x] ^ 2];{DropShadowing[{0, -8t}, (2t) ^ 2], Text[Style[chars[[i]], 42, Bold], {i, 0.2t}]}, {i, Length[chars]}]}, ImageSize -> Medium, PlotRange -> {{0, Length[chars] + 1}, {-1, 1}}] ], {x, 0, 1} ]
Wolfram Research (2022)，DropShadowing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DropShadowing.html.

文本

Wolfram Research (2022)，DropShadowing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DropShadowing.html.

CMS

Wolfram 语言. 2022. "DropShadowing." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DropShadowing.html.

APA

Wolfram 语言. (2022). DropShadowing. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DropShadowing.html 年

BibTeX

@misc{reference.wolfram_2026_dropshadowing, author="Wolfram Research", title="{DropShadowing}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/DropShadowing.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dropshadowing, organization={Wolfram Research}, title={DropShadowing}, year={2022}, url={https://reference.wolfram.com/language/ref/DropShadowing.html}, note=[Accessed: 16-September-2026]}