WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Epilog

グラフィックス関数のオプションとして使われ，グラフィックスの主な部分が描画された後に描くグラフィックスプリミティブのリストを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Epilog

Epilog

グラフィックス関数のオプションとして使われ，グラフィックスの主な部分が描画された後に描くグラフィックスプリミティブのリストを指定する．

詳細

  • 3Dグラフィックスにおいて，2DグラフィックスプリミティブをEpilogオプションで指定することができる．グラフィックスプリミティブは，0,1座標系で描かれる．

例題

すべて開く すべて閉じる

例  (2)

プロットの上にサンプル点を描く：

Wolfram Language code: data = Table[{i, RandomReal[i]}, {i, 10}];
Wolfram Language code: ListLinePlot[data, Epilog -> {PointSize[Medium], Point[data]}, InterpolationOrder -> 2]

3Dグラフィックスの右下コーナーにテキストを置く：

Wolfram Language code: SphericalPlot3D[ϕ, {θ, 0, Pi}, {ϕ, 0, 3Pi}, Epilog -> Inset[Framed[Style["Spiral", 20], Background -> LightYellow], {Right, Bottom}, {Right, Bottom}]]

スコープ  (2)

2DグラフィックスのEpilogでは通常の座標系が使われている：

Wolfram Language code: Table[Graphics[{Pink, Disk[{0, 0}, 10]}, Axes -> True, Epilog -> Disk[p, 2]], {p, {{-5, -5}, {0, 0}, {5, 5}}}]

3DグラフィックスのEpilogではスケールされた0,1座標系が使われている：

Wolfram Language code: Table[Graphics3D[Sphere[{0, 0, 0}, 10], Epilog -> Disk[p, .1]], {p, {{.2, .2}, {.5, .5}, {.8, .8}}}]

アプリケーション  (3)

補間されたプロットの上にサンプル点とそれを繋ぐ線を表示する：

Wolfram Language code: data = Table[{i, RandomReal[i]}, {i, 10}];
Wolfram Language code: ListLinePlot[data, Epilog -> {Green, Line[data], PointSize[Medium], Red, Point[data]}, InterpolationOrder -> 2]

線形補間とメッシュを含む複写されたデータを使った同じ結果：

Wolfram Language code: ListLinePlot[{data, data}, InterpolationOrder -> {2, 1}, PlotStyle -> {Automatic, Green}, Mesh -> Full, MeshStyle -> Directive[PointSize[Medium], Red]]

直線と曲線が交差するところに大きい点を描く：

Wolfram Language code: {f, g} = {27 x + 130, -12 - 58 x + x^2 + x^3};
Wolfram Language code: Plot[{f, g}, {x, -10, 10}, Epilog -> {PointSize[Large], (Point[{#, f /. x -> #}]&) /@ (x /. NSolve[f == g, x])}]

あるいは，MeshFunctionsを使って交点を求める：

Wolfram Language code: Plot[{f, g}, {x, -10, 10}, MeshFunctions -> {(f - g) /. x -> #&}, Mesh -> {{0}}, MeshStyle -> PointSize[Large]]

グラフィックスの上に透かし模様を入れる：

Wolfram Language code: watermark = Style["Watermark", 36, Bold, FontFamily -> "Helvetica", Opacity[.3]];
Wolfram Language code: SphericalPlot3D[ϕ, {θ, 0, Pi}, {ϕ, 0, 3Pi}, Mesh -> None, PlotStyle -> Directive[Specularity[White, 50], Yellow], Epilog -> Inset[watermark, Automatic, Automatic, Automatic, {1, 1}]]

特性と関係  (3)

Epilog中のオブジェクトはPlotRangeの計算には含まれない：

Wolfram Language code: Graphics[{Pink, Disk[]}, Epilog -> Circle[{0, 1}], Frame -> True]

2Dでは，グラフィックスの上に座標軸が描かれる：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True]

Epilog中のオブジェクトは，座標軸を含めたグラフィックスの上に描かれる：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True, Epilog -> {Blue, Disk[{0, 0}, .4]}]

プロット関数では，PlotRangeClippingはデフォルトでEpilogを含むグラフィックスを切り取る：

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Epilog -> Circle[], AspectRatio -> Automatic]

PlotRangeClippingをFalseにすると，グラフィックスがプロット範囲の外側まで描かれる：

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Epilog -> Circle[], PlotRangeClipping -> False, AspectRatio -> Automatic]

おもしろい例題  (1)

RegionPlotが生成した画像マスク：

Wolfram Language code: g = RegionPlot[.45 ^ 10 < (x - .5) ^ 10 + (y - .5) ^ 10, {x, 0, 1}, {y, 0, 1}, ColorFunction -> "TemperatureMap"]

3Dグラフィックスの上に「写真のフレーム」のようにマスクを適用する：

Wolfram Language code: Graphics3D[Cylinder[], Boxed -> False, SphericalRegion -> True, Epilog -> First[g]]
Wolfram Research (1991), Epilog, Wolfram言語関数， https://reference.wolfram.com/language/ref/Epilog.html.

テキスト

Wolfram Research (1991), Epilog, Wolfram言語関数， https://reference.wolfram.com/language/ref/Epilog.html.

CMS

Wolfram Language. 1991. "Epilog." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Epilog.html.

APA

Wolfram Language. (1991). Epilog. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Epilog.html

BibTeX

@misc{reference.wolfram_2026_epilog, author="Wolfram Research", title="{Epilog}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/Epilog.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_epilog, organization={Wolfram Research}, title={Epilog}, year={1991}, url={https://reference.wolfram.com/language/ref/Epilog.html}, note=[Accessed: 06-September-2026]}