WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Enclose[expr]

expr を評価して結果を返そうとするが，エラーをキャッチした場合は評価を中止して失敗オブジェクトを返す．

Enclose[expr,f]

生成された任意の失敗オブジェクトに f を適用する．

Enclose[expr,"prop"]

生成された任意の失敗オブジェクトの特性 prop を与える．

Enclose[expr,handler,form]

明示的に指定された，form と一致するタグでスローされたエラーだけをキャッチする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

Enclose

Enclose[expr]

expr を評価して結果を返そうとするが，エラーをキャッチした場合は評価を中止して失敗オブジェクトを返す．

Enclose[expr,f]

生成された任意の失敗オブジェクトに f を適用する．

Enclose[expr,"prop"]

生成された任意の失敗オブジェクトの特性 prop を与える．

Enclose[expr,handler,form]

明示的に指定された，form と一致するタグでスローされたエラーだけをキャッチする．

詳細

  • Enclose[expr,…]は，評価中にエラーがキャッチされなかったときは expr の値を返す．
  • Encloseは，内側のEncloseですでにキャッチされているエラーはキャッチしない．
  • Encloseのスコープは，タグが与えられていない場合は語彙的になり，タグが与えられている場合は動的になる．Enclose[expr]は，したがって，式 expr に語彙的に現れるConfirm等のインスタンスだけを処理する．expr の処理中に遭遇したConfirm等のインスタンスは処理しない．
  • tag は，パターンを含む任意の式でよい．
  • Encloseは，Confirm，ConfirmBy，ConfirmMatch，ConfirmQuiet，ConfirmAssertがスローしたエラーをキャッチする．
  • Encloseは，事実上特殊なタグでCatchを使う．
  • Enclose[expr,f,…]の中の f のデフォルト値はIdentityである．
  • Enclose[expr,"prop"]でリクエストできる特性は，スローされたエラーによって異なる． »

例題

すべて開く すべて閉じる

例  (2)

式を評価し，エラーがスローされ次第評価を中止する：

Wolfram Language code: Enclose[2 + 2]
Wolfram Language code: Enclose[2 + 2;Confirm[$Failed];4 + 4]

ロバストな関数を作成する：

Wolfram Language code: addtwo[x_] := Enclose[ConfirmBy[x, NumberQ] + 2]
Wolfram Language code: addtwo[4]
Wolfram Language code: addtwo[x]

スコープ  (6)

返す前にエラーを処理する：

Wolfram Language code: Enclose[2 + 2;Confirm[$Failed];4 + 4, f]

f を"Expression"に設定して，エラーをFailureで包み込まずに伝播する：

Wolfram Language code: Enclose[f[Confirm[Missing["NA"]]], "Expression"]

最も内側のEncloseが最優先される：

Wolfram Language code: Enclose[a; Enclose[b; Confirm[$Failed]; c]; d]

タグを使ってエラーを外側のEncloseに渡す：

Wolfram Language code: Enclose[a;Enclose[b;Confirm[$Failed, None, "tag"];c];d, Identity, "tag"]

エラーが発生した場合に固定値を返すために，f に定数関数を与える：

Wolfram Language code: recip[x_] := Enclose[1 / ConfirmBy[x, GreaterThan[0] @* Abs], Missing[]&]
Wolfram Language code: recip[2]
Wolfram Language code: recip[0]

エラーを複数レベルに伝播する：

Wolfram Language code: addtwo[x_] := Enclose[Confirm[x] + 2] framedAddtwo[x_] := Enclose[Framed[Confirm[addtwo[x]]]]
Wolfram Language code: framedAddtwo[5]
Wolfram Language code: framedAddtwo[$Failed]

確認をネストさせて複数回確認する：

Wolfram Language code: Enclose[f[ConfirmBy[ConfirmMatch[x, _Integer], EulerPhi[#] > 3&]]]

アプリケーション  (3)

失敗する可能性のある関数を安全に呼び出し，エラーを変更せずに伝播する：

Wolfram Language code: cityPopulation[s_] := Enclose[Confirm[Interpreter["City"][s]]["Population"], "Expression"]
Wolfram Language code: cityPopulation["nyc"]
Wolfram Language code: cityPopulation["null island"]

すべての国の一人あたりGDPを計算し，不足値を伝播する：

Wolfram Language code: Short[Enclose[Confirm[#[[1]]] / Confirm[#[[2]]], Missing[]&]& /@ EntityValue["Country", {"GDP", "Population"}]]

BoundaryMeshRegionが使用できない多面体を無視して，頂点のすべてのペアの間に辺があるすべての多面体を検索する：

Wolfram Language code: Keys[Select[EntityValue["Polyhedron", "BoundaryMeshRegion", "EntityAssociation"], Enclose[CompleteGraphQ[MeshConnectivityGraph[Confirm[#], 2]], False&]&]]

考えられる問題  (3)

Catch[…,_]はエラーが傍受できる：

Wolfram Language code: Enclose[Catch[Confirm[$Failed], _];d]

EncloseはThrowがスローした式はキャッチしない：

Wolfram Language code: Enclose[Throw[a];b]

タグが与えられないと，EncloseはConfirmのようなシンボルをタグ付きの異形で語彙的に置換する：

Wolfram Language code: Enclose[Hold[Confirm]]
Wolfram Research (2020), Enclose, Wolfram言語関数， https://reference.wolfram.com/language/ref/Enclose.html.

テキスト

Wolfram Research (2020), Enclose, Wolfram言語関数， https://reference.wolfram.com/language/ref/Enclose.html.

CMS

Wolfram Language. 2020. "Enclose." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Enclose.html.

APA

Wolfram Language. (2020). Enclose. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Enclose.html

BibTeX

@misc{reference.wolfram_2026_enclose, author="Wolfram Research", title="{Enclose}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/Enclose.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_enclose, organization={Wolfram Research}, title={Enclose}, year={2020}, url={https://reference.wolfram.com/language/ref/Enclose.html}, note=[Accessed: 10-September-2026]}