WOLFRAM

Wolfram 语言与系统参考资料中心

Epilog

是图形函数的一个选项，用来给出绘制图形的主要部分之后将要绘制的一个图形基元列表.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

Epilog

Epilog

是图形函数的一个选项，用来给出绘制图形的主要部分之后将要绘制的一个图形基元列表.

更多信息

  • 在三维图形中，二维图形基元可以由 Epilog 选项指定. 这些图形基元在 0，1 坐标系统中绘制.

范例

打开所有单元 关闭所有单元

基本范例  (2)

在图形顶部绘制样本点：

Wolfram Language code: data = Table[{i, RandomReal[i]}, {i, 10}];
Wolfram Language code: ListLinePlot[data, Epilog -> {PointSize[Medium], Point[data]}, InterpolationOrder -> 2]

在三维图象的右下角放置文本：

Wolfram Language code: SphericalPlot3D[ϕ, {θ, 0, Pi}, {ϕ, 0, 3Pi}, Epilog -> Inset[Framed[Style["Spiral", 20], Background -> LightYellow], {Right, Bottom}, {Right, Bottom}]]

范围  (2)

在二维图像中， Epilog 使用的普通坐标系：

Wolfram Language code: Table[Graphics[{Pink, Disk[{0, 0}, 10]}, Axes -> True, Epilog -> Disk[p, 2]], {p, {{-5, -5}, {0, 0}, {5, 5}}}]

在三维图象中，Epilog 使用的成比例的 0,1 坐标系：

Wolfram Language code: Table[Graphics3D[Sphere[{0, 0, 0}, 10], Epilog -> Disk[p, .1]], {p, {{.2, .2}, {.5, .5}, {.8, .8}}}]

应用  (3)

在插图上显示样本点，并用线条连接：

Wolfram Language code: data = Table[{i, RandomReal[i]}, {i, 10}];
Wolfram Language code: ListLinePlot[data, Epilog -> {Green, Line[data], PointSize[Medium], Red, Point[data]}, InterpolationOrder -> 2]

相同的结果，用带有线性插值和网格线的复杂数据集：

Wolfram Language code: ListLinePlot[{data, data}, InterpolationOrder -> {2, 1}, PlotStyle -> {Automatic, Green}, Mesh -> Full, MeshStyle -> Directive[PointSize[Medium], Red]]

在线和曲线的交点处绘制较大的点：

Wolfram Language code: {f, g} = {27 x + 130, -12 - 58 x + x^2 + x^3};
Wolfram Language code: Plot[{f, g}, {x, -10, 10}, Epilog -> {PointSize[Large], (Point[{#, f /. x -> #}]&) /@ (x /. NSolve[f == g, x])}]

可选择用 MeshFunctions 求出交集：

Wolfram Language code: Plot[{f, g}, {x, -10, 10}, MeshFunctions -> {(f - g) /. x -> #&}, Mesh -> {{0}}, MeshStyle -> PointSize[Large]]

在图形顶部放置水印：

Wolfram Language code: watermark = Style["Watermark", 36, Bold, FontFamily -> "Helvetica", Opacity[.3]];
Wolfram Language code: SphericalPlot3D[ϕ, {θ, 0, Pi}, {ϕ, 0, 3Pi}, Mesh -> None, PlotStyle -> Directive[Specularity[White, 50], Yellow], Epilog -> Inset[watermark, Automatic, Automatic, Automatic, {1, 1}]]

属性和关系  (3)

Epilog 中的对象不是 PlotRange 计算中的部分：

Wolfram Language code: Graphics[{Pink, Disk[]}, Epilog -> Circle[{0, 1}], Frame -> True]

在二维图形中，在图形上绘制轴线：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True]

在任意图像上绘制 Epilog 中的对象，包括轴线：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True, Epilog -> {Blue, Disk[{0, 0}, .4]}]

在图形函数中，PlotRangeClipping 缺省情况下剪切包括 Epilog 的图形：

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Epilog -> Circle[], AspectRatio -> Automatic]

通过将 PlotRangeClipping 设置为 False，可以在绘图范围之外绘制图形：

Wolfram Language code: Plot[2Sin[x], {x, 0, 10}, Epilog -> Circle[], PlotRangeClipping -> False, AspectRatio -> Automatic]

巧妙范例  (1)

由 RegionPlot 生成的图像屏蔽：

Wolfram Language code: g = RegionPlot[.45 ^ 10 < (x - .5) ^ 10 + (y - .5) ^ 10, {x, 0, 1}, {y, 0, 1}, ColorFunction -> "TemperatureMap"]

在三维图象上应用屏蔽，类似一个“画框”：

Wolfram Language code: Graphics3D[Cylinder[], Boxed -> False, SphericalRegion -> True, Epilog -> First[g]]
Wolfram Research (1991)，Epilog，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Epilog.html.

文本

Wolfram Research (1991)，Epilog，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Epilog.html.

CMS

Wolfram 语言. 1991. "Epilog." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Epilog.html.

APA

Wolfram 语言. (1991). Epilog. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Epilog.html 年

BibTeX

@misc{reference.wolfram_2026_epilog, author="Wolfram Research", title="{Epilog}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/Epilog.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_epilog, organization={Wolfram Research}, title={Epilog}, year={1991}, url={https://reference.wolfram.com/language/ref/Epilog.html}, note=[Accessed: 10-September-2026]}