WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Entropy[data]

data 中の値の底が の情報エントロピーを与える．

Entropy[k,data]

底が k の情報エントロピーを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
SameTest  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Entropy

Entropy[data]

data 中の値の底が の情報エントロピーを与える．

Entropy[k,data]

底が k の情報エントロピーを与える．

詳細とオプション

  • Entropyは，データ内の変動（情報のサイズ）の尺度である
  • data は，次の追加的な形式と解釈を持つことができる．
  • {x1,x2,…}数値または記号値のリスト » »
    stringString string の文字のリスト »
    WeightedData重み付きの値のリスト »
    TimeSeries, TemporalData値のベクトルまたは配列（タイムスタンプは無視される） »
  • Entropy[k,{x1, …}]は-piLog[k,pi]に等しい．ここで，piは xiの個別要素の出現率である． »
  • 次は，使用可能なオプションである．
  • SameTest Automatic式の等価性を検定する関数 »
  • Entropy[data,SameTestf]は，データ要素のペアに f を適用して両者が等しいと判断されるべきかどうかを決定する．

例題

すべて開く すべて閉じる

例  (3)

データのリストのエントロピー：

Wolfram Language code: Entropy[{0, 1, 1, 4, 1, 1}]

文字列のエントロピー：

Wolfram Language code: Entropy["A quick brown fox jumps over the lazy dog"]
Wolfram Language code: %//N

記号リストのエントロピー：

Wolfram Language code: Entropy[{a, b, b, c, c, c, c}]

7つの要素のうち1つは1回出現し，別の要素は2回出現し，3つ目は4回出現する：

Wolfram Language code: -1 / 7Log[1 / 7] - 2 / 7Log[2 / 7] - 4 / 7Log[4 / 7] == %

スコープ  (4)

0と1のランダムなリストのエントロピー：

Wolfram Language code: list = RandomInteger[1, 1000];
Wolfram Language code: Counts[list]
Wolfram Language code: Entropy[list]
Wolfram Language code: %//N

WeightedDataのエントロピー：

Wolfram Language code: data = {0, 1, 1, 4, 1, 1}; weights = {3, 1, 1, 1, 1, 1};
Wolfram Language code: Entropy[WeightedData[data, weights]]//Simplify

重みなしのデータのエントロピーと比較する：

Wolfram Language code: Entropy[data]//Simplify
Wolfram Language code: N /@ {%, %%}

TimeSeriesのエントロピーを計算する：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{5, 4, 5, 6, 3, 3, 3, 6, 6, 6, 3, 3, 3, 6, 6, 6, 3, 6, 4, 4, 6, 6, 4, 5, 3, 5, 3, 4, 5, 6, 5, 3, 6, 3, 6, 5, 5, 4, 3, 5, 3, 5, 4, 5, 3, 3, 4, 6, 4, 5, 6, 5, 3, 4, 6, 4, 5, 3, 3, 6, 4, 4, 3, 4, 6, 3, 3, 4, 3, 3, ... , 4, 5, 4, 3, 3, 3, 3, 3, 6, 4, 4, 5, 5, 3, 3, 4, 4, 5, 3, 4, 3, 4, 6, 3}}, {{1, 174, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, False, 14.3];
Wolfram Language code: ListPlot[ts]
Wolfram Language code: Entropy[ts]

エントロピーは値のみに依存する：

Wolfram Language code: Entropy[ts["Values"]]
Wolfram Language code: %% - %//Simplify

底を指定する：

Wolfram Language code: list = {0, 1, 1, 4, 1, 1};
Wolfram Language code: Entropy[10, list]//Simplify
Wolfram Language code: Entropy[2, list]//Simplify

デフォルトの底：

Wolfram Language code: Entropy[E, list] == Entropy[list]

オプション  (1)

SameTest  (1)

データ要素の比較検定を指定する：

Wolfram Language code: data = {0, 1., 1, 0, 1., 1};
Wolfram Language code: Entropy[data, SameTest -> Equal]
Wolfram Language code: N[%]

デフォルト設定と比較する：

Wolfram Language code: Entropy[data]//N

アプリケーション  (2)

エントロピーを使ってデータ集合間の変動レベルが比較できる：

Wolfram Language code: list1 = {0, 1, 1, 0, 0, 1, 1}; list2 = {1, 2, 3, 4, 5, 6, 7};
Wolfram Language code: N[Entropy /@ {list1, list2}]

TelegraphProcessの経路のエントロピーをレート で計算する：

Wolfram Language code: μ = 1.3; data = RandomFunction[TelegraphProcess[μ], {1, 10 ^ 2}]
Wolfram Language code: ListPlot[data]
Wolfram Language code: Entropy[data]
Wolfram Language code: N[%]

特性と関係  (3)

エントロピーはデータ値には依存しない：

Wolfram Language code: Entropy[{1, 2, 3, 4}]
Wolfram Language code: Entropy[{x, y, z, w}]
Wolfram Language code: Entropy["star"]

定義からのリストのエントロピーを計算する：

Wolfram Language code: list = RandomInteger[3, 100]
Wolfram Language code: probs = Values[Counts[list]] / Length[list]
Wolfram Language code: -Total[probs Log[probs]]

チェックする：

Wolfram Language code: Entropy[list] - %//FullSimplify

文字列のエントロピーはその文字のリストのエントロピーに等しい：

Wolfram Language code: string = "A quick brown fox jumps over the lazy dog";
Wolfram Language code: Entropy[string]

文字のリスト：

Wolfram Language code: Characters[string]
Wolfram Language code: Entropy[%]
Wolfram Language code: %%% - %//Simplify

考えられる問題  (1)

記号の底の場合，b を底とするlogは対数の商として評価される：

Wolfram Language code: Entropy[b, {0, 1, 1, 1, 2, 2}]//Simplify

おもしろい例題  (2)

テキストのエントロピー：

Wolfram Language code: Entropy[ExampleData[{"Text", "Hamlet"}]]//Short
Wolfram Language code: %//N

「ソネット」と比較する：

Wolfram Language code: Entropy[ExampleData[{"Text", "ShakespearesSonnets"}]]//N

異なる言語の国連人権宣言のテキストのエントロピーを比較する：

Wolfram Language code: unhr = Select[ExampleData["Text"], StringContainsQ[#[[2]], "UNHumanRights"]&];
Wolfram Language code: unhr//Short
Wolfram Language code: labels = Map[Style[StringDrop[#, 13], 9]&, unhr[[All, 2]]];
Wolfram Language code: BarChart[Map[N@Entropy[ExampleData[#]]&, unhr], ChartLabels -> Placed[labels, After], BarOrigin -> Left, ColorFunction -> Function[{height}, ColorData["IslandColors"][1 - height]]]
Wolfram Research (2008), Entropy, Wolfram言語関数， https://reference.wolfram.com/language/ref/Entropy.html.

テキスト

Wolfram Research (2008), Entropy, Wolfram言語関数， https://reference.wolfram.com/language/ref/Entropy.html.

CMS

Wolfram Language. 2008. "Entropy." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Entropy.html.

APA

Wolfram Language. (2008). Entropy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Entropy.html

BibTeX

@misc{reference.wolfram_2026_entropy, author="Wolfram Research", title="{Entropy}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Entropy.html}", note=[Accessed: 16-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_entropy, organization={Wolfram Research}, title={Entropy}, year={2008}, url={https://reference.wolfram.com/language/ref/Entropy.html}, note=[Accessed: 16-October-2026]}