WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EulerAngles[r]

回転行列 r に対応するオイラー角{α,β,γ}を与える．

EulerAngles[r,{a,b,c}]

回転順序が{a,b,c}のオイラー角{α,β,γ}を与える．

詳細
Details and Options Details and Options
例題  
例  
アプリケーション  
回転表現  
座標系  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

EulerAngles

EulerAngles[r]

回転行列 r に対応するオイラー角{α,β,γ}を与える．

EulerAngles[r,{a,b,c}]

回転順序が{a,b,c}のオイラー角{α,β,γ}を与える．

詳細

  • EulerAngles[r,{a,b,c}]は，EulerMatrix[{α,β,γ},{a,b,c}]r となるような角{α,β,γ}を与える．
  • EulerAngles[r]は，z-y-z回転EulerAngles[r,{3,2,3}]に等しい．
  • デフォルトのz-y-z角EulerAngles[r,{3,2,3}]は，回転を3段階に分解する．
  • 回転軸 a，b，c は，任意の整数1，2あるいは3でよい．しかし，任意の3D回転を指定するのに十分に一般的である組合せは12しかない．
  • 最初と最後の軸が繰り返される回転
  • {3,2,3}z-y-z回転（デフォルト）
    {3,1,3}z-x-z回転
    {2,3,2}y-z-y回転
    {2,1,2}y-x-y 回転
    {1,3,1}x-z-x回転
    {1,2,1}x-y-x回転
  • 3軸がみな違う回転
  • {1,2,3}x-y-z回転
    {1,3,2}x-z-y回転
    {2,1,3}y-x-z回転
    {2,3,1}y-z-x回転
    {3,1,2}z-x-y回転
    {3,2,1}z-y-x回転
  • 続く軸が繰り返される回転は，3Dにおける可能なすべての回転を表すことができないので，可逆ではない．

例題

すべて開く すべて閉じる

例  (2)

回転行列からオイラー角を得る：

Wolfram Language code: m = EulerMatrix[{Pi / 2, Pi / 3, Pi / 4}];
Wolfram Language code: EulerAngles[m]

指定された回転順の回転行列からオイラー角を得る：

Wolfram Language code: m = EulerMatrix[{Pi / 2, Pi / 3, Pi / 4}, {1, 2, 3}];
Wolfram Language code: EulerAngles[m, {1, 2, 3}]

アプリケーション  (6)

回転表現  (4)

オイラー角を1つの回転順から別の回転順に変換する：

Wolfram Language code: a = {Pi / 2, Pi / 3, Pi / 4};
Wolfram Language code: m = EulerMatrix[a, {3, 2, 1}];
Wolfram Language code: EulerAngles[m, {1, 2, 1}]

ロールピッチヨー角をオイラー角に変換する：

Wolfram Language code: m = RollPitchYawMatrix[{Pi / 2, Pi / 3, Pi / 4}];
Wolfram Language code: EulerAngles[m]

t{1,1,1} + s{1,–2,1}で与えられる平面上の3D回転のためのオイラー角を得る：

Wolfram Language code: m = RotationMatrix[Pi / 3, {{1, 1, 1}, {1, -2, 1}}];
Wolfram Language code: EulerAngles[m]

オイラー回転の組み合せから，オイラー角の単一集合を求める：

Wolfram Language code: m1 = EulerMatrix[{Pi / 2, Pi / 2, Pi / 4}]; m2 = EulerMatrix[{Pi / 3, Pi / 4, 3Pi / 2}]; m3 = m1.m2;
Wolfram Language code: a = EulerAngles[m3]

どちらも同じ変換（赤）を行う：

Wolfram Language code: arrow = Arrow[{{0, 0, 0}, {0, 1, 0}}];
Wolfram Language code: Table[Graphics3D[{arrow, Red, GeometricTransformation[arrow, m]}, BoxStyle -> LightGray], {m, {m3, EulerMatrix[a]}}]

座標系  (2)

とをお互いから回転している直交座標の座標軸とする：

Wolfram Language code: {x1, y1, z1} = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}; {x2, y2, z2} = RotationTransform[π / 3, {1, 0, 0}][{x1, y1, z1}];

TemplateBox[{{{, {{x, _, 2}, ,, {y, _, 2}, ,, {z, _, 2}}, }}}, Transpose]=R.TemplateBox[{{{, {{x, _, 1}, ,, {y, _, 1}, ,, {z, _, 1}}, }}}, Transpose]（回転された 軸は で与えられる等）のとき，TemplateBox[{{{, {{x, _, 1}, ,, {y, _, 1}, ,, {z, _, 1}}, }}}, Transpose]は直交行列でその逆行列はその置換であるので，R=TemplateBox[{{{, {{x, _, 2}, ,, {y, _, 2}, ,, {z, _, 2}}, }}}, Transpose].{x_1,y_1,z_1}である：

Wolfram Language code: R = {x2, y2, z2}.{x1, y1, z1};

が座標系を関連付ける回転であることを確かめる：

Wolfram Language code: {x2, y2, z2} == R.{x1, y1, z1}//Simplify

