WOLFRAM

Wolfram 语言与系统参考资料中心

EntityRegister[estore]

在 entity store estore 中注册实体，以便可用 Entity 直接访问这些实体.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

EntityRegister

EntityRegister[estore]

在 entity store estore 中注册实体，以便可用 Entity 直接访问这些实体.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

注册包含有关水果数据的实体存储：

Wolfram Language code: EntityRegister[EntityStore["fruit" -> <| "Entities" -> <| "banana" -> <|"color" -> Yellow|>, "strawberry" -> <|"color" -> Red|> |> |>]]

列出所有 "fruit" 实体：

Wolfram Language code: EntityList["fruit"]

查找香蕉的颜色：

Wolfram Language code: Entity["fruit", "banana"]["color"]

添加其他水果数据：

Wolfram Language code: Entity["fruit", "kiwi"]["color"] = Green;

给出获取 "fruit" 实体类型的数据时访问的实体存储：

Wolfram Language code: Entity["fruit"]["EntityStore"]

列出所有注册的实体存储：

Wolfram Language code: EntityStores[]

取消 "fruit" 实体存储的注册：

Wolfram Language code: EntityUnregister["fruit"]

注册一个基于 SQL 的 EntityStore：

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]

范围  (2)

在赋值时，为每个新的实体类型创建单独的实体存储：

Wolfram Language code: Entity["MyType1", "e"]["p"] = 915; Entity["MyType2", "f"]["q"] = "abc";
Wolfram Language code: EntityStores[]
Wolfram Language code: EntityUnregister /@ {"MyType1", "MyType2"};

如果想要将数据导入同一实体存储，在赋值之前注册一个包含这两种类型的存储：

Wolfram Language code: EntityRegister[EntityStore[{"MyType1", "MyType2"}]];
Wolfram Language code: Entity["MyType1", "e"]["p"] = 915; Entity["MyType2", "f"]["q"] = "abc";
Wolfram Language code: EntityStores[]

引用其中任意一个类型即可取消整个实体存储的注册：

Wolfram Language code: EntityUnregister["MyType1"]
Wolfram Language code: EntityStores[]

注册包含两种类型的实体存储：

Wolfram Language code: EntityRegister[EntityStore[{ "t1" -> <| "Entities" -> <|"e" -> <|"p" -> Entity["t2", "f"]|>|> |>, "t2" -> <| "Entities" -> <|"f" -> <|"q" -> 19|>|> |> }]]
Wolfram Language code: Entity["t1", "e"]["p"] %["q"]

注册另一个存储，覆盖类型 "t2"：

Wolfram Language code: EntityRegister[EntityStore[ "t2" -> <| "Entities" -> <|"f" -> <|"q" -> 7891|>|> |> ]];

现在存储 Entity["t2","f"] 指代的是新注册的存储中的实体：

Wolfram Language code: Entity["t1", "e"]["p"] %["q"]

取消注册类型 "t2" 将恢复之前的结果：

Wolfram Language code: EntityUnregister["t2"]
Wolfram Language code: Entity["t1", "e"]["p"] %["q"]

取消注册类型 "t1"：

Wolfram Language code: EntityUnregister["t1"]

可能存在的问题  (1)

在处理外部数据库时，可能会遇到一个数据库，其中没有为某些表设置主键：

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[URLDownload[CloudObject["https://www.wolframcloud.com/obj/documentation/nopk.sqlite"]]]]]

这种情况下，EntityStore 将发出一条消息. 这意味着将禁用涉及单个实体的某些功能：

Wolfram Language code: EntityList["table"]

但是 EntityValue 一般依然可用：

Wolfram Language code: EntityValue["table", "col"]

解决此问题的唯一方法是在外部数据库中设置主键约束.

Wolfram Research (2018)，EntityRegister，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EntityRegister.html.

文本

Wolfram Research (2018)，EntityRegister，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EntityRegister.html.

CMS

Wolfram 语言. 2018. "EntityRegister." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EntityRegister.html.

APA

Wolfram 语言. (2018). EntityRegister. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EntityRegister.html 年

BibTeX

@misc{reference.wolfram_2026_entityregister, author="Wolfram Research", title="{EntityRegister}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/EntityRegister.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_entityregister, organization={Wolfram Research}, title={EntityRegister}, year={2018}, url={https://reference.wolfram.com/language/ref/EntityRegister.html}, note=[Accessed: 13-September-2026]}