WOLFRAM

Wolfram 语言与系统参考资料中心

DualPolyhedron[poly]

给出多面体 poly 的对偶多面体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
基本应用  
多面体运算  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

DualPolyhedron

DualPolyhedron[poly]

给出多面体 poly 的对偶多面体.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

十二面体的对偶多面体：

Wolfram Language code: DualPolyhedron[Dodecahedron[]]
Wolfram Language code: Graphics3D[%]

给出航天飞机的对偶多面体：

Wolfram Language code: 𝒫 = DualPolyhedron[Polyhedron[{{-4.999492168426514, -0.6817100048065186, 0.569242000579834}, {-4.999759197235107, -0.4911530017852783, 0.8052060008049011}, {-5.349475860595703, -0.47093498706817627, 0.5660619735717773}, {-4.999759197235107, 0.491153001785278 ... }, {291, 218, 220}, {211, 259, 258}, {280, 206, 218}, {212, 258, 288}, {225, 187, 219}, {245, 197, 196}, {200, 236, 235}, {263, 196, 207}, {274, 205, 193}, {282, 210, 205}, {268, 193, 188}, {226, 219, 210}, {269, 188, 187}, {215, 288, 287}}]];

图示：

Wolfram Language code: Graphics3D[𝒫, Boxed -> False]

范围  (3)

DualPolyhedron 适用于多面体：

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: Graphics3D[{Opacity[0.2], 𝒫, %}]

柏拉图体的 DualPolyhedron 包括 Tetrahedron：

Wolfram Language code: DualPolyhedron[Tetrahedron[1]]

Cube：

Wolfram Language code: DualPolyhedron[Cube[1]]
Wolfram Language code: Graphics3D[%]

Dodecahedron：

Wolfram Language code: DualPolyhedron[Dodecahedron[1]]

Octahedron：

Wolfram Language code: DualPolyhedron[Octahedron[1]]

Icosahedron：

Wolfram Language code: DualPolyhedron[Icosahedron[1]]

特殊多面体表示：

Wolfram Language code: 𝒫 = ExampleData[{"Geometry3D", "SpaceShuttle"}, "BoundaryMeshRegion"]
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: Graphics3D[{Opacity[0.2], 𝒫, %}]

应用  (9)

基本应用  (3)

创建柏拉图体及其对偶多面体的图集：

Wolfram Language code: Grid[Table[{Graphics3D[f[1], Boxed -> False], [image], Graphics3D[DualPolyhedron[f[1]], Boxed -> False]}, {f, {Tetrahedron, Cube, Octahedron, Dodecahedron, Icosahedron}}]]

创建阿基米德体及其对偶多面体的图集：

Wolfram Language code: Multicolumn[Table[Row[{Graphics3D[f, Boxed -> False, ImageSize -> 50], [image], Graphics3D[DualPolyhedron[f], Boxed -> False, ImageSize -> 50]}], {f, PolyhedronData["Archimedean", "Polyhedron"]}], 2, Spacings -> 3]

柏拉图体的对偶复合体：

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], DualPolyhedron[f[1]], f[1]}, Boxed -> False], {f, {Tetrahedron, Cube, Dodecahedron}}]

阿基米德体：

Wolfram Language code: Table[Graphics3D[{Opacity[0.5], f, DualPolyhedron[f]}, Boxed -> False], {f, PolyhedronData["Archimedean", "Polyhedron"]}]

多面体运算  (6)

用 DualPolyhedron 进行多面体运算，比如 needle 运算：

