WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticExpPrime[u,{a,b}]

给出关于 u 的 EllipticExp[u,{a,b}] 导数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
积分  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EllipticExpPrime

EllipticExpPrime[u,{a,b}]

给出关于 u 的 EllipticExp[u,{a,b}] 导数.

更多信息

  • 数学函数，同时适合符号和数值操作.
  • 对一些特定自变量而言，EllipticExpPrime 自动计算其精确值.
  • EllipticExpPrime 可以计算到任意数值精度.

范例

打开所有单元 关闭所有单元

基本范例  (2)

数值运算：

Wolfram Language code: EllipticExpPrime[-0.4, {4., 1}]

在数个实数周期上绘制 EllipticExpPrime 的分量：

Wolfram Language code: Plot[{EllipticExpPrime[x, {4, 1}]//First, EllipticExpPrime[x, {4, 1}]//Last}, {x, 0, 4 2.83147}]

范围  (9)

数值计算  (4)

数值化计算：

Wolfram Language code: EllipticExpPrime[6., {4, 1}]
Wolfram Language code: EllipticExpPrime[-.2, {3, 2}]

高精度计算：

Wolfram Language code: N[EllipticExpPrime[1 / 3, {5, 1}], 50]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticExpPrime[0.3333330003333333333, {5, 1}]

复数输入：

Wolfram Language code: N[EllipticExpPrime[27 + I, {5 - I, 2}]]

高精度的高效计算：

Wolfram Language code: N[EllipticExpPrime[157`10, {5, 1}], 50]//Timing
Wolfram Language code: N[EllipticExpPrime[157`10000, {5, 1}], 50];//Timing

特殊值  (2)

在固定点的值：

Wolfram Language code: Table[EllipticExpPrime[x, {0 , 0}], {x, {-1, 2}}]

零处的值：

Wolfram Language code: EllipticExpPrime[0, {1, 2}]

可视化  (2)

绘制各种参数值的 EllipticExpPrime 函数：

Wolfram Language code: Plot[{EllipticExpPrime[u, {2, 3}], EllipticExpPrime[u, {4, 3}], EllipticExpPrime[-u, {4, 3}]}, {u, -3, 3}]

绘制 EllipticExpPrime[z,{1,2}] 实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticExpPrime[z, {1, 2}]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

绘制 EllipticExpPrime[z,{1,2}] 虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticExpPrime[z, {1, 2}]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

积分  (1)

使用 Integrate 计算不定积分：

Wolfram Language code: Integrate[EllipticExpPrime[u, {a, b}], u]

验证反导数：

Wolfram Language code: FullSimplify[D[%, u]]

应用  (1)

可视化函数：

Wolfram Language code: Plot3D[Norm[EllipticExpPrime[x + I y, {1, 2}]], {x, -3, 3}, {y, -3, 3}]

属性和关系  (4)

EllipticExpPrime 是 EllipticExp 的导数：

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

EllipticExpPrime 与 WeierstrassP 函数及其导数密切相关：

Wolfram Language code: ellipticExpPrime[u_, {a_, b_}] := {8 WeierstrassPPrime[2 u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}], 48 WeierstrassP[2 u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]^2 - (a^2/3) + b}

比较数值：

Wolfram Language code: ellipticExpPrime[0.5, {3, 4}]//Chop
Wolfram Language code: EllipticExpPrime[0.5, {3, 4}]

计算椭圆指数及其导数：

Wolfram Language code: u = -0.4;{a, b} = {4., 1.};
Wolfram Language code: eExp = EllipticExp[u, {a, b}]
Wolfram Language code: eExpPrime = EllipticExpPrime[u, {a, b}]

EllipticExpPrime 可用 EllipticExp 的分量表示：

Wolfram Language code: eExpPrime == {2Indexed[eExp, 2], 3Indexed[eExp, 1]^2 + 2a Indexed[eExp, 1] + b}

WeierstrassHalfPeriods 可用于计算 EllipticExpPrime 的两个线性独立周期：

Wolfram Language code: {a, b} = {4., 1.}; {p1, p2} = 2WeierstrassHalfPeriods[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]

比较 EllipticExpPrime 在复平面内同位点（congruent point）的数值运算：

Wolfram Language code: u = -0.4; {EllipticExpPrime[u, {a, b}], EllipticExpPrime[u + p1, {a, b}], EllipticExpPrime[u + p2, {a, b}]}
Wolfram Research (1991)，EllipticExpPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

文本

Wolfram Research (1991)，EllipticExpPrime，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

CMS

Wolfram 语言. 1991. "EllipticExpPrime." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

APA

Wolfram 语言. (1991). EllipticExpPrime. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticExpPrime.html 年

BibTeX

@misc{reference.wolfram_2026_ellipticexpprime, author="Wolfram Research", title="{EllipticExpPrime}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticExpPrime.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticexpprime, organization={Wolfram Research}, title={EllipticExpPrime}, year={1991}, url={https://reference.wolfram.com/language/ref/EllipticExpPrime.html}, note=[Accessed: 16-September-2026]}