を定義する，対応するオイラー角を求める：

Wolfram Language code: EulerAngles[R]

可視化する：

Wolfram Language code: billboard[s_, p_] := Inset[Framed[s, Background -> LightGray], p];
Wolfram Language code: s1 = {{Arrow[{{0, 0, 0}, x1}], billboard["X", x1]}, {Arrow[{{0, 0, 0}, y1}], billboard["Y", y1]}, {Arrow[{{0, 0, 0}, z1}], billboard["Z", z1]}};
Wolfram Language code: s2 = {{Red, Arrow[{{0, 0, 0}, x2}], billboard["X", x2]}, {Green, Arrow[{{0, 0, 0}, y2}], billboard["Y", y2]}, {Blue, Arrow[{{0, 0, 0}, z2}], billboard["Z", z2]}};
Wolfram Language code: Show[Graphics3D[#, ViewPoint -> {2, 1, 1}]& /@ {s1, s2}]

右手系のZ-Up座標系は，数学の直交座標で一般的である．しかし，コンピュータグラフィックスのアプリケーションでは，右手系のY-Up座標系のような別の系が使われることがある．前の例を使ってZ-UpをY-Up座標系に変換するオイラー角を求める：

Wolfram Language code: {x1, y1, z1} = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}; {x2, y2, z2} = {{0, 1, 0}, {0, 0, 1}, {1, 0, 0}};

回転行列 と， を定義する対応するオイラー角を求める：

Wolfram Language code: R = {x1, y1, z1}.{x2, y2, z2};
Wolfram Language code: ea = EulerAngles[R]

これらの角を使ってY-Up座標系を変換し可視化する（Z-Up系，Y-Up系，変換されたY-Up系）：

Wolfram Language code: billboard[s_, p_] := Inset[Framed[s, Background -> LightGray], p];
Wolfram Language code: s1 = {{Arrow[{{0, 0, 0}, x1}], billboard["X", x1]}, {Arrow[{{0, 0, 0}, y1}], billboard["Y", y1]}, {Arrow[{{0, 0, 0}, z1}], billboard["Z", z1]}};
Wolfram Language code: s2 = {{Red, Arrow[{{0, 0, 0}, x2}], billboard["X", x2]}, {Green, Arrow[{{0, 0, 0}, y2}], billboard["Y", y2]}, {Blue, Arrow[{{0, 0, 0}, z2}], billboard["Z", z2]}};
Wolfram Language code: s3 = GeometricTransformation[s2, EulerMatrix[ea]];
Wolfram Language code: Row[Graphics3D[#, ViewPoint -> {2, 1, 1}, ImageSize -> Tiny]& /@ {s1, s2, s3}]

特性と関係  (1)

EulerAnglesは，EulerMatrixがそれについて同じ回転行列与える角を与える：

Wolfram Language code: m1 = EulerMatrix[{π / 3, π / 2, π / 4}]; m2 = EulerMatrix[EulerAngles[m1]];
Wolfram Language code: m1 == m2

角度は等しくなくてもよい：

Wolfram Language code: a1 = {π / 2, π, π / 3}; m1 = EulerMatrix[a1];
Wolfram Language code: a2 = EulerAngles[m1]

しかし，両方の角度集合は同じ回転行列を生成する：

Wolfram Language code: EulerMatrix[a1] == EulerMatrix[a2]

考えられる問題  (1)

EulerMatrixを使うと等しい軸の連続が許容され，これが回転行列を生成する：

Wolfram Language code: m = EulerMatrix[{Pi, Pi / 2, Pi / 8}, {1, 1, 2}]
Wolfram Language code: {OrthogonalMatrixQ[m], Det[m]}//Simplify

しかし，EulerAnglesでは連続する軸が異なっていなければならない：

Wolfram Language code: EulerAngles[m, {1, 1, 2}]

これは，連続する軸が等しいと表すことができない回転行列が出てくるからである：

Wolfram Language code: m1 = EulerMatrix[{Pi / 3, 0, 0}, {3, 2, 1}]
Wolfram Language code: m2 = EulerMatrix[{α, β, γ}, {1, 1, 2}]
Wolfram Language code: FindInstance[And@@Thread[m1 == m2], {α, β, γ}]
Wolfram Research (2015), EulerAngles, Wolfram言語関数， https://reference.wolfram.com/language/ref/EulerAngles.html.

テキスト

Wolfram Research (2015), EulerAngles, Wolfram言語関数， https://reference.wolfram.com/language/ref/EulerAngles.html.

CMS

Wolfram Language. 2015. "EulerAngles." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EulerAngles.html.

APA

Wolfram Language. (2015). EulerAngles. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EulerAngles.html

BibTeX

@misc{reference.wolfram_2026_eulerangles, author="Wolfram Research", title="{EulerAngles}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/EulerAngles.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eulerangles, organization={Wolfram Research}, title={EulerAngles}, year={2015}, url={https://reference.wolfram.com/language/ref/EulerAngles.html}, note=[Accessed: 09-September-2026]}