Wolfram Language code: needle[poly_] := DualPolyhedron[TruncatedPolyhedron[poly]]
Wolfram Language code: needle[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Meta 运算：

Wolfram Language code: meta[poly_] := DualPolyhedron[BeveledPolyhedron[poly]]
Wolfram Language code: meta[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

合并：

Wolfram Language code: join[poly_] := DualPolyhedron[TruncatedPolyhedron[poly]]
Wolfram Language code: join[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Zip 运算：

Wolfram Language code: zip[poly_] := DualPolyhedron[AugmentedPolyhedron[poly]]
Wolfram Language code: zip[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

Ortho 运算：

Wolfram Language code: ortho[poly_] := DualPolyhedron[TruncatedPolyhedron[TruncatedPolyhedron[poly]]]
Wolfram Language code: ortho[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

扩展：

Wolfram Language code: expand[poly_] := DualPolyhedron[TruncatedPolyhedron[TruncatedPolyhedron[poly, 0.5]]]
Wolfram Language code: expand[Tetrahedron[1]]
Wolfram Language code: Graphics3D[%]

属性和关系  (4)

简单多面体的对偶多面体还是简单多面体：

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: SimplePolyhedronQ[#]& /@ {𝒫, DualPolyhedron[𝒫]}

柏拉图多面体的对偶多面体还是柏拉图多面体：

Wolfram Language code: 𝒫 = Cube[1];
Wolfram Language code: DualPolyhedron[𝒫]
Wolfram Language code: {Graphics3D[𝒫], Graphics3D[%]}

对偶多面体的对偶多面体是原来的多面体：

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}}];
Wolfram Language code: DualPolyhedron[DualPolyhedron[𝒫]];
Wolfram Language code: {Graphics3D[𝒫], Graphics3D[%]}

四棱锥是自对偶多面体：

Wolfram Language code: DualPolyhedron[Pyramid[]]
Wolfram Language code: Graphics3D[%]

可能存在的问题  (3)

DualPolyhedron 只支持简单多面体：

Wolfram Language code: 𝒫 = Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {1, 0, 0}, {2, 0, 0}, {1, 1, 0}, {1, 0, 1}}, {{1, 2, 3}, {1, 2, 4}, {2, 3, 4}, {1, 3, 4}, {5, 6, 7}, {5, 6, 8}, {6, 7, 8}, {5, 7, 8}}];
Wolfram Language code: SimplePolyhedronQ[𝒫]
Wolfram Language code: DualPolyhedron[𝒫]

多面体的对偶在拓扑上是对偶的:

Wolfram Language code: dual = DualPolyhedron[Tetrahedron[1]]

对偶的对偶:

Wolfram Language code: DualPolyhedron[dual]

DualPolyhedron 可以给出退化多面体：

Wolfram Language code: DualPolyhedron[Polyhedron[{{-1, 0, 0}, {-1/2, -1/2, -(1/Sqrt[2])}, {-1/2, -1/2, 1/Sqrt[2]}, {-1/2, 1/2, -(1/Sqrt[2])}, {-1/2, 1/2, 1/Sqrt[2]}, {0, -1, 0}, {0, 1, 0}, {1/2, -1/2, -(1/Sqrt[2])}, {1/2, -1/2, 1/Sqrt[2]}, {1/2, 1/2, -(1/Sqrt[2])}, {1/2, 1/2, 1/Sqrt[2]}, {1, 0, 0}}, {{4, 10, 8, 2}, {3, 9, 11, 5}, {9, 6, 8, 12}, {3, 1, 2, 6}, {5, 7, 4, 1}, {11, 12, 10, 7}, {12, 11, 9}, {3, 5, 1}, {6, 9, 3}, {5, 11, 7}, {8, 10, 12}, {1, 4, 2}, {2, 8, 6}, {7, 10, 4}}]]
Wolfram Language code: RegionQ[%]
Wolfram Research (2019)，DualPolyhedron，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DualPolyhedron.html.

文本

Wolfram Research (2019)，DualPolyhedron，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DualPolyhedron.html.

CMS

Wolfram 语言. 2019. "DualPolyhedron." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DualPolyhedron.html.

APA

Wolfram 语言. (2019). DualPolyhedron. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DualPolyhedron.html 年

BibTeX

@misc{reference.wolfram_2026_dualpolyhedron, author="Wolfram Research", title="{DualPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DualPolyhedron.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dualpolyhedron, organization={Wolfram Research}, title={DualPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/DualPolyhedron.html}, note=[Accessed: 08-September-2026